エクセルのマクロで困ってます。シートの内容をコピーして新しいシートにそのままの形で貼り付けたい

Question

ネットで拾ったマクロをなんとなく自分で直して使ってたのですが、"基礎"のシートを丸ごとコピーしてコピーしたものを新しいシートに張りつける際に書式設定(セルの大きさ)が変わってしまうので、基礎のままコピペしたいです
やったことはRange("A1:J461").Copyの部分をcells.select.copyに変えたのですが、ダメでした

With Worksheets.Add()
.Name = Sheets("顧客管理").Range("D1")
.Move After:=Worksheets(Worksheets.Count)
End With

Worksheets("基礎").Range("A1:J461").Copy Worksheets(Worksheets.Count).Range("A1")
Columns("B:B").EntireColumn.AutoFit

With Worksheets("顧客管理").Activate
Dim LastRow As Long
LastRow = Cells(Rows.Count, 1).End(xlUp).Row + 1
Cells(LastRow, 1) = (Range("D1"))
End With

自分はここを直すとおもうのですが、直し方が分かりません
......................................↓ここの変え方(シート全体に指定)
Worksheets("基礎").Range("A1:J461").Copy Worksheets(Worksheets.Count).Range("A1")
↓この部分はいらないと思います...。
Columns("B:B").EntireColumn.AutoFit

...................................................................
ABCDEF
1
2
3
4

A左１の上にあるボタンを押してすべて選択してコピーしてペーストするとそのままの形(セルの大きさなど)で表示されるのでそうしたいです。
今のマクロだと初期のセルの大きさに戻ってしまいます
もちろん違うコピーの選択でも構いません(自分がこのやり方しか知らないので)

Comments

[meg_]

”シート自体のコピー”じゃ駄目なんですか？

[sugerShogo]

シート自体のコピーをしたらシート名はどうなりますか？
.Name = Sheets("顧客管理").Range("D1")のままのシート名でもペーストできますか？

[meg_]

> シート自体のコピーをしたらシート名はどうなりますか？
どうなるかはご自身でやって確かめるのが一番かと思います。
> .Name = Sheets("顧客管理").Range("D1")のままのシート名でもペーストできますか？
シート名はコピー後に変更すれば良いんじゃないでしょうか？

Answer 1

エクセルは、
列の幅は列に、行の幅は行に依存している（同じ列の個々のセルでセル幅が違うということはあり得ない）ので、列幅を維持したいなら列全体を、行高を維持したいなら行全体をコピーする必要があります。
両方ならシートそのものをコピーするか、
個々に行や列を設定するしかないかと思います。

---

追記

セル全体をコピーしてもいいんですね。
目から鱗です。

手動では操作したいものは、選択してエクセルに伝えますが、
VBAでは、操作したいものを文章で指示しますので、
選択したりアクティブにしたりの命令の記述は、不要です。
というか無駄な操作です。

Sub test1()
    Dim wshTemplate As Worksheet    '雛形シート
    Dim wshNew As Worksheet         '新しく作るシート
    Dim strName As String           'シート名
    
    '準備（前提条件の整理）
    strName = Worksheets("顧客管理").Range("D1").Value
    With Worksheets
        Set wshTemplate = .Item("基礎")
        Set wshNew = .Add(after:=.Item(.Count))
    End With
    
    '転記＆追記
    With wshNew
        wshTemplate.Cells.Copy .Cells
        .Name = strName
        With .UsedRange
            .Cells(.Rows.Count + 1, 1).Value = strName
        End With
    End With
End Sub

ただ、
1）新しいシートを作成
2）雛形シートのセルをコピペ
だと作業が2工程になりますが、

1）雛形シートをコピー

の1工程でも同じ結果になりませんか？
シート名を変えるのは同じですし。

Sub test2()
    Dim s As String
    Dim ix As Long
    
    With Worksheets
        s = .Item("顧客管理").Range("D1").Value
        ix = .Count
        .Item("基礎").Copy after:=.Item(ix)   '←シートを丸ごとコピー
        With .Item(ix + 1)
            .Name = s
            .Cells(.Rows.Count, 1).End(xlUp).Offset(1).Value = s
        End With
    End With
End Sub

解説が必要な部分があれば、聞いてください。

Comments

[sugerShogo]

基礎シートそのものをコピーして新シートにペーストしたいです
シート名は基礎ではなくName = Sheets("顧客管理").Range("D1")を使用して
それのマクロの組み方が分かりません

Answer 2

新しいシートを挿入して、そのまま”基礎”シートの内容を貼り付けるとすると以下の内容になると思います。

    Worksheets.Add After:=Worksheets(Worksheets.Count)
    Sheets("基礎").Cells.Copy
    Sheets(Worksheets.Count).PasteSpecial
    Application.CutCopyMode = False

Answer 3

マクロの記録で 試してみました

Sub Macro1()
'
    Cells.Select
    Range("A3564").Activate
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("Sheet1").Select
    Cells.Select
    Selection.PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
        , SkipBlanks:=False, Transpose:=False

End Sub