VBA を使ってinsert文を作りたい。

Question

コード
Sub sample()

    Dim IN_SQL As String
    Dim IN_TEAM As Variant
    Dim IN_ID As Variant
    Dim Y As Long
    Dim MaxRow As String
    MaxRow = Worksheets("sheet1").Cells(Rows.Count, 1).End(xlUp).Row
    
    'insert文作成
    IN_SQL = ""
    IN_SQL = IN_SQL & "INSERT INTO TEAM VALUES("
    'エクセルのid,とnameを取得
    For Y = 8 To MaxRow
        IN_ID = Worksheets(Sheet1).Cells(Y, "1").Value
        IN_TEAM = Worksheets(Sheet1).Cells(Y, "3").Value
        IN_SQL = IN_SQL & IN_ID
        IN_SQL = IN_SQL & IN_TEAM
        IN_SQL = IN_SQL & ")"
    Next
    'insert文を格納
    Worksheets("sheet1").Cells(15, 1) = IN_SQL
End Sub

VBA 初心者です。
insert文を作って、エクセルにセルに格納したいです。
idと、nameだけ挿入したいです。
今、データは、7個しかないが、時々によって8個になったり10個になったり、変わります。
エラーは型が一致しないとが出ます。
誰か教えてください、よろしくお願いします。

Comments

[kaz.Suenaga]

「エラー」はどの行で出ますか。

Answer 1

前回の実行結果がどこかの行に残っていませんか？
A列の下の方に、何かデータがあると、型が一致しない等のエラーが出ると思います。

更に、SQL文は、どのデータベースで利用するのでしょうか？

もし、ACCESSで利用する場合、複数の行のVALUESは指定できません。１行のデータのみです。
他のデータベースであれば、複数行のSQL文で、問題ないと思います。

一応、２通り用意します。

◆ Accessで利用する場合。

Sub sample()
    Dim IN_SQL1 As String
    Dim IN_SQL2 As String
    Dim IN_ID As Integer
    Dim IN_TEAM As String
    Dim Y As Long
    Dim MaxRow As Long
    
    MaxRow = Worksheets("sheet1").Cells(Rows.Count, 1).End(xlUp).Row
    
    'insert文作成
    IN_SQL1 = "INSERT INTO ITEM ( id, name ) values ("
    For Y = 8 To MaxRow
        'エクセルのid,とnameを取得
        IN_ID = Worksheets("Sheet1").Cells(Y, 1).Value
        IN_TEAM = Worksheets("Sheet1").Cells(Y, 3).Value
        IN_SQL2 = IN_SQL1 & IN_ID & ", """ & IN_TEAM & """);"
        'insert文を格納
        Worksheets("sheet1").Cells(Y, 6).Value = IN_SQL2
    Next
End Sub

結果↓

◆ SQL言語

Sub sample()
    Dim IN_SQL1 As String
    Dim IN_SQL2 As String
    Dim IN_ID As Integer
    Dim IN_TEAM As String
    Dim Y As Long
    Dim MaxRow As Long
    
    MaxRow = Worksheets("sheet1").Cells(Rows.Count, 1).End(xlUp).Row
    
    'insert文作成
    IN_SQL1 = "INSERT INTO ITEM ( id, name ) VALUES "
    For Y = 8 To MaxRow
        'エクセルのid,とnameを取得
        IN_ID = Worksheets("Sheet1").Cells(Y, 1).Value
        IN_TEAM = Worksheets("Sheet1").Cells(Y, 3).Value
        IN_SQL2 = IN_SQL2 & "(" & IN_ID & ", """ & IN_TEAM & """), "
    Next
    'insert文を格納
    Worksheets("sheet1").Cells(Y + 1, 1).Value = IN_SQL1 & Left(IN_SQL2, Len(IN_SQL2) - 2) & ";"
End Sub

結果↓

Answer 2

" の位置がおかしいです。

Worksheets(Sheet1).Cells(Y, "1").Value ⇒ Worksheets("Sheet1").Cells(Y, 1).Value

Sub sample()
    Dim IN_SQL As String
    Dim IN_TEAM As Variant
    Dim IN_ID As Variant
    Dim Y As Long
    Dim MaxRow As String
    MaxRow = Worksheets("sheet1").Cells(Rows.Count, 1).End(xlUp).Row

    'insert文作成
    IN_SQL = ""
    IN_SQL = IN_SQL & "INSERT INTO TEAM VALUES("
    'エクセルのid,とnameを取得
    For Y = 8 To MaxRow
        IN_ID = Worksheets("Sheet1").Cells(Y, 1).Value
        IN_TEAM = Worksheets("Sheet1").Cells(Y, 3).Value
        IN_SQL = IN_SQL & IN_ID
        IN_SQL = IN_SQL & IN_TEAM
        IN_SQL = IN_SQL & ")"
    Next
    'insert文を格納
    Worksheets("sheet1").Cells(15, 1) = IN_SQL
End Sub

これでエラーはでなくなります。
ただし、できるINSERT文はSQLとしてはおかしいですが、、、

Comments

[jingjing]

ありがとうございました。何とか解決することができました。
確かにSQL文がおかしいのでまた考えたいと思います。