バッチを用いて、txtデータをカラム毎に改行したい

Question

バッチファイルで実現可能か、分からないのですが、、、

AA12345678BB12345678CC 2 4 6 8DD1 3 5 7 EE12345678

のようなtxtデータを

AA12345678
BB12345678
CC 2 4 6 8
DD1 3 5 7
EE12345678

と１０カラム毎に改行し、別txtへ出力する事は出来るのでしょうか？

ざっくりとした質問で申し訳ないですが、お願い致します。

Comments

[yambejp]

windowsのcmdですか？powershell?
WSHは想定していないですか？

[aki_matrix]

windowsのcmd（.batで作成する事）を想定していました。

Answer 1

可能かと言えば、概ね可能です。

@echo off
(
for /f "delims=" %%A in (in.txt) do call :SUB "%%~A"
)>out.txt
exit /b

:SUB
set "A=%~1"
echo=%A:~0,10%
echo=%A:~10,10%
echo=%A:~20,10%
echo=%A:~30,10%
echo=%A:~40,10%

ファイルの中身が英数字や一部の記号だと大丈夫ですが、"など一部の記号は駄目です。

#追記
長さを決めないとすると、

@echo off
setlocal enabledelayedexpansion
(
for /f "delims=" %%A in (in.txt) do call :SUB "%%~A"
)>out.txt
type out.txt
exit /b

:SUB
set "A=%~1"
set N=0
:LOOP
if "!A:~%N%,10!"=="" exit /b
echo=!A:~%N%,10!
set /a N+=10
goto LOOP

Comments

[aki_matrix]

回答ありがとうございます。
後出しになってしまうのですが、実際は確実に５行で終わるテキストデータでは無く、何行になるか分からないテキストデータを想定していました。
横に長いデータでも耐えうるパターンも作れるものなのでしょうか？

[otn]

途中に10文字以上連続した空白が無いのであれば、
簡単には、ひたすら書けば可能です。途中で終わることも考えると、
if not "%A:~40,10%"=="" echo=%A:~40,10%
みたいなのを必要なだけ書けばいいです。

ループで書く事も可能ですが。

[aki_matrix]

ありがとうございます！
テスト的に試した文字列では、上手く出力する事が出来ました。

実際に組み込もうとしたところ、上手く出力されなかった為、調査したところ、
「%」が含まれている文字列を対象とした場合、上手く出力出来ていない事が分かりました。
対象の文字列に%が含まれている場合は、batファイルでは、上手く処理が出来ないものなのでしょうか？

[otn]

そうですね。どうしようもないです。

[aki_matrix]

承知致しました。ありがとうございました！