ポインタ配列のPROGMEMの要素を変数を使って出したい

Question

###前提・実現したいこと
Arduinoのプログラムで、それぞれの配列の長さが違うのでポインタの配列を変数としてPROGMEM機能を使った際に思った通りになりませんでした。
どうすれば上手くいくのか、できないのであれば理由を教えていただけると幸いです。
下記のプログラムは例ですが、同じ問題が起こります。

###ソースコード

const int Array1[] PROGMEM = {1, 2};
const int Array2[] PROGMEM = {4, 8};
const int Array3[] PROGMEM = {16, 32};
const int Array4[] PROGMEM = {64, 128};
int *const Length[] PROGMEM = {Array1, Array2, Array3, Array4};

void setup() {
  Serial.begin(9600);
}

void loop() {
  for (int i = 0; i < 4; i++) {
    for (int j = 0; j < 2; j++) {
      Serial.println(pgm_read_byte(&(Length[i][j])));
    }
  }
  while (1);
}

###出力

12  //1のはずが…
65  //2のはずが…
239 //4のはずが…
224 //8のはずが…
12  //16のはずが…
65  //32のはずが…
12  //64のはずが…
65  //128のはずが…

###試したこと

######直接指定してみる

const int Array1[] PROGMEM = {1, 2};
const int Array2[] PROGMEM = {4, 8};
const int Array3[] PROGMEM = {16, 32};
const int Array4[] PROGMEM = {64, 128};
int *const Length[] PROGMEM = {Array1, Array2, Array3, Array4};

int const Length1[][2] PROGMEM = {
  {1, 2},
  {4, 8},
  {16, 32},
  {64, 128}
};

void setup() {
  Serial.begin(9600);
}

void loop() {
  Serial.println(pgm_read_byte(&(Length[0][0])));
  Serial.println(pgm_read_byte(&(Length[0][1])));
  Serial.println(pgm_read_byte(&(Length[1][0])));
  Serial.println(pgm_read_byte(&(Length[1][1])));
  Serial.println(pgm_read_byte(&(Length[2][0])));
  Serial.println(pgm_read_byte(&(Length[2][1])));
  Serial.println(pgm_read_byte(&(Length[3][0])));
  Serial.println(pgm_read_byte(&(Length[3][1])));
  while (1);
}

1
2
4
8
16
32
64
128//これだとうまくいくのはなぜなのか

###補足情報
Arduino 1.8.13
Arduino Uno を使っています。
よろしくお願いします。

Answer 1

「そういうもの」で満足ですか?

Length[]の宣言がconst int *const Length[] PROGMEM = {Array1, Array2, Array3, Array4};
配列がconst int[]なので読み出しがpgm_read_word()なのはともかく。

ソースコードをコンパイルしてアセンブルレベルで覗いてみたところ、

pgm_read_word(&Length[0][1])等のように直接指定した場合は、コンパイル時に定数に展開しています。つまり、ソースコード上&Length[0][1]と記述していても、これはLength[0]は定数Array1、&Length[0][1]は定数Array1+1としてコンパイルされています。結果、prg_read_word(&Length[0][1])は2を読み出すことになります。

一方、
pgm_read_word(&Length[i][j])と記述した場合は、Length[i]をRAMエリアに配置された配列(これを仮に変数(RAM)と表す)として*(Length(RAM)+i)の変数として求め、さらに*(Length(RAM)+i)(RAM)+jを今度はプログラムエリアのアドレスとして値を求める、ということになるようです。

ということで、
&Length[i]をプログラム領域として処理するよう明示的に指示してやる必要があって、結果
Serial.print(pgm_read_word(&((int*)pgm_read_ptr(&Length[i]))[j]));
で

1
2
4
8
<以下略>

が得られます。

Comments

[UMA821]

回答していただき、ありがとうございます。
なるほど、直接指定した場合には勝手に置き換わっているのですね、納得しました。
そしてプログラム領域から読み取るpgm_read_ptr()というものは知りませんでした。
疑問が解消しました、ありがとうございます！

[thkana]

pgm_read_ptr()は私も知っていたわけではないのですが、この件で検索していると出てくるavr/pgmspace.hを覗いていたらあったので使ってみました。

あなたにとって「ベスト」であった回答をベストアンサーに選んで下さいね。一度選んだベストアンサーの取り消し/選び直しも出来るようになっています。

Answer 2

AVR（ATMega328）では、フラッシュメモリとRAMは独立していて別のメモリとしてアクセスされます
PROGMEMを指すポインタ/アドレスは使用できません。

Arduino 日本語リファレンス

Comments

[UMA821]

回答していただき、ありがとうございます。
やはりきちんと配列の配列で宣言するほかなさそうですね。
ではどうして直接指定した場合にはうまく働いているように見えるのでしょうか、教えていただけると幸いです。

[y_waiwai]

そういうもの、としかいいようがないです
コンパイラはGCCなんだから、ご自分でポインタ使えるように修正すればどうでしょう。

[UMA821]

そういうものなんですか…がんばってみます。