for each と FileSystemObject の組み合わせ

Question

for each　の使い方を覚えようと思い、以下のコードを作成しましたが、「型が一致しません」と表示されます。
サブフォルダーをセルに記載しているので、型をstringに変えるなど試しましたが、バリアント型、もしくはオブジェクト型しか利用できないと表示されます。

Sub ステータス確認(sename)
Dim path As String
Dim fso As Object
Dim k As Object

path = ThisWorkbook.path & "\" & "写真格納ファイル" & "\" & sename & "\"
Set fso = CreateObject("Scripting.FileSystemObject")

For Each k In fso.Getfolder(path).SubFolders

Dim i As String
Cells(i, 1) = k
i = i + 1

Next
End Sub

改善方法や根本的に間違いがありましたらアドバイスをお願いします。
よろしくお願いします。

Comments

[meg_]

>「型が一致しません」と表示されます。
どの行でエラーが発生するのでしょうか？

[dodox86]

> Dim i As String
> Cells(i, 1) = k
> i = i + 1
なぜ、Stringなのか。

[ice930]

失礼しました・・・。
エラーが起きるのは「Cells(i, 1) = k」のところです。
※ちなみにstringではなくLongでエラーが表示されます。
オブジェクトはセルに入力できないのでしょうか

Answer 1

Option Explicit

'FileSystemObjectの参照設定を行うこと

Sub test()
    ステータス確認 "サンプル"
End Sub


Sub ステータス確認(ByVal seName As String)
    Dim FSO As Scripting.FileSystemObject
    Set FSO = New Scripting.FileSystemObject
    seName = ThisWorkbook.path & "\" & seName
    If FSO.FolderExists(seName) = False Then Exit Sub

    Dim o As Folder
    Dim i As Long
    For Each o In FSO.Getfolder(seName).SubFolders
        Let i = i + 1
        Cells(i, 1).Value = o.path
    Next
End Sub

参考＞＞
FileSystemObjectの参照設定を行う

注意点
1)シートの0行目はないので、必ず行番号に使う変数は何か代入してから、
セルを指定する。

2）ループの中で変数を宣言しない。
1度すればいいことを何度もするのは無駄。
ループの回数が多いと処理速度にも影響するかも？

3）なんとなーくでコードを書かない
Cells(i, 1)
とか
= k
とか、
Dim k As Object
とか
Sub ステータス確認(sename)
とか、

つまりたまたま上手く行ったが意味が解ってないままだと、
応用が利きにくいです。
省略が許されているので、書かないというのもありだけど、
自分の意図をコードにはっきり書くことをお勧めします。
現状、「こういう時はこう書く」と単に暗記されているように
見受けました。

例えば、
＞Cells(i, 1).Value = o.path
フォルダー「O」のパスをセルの値に設定

そうすれば、変数の型がなんでないといけないかも、
イメージしやすいかと思います。

4）ユーザーにVBEの画面を見させないよう注意する
FSO.Getfolder(seName)
変数に存在しないフォルダーのパスを指定した場合エラーになります。
勝手にフォルダーを削除された、
無意識にフォルダーを移動した等

If FSO.FolderExists(seName) = False Then Exit Sub
と、最初に存在確認をしたら、エラーを回避できます。

FileSystemObjectオブジェクト - FolderExistsメソッド

あと、ステップインで実行しながら、
ローカルウィンドウで変数にどんな値が入っているか、
確認してください。
オブジェクト型の変数は情報が折りたたまれているので、
変数名の前の「+」をクリックして展開してみてください。
「オブジェクト」というもののイメージがわかるかも知れません。
プロパティ、メソッドの探り方 マクロ記録とＦ１のHelpを使う

Comments

[hatena19]

おおむね同感ですが、

> 2）ループの中で変数を宣言しない。
> 1度すればいいことを何度もするのは無駄。

ループの中に記述しても、宣言は1回だけしたことになります。
どこに記述しても一番最初に1回評価されます。

VBA 変数宣言はIfやFor等のコードブロック中に書いても機能する - t-hom’s diary
https://thom.hateblo.jp/entry/2018/06/02/185716

[mattuwan]

あ、情報の訂正ありがとうございます。

[ice930]

ご指摘の通り丸暗記している部分が多かった様に思います。
変数の変化などを確認しながら学習していきたいと思います。
ありがとうございました！

Answer 2

Option Explicit
Sub ステータス確認(sename)
Dim path As String
Dim fso As Object 'Scripting.FileSystemObject
Dim k As Object 'Scripting.Folder

path = ThisWorkbook.Path & "" & "写真格納ファイル" & "" & sename & ""
Set fso = CreateObject("Scripting.FileSystemObject")

For Each k In fso.Getfolder(path).SubFolders

Dim i As Long
Cells(i, 1) = k.Name
i = i + 1

Next
End Sub

Answer 3

Sub ステータス確認()
    Dim path As String
    Dim FSO As Object
    Dim k As Object

    path = ThisWorkbook.path & "\" & "写真格納ファイル" & "\" & sename & "\"
    Set FSO = CreateObject("Scripting.FileSystemObject")

    For Each k In FSO.GetFolder(path).SubFolders

        Dim i As Long ' Longに修正
        i = i + 1     ' こちらに移動
        Cells(i, 1) = k '=k.path ファイル名だけなら k.Name
     Next
End Sub