VBAでタブ区切りtxtからxlsxに変換し保存したい

Question

前提・実現したいこと

複数のテキストファイルがあり、それら一つずつxlsxファイルに保存したい。
a.txt -> a.xlsx
b.txt -> b.xlsx
.
.
という感じです。

発生している問題・エラーメッセージ

実際にフォーマットをxlsxに指定しているのにも関わらず、txtファイルで保存される。

該当のソースコード

Sub テキスト読み込み()
    
    Dim txtNames As Variant
    Dim txtName As Variant
    Dim newbk As Variant
    txtNames = Application.GetOpenFilename(FileFilter:="テキスト ファイル (*.txt), *.txt", _
    Title:="テキストファイル選択", MultiSelect:=True)
    
    
    
    For Each txtName In txtNames
            '新規にブックを追加
        Workbooks.Add
        '追加したブックの名前を取得
        newbk = ActiveWorkbook.Name
        'アクティブにする
        Workbooks(newbk).Activate
        If txtName <> "False" Then
            Open txtName For Input As #1
        End If
        
        Dim r As Long
        r = 1 '1行目から書き出す
        
        Do Until EOF(1)
        
            Dim buf As String
            Line Input #1, buf
            
            Dim aryLine As Variant '文字列格納用配列変数
            aryLine = Split(buf, vbTab) '読み込んだ行をタブ区切りで配列変数に格納
            
            Dim i As Long
            For i = LBound(aryLine) To UBound(aryLine)
                'インデックスが0から始まるので列番号に合わせるため+1
                Cells(r, i + 1) = aryLine(i)
            Next
            
            r = r + 1
        
        Loop
        
        Close #1
        ActiveWorkbook.SaveAs FileName:=txtName, FileFormat:=xlOpenXMLWorkbook
        
    Next txtName
        
    MsgBox "終了しました。"

End Sub

Answer 1

実際にフォーマットをxlsxに指定しているのにも関わらず、txtファイルで保存される。

読み込んだファイル名そのまま、拡張子も変えずに保存しているから。

ActiveWorkbook.SaveAs FileName:=Left(txtName, InStrRev(txtName, ".") - 1) & ".xlsx", FileFormat:=xlOpenXMLWorkbook

Comments

[SOSEKI]

なるほど、フォーマットを指定するだけではダメなんですね。
pythonで変換した時は.xls.xlsxのようにかけたので今回もできると思い込んでいました。