ExcelのVBAでURLDownloadToFile関数を使ってファイルを保存したいのですが ファイルが壊れてしまい上手くいきません

Question

ExcelのVBAでURLDownloadToFile関数を使ってファイルを保存したいのですが
ファイルが壊れてしまい上手くいきません。。

ExcelのA列にtitleを、B列にダウンロード先のリンク、C列に判定を返したいと思っています。
リンク先はdropbox等です。

titleは「数字.pdf」など格納されているファイルに応じて拡張子をつけています。
（dropboxに格納されているフォルダはJPGやPDF等、拡張子がバラバラに入っているので、もしも良い方法があればご教示いただけると嬉しいです。またはフォルダごと落とせたら最高なのですが。。）
何卒よろしくお願いいたします。

Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" _
Alias "URLDownloadToFileA" (ByVal pCaller As Long, _
ByVal szURL As String, ByVal szFileName As String, _
ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long

Dim Ret As Long

'保存フォルダー
Const FolderName As String = "c:\test"

Sub DownloadFileFromURL()
Dim ws As Worksheet
Dim LastRow As Long, i As Long
Dim strPath As String

'シート名
Set ws = Sheets("Sheet1")

'最終行
LastRow = ws.Range("A" & Rows.Count).End(xlUp).Row

For i = 2 To LastRow '2行目から
    strPath = FolderName & ws.Range("A" & i).Value

    Ret = URLDownloadToFile(0, ws.Range("B" & i).Value, strPath, 0, 0)

    If Ret = 0 Then
        ws.Range("C" & i).Value = "成功"
    Else
        ws.Range("C" & i).Value = "失敗"
    End If
Next i

End Sub

Answer 1

dropbox以外のブログなどで画像などでダウンロードできることを確認しました。
dropboxでは、直接URLを指定しダウンロードする前に、ログイン認証に相当する手順が
必要なのではないでしょうか？
（壊れていると思われるファイルに、実際にはエラーページの内容が保存されているとか）

URL末尾からファイル名を取るようにしたコードについて、参考までに記載します。

Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" _
Alias "URLDownloadToFileA" (ByVal pCaller As Long, _
ByVal szURL As String, ByVal szFileName As String, _
ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long


Dim Ret As Long

'保存フォルダー
Const FolderName As String = "c:\test\"

Sub DownloadFileFromURL()
  Dim ws As Worksheet
  Dim LastRow As Long, i As Long
  Dim strPath As String
  
  'シート名
  Set ws = Sheets("Sheet1")
    
  '最終行
  'A列ではなくB列を見るようにする
  LastRow = ws.Range("B" & Rows.Count).End(xlUp).Row
  
  Dim fileName1 As String
  Dim urlToDL As String
  
  For i = 2 To LastRow '2行目から
      urlToDL = ws.Range("B" & i).Value
      fileName1 = getBaseName(urlToDL)
      If fileName1 = "" Then
          ws.Range("C" & i).Value = "ファイル名の取得に失敗"
          Exit Sub
      End If
      strPath = FolderName & fileName1
      Ret = URLDownloadToFile(0, urlToDL, strPath, 0, 0)
      
      If Ret = 0 Then
          ws.Range("C" & i).Value = "成功"
      Else
          ws.Range("C" & i).Value = "失敗"
      End If
  Next i

  '変数を解放しておく
  Set ws = Nothing
  
End Sub

'/を含む Urlからファイル名を返す
Public Static Function getBaseName(s As String) As String
    If s = "" Then
        getBaseName = ""
        Exit Function
    ElseIf InStr(s, "/") < 1 Then
        getBaseName = ""
        Exit Function
    End If
    
    Dim delimited As Variant
    delimited = Split(s, "/")
    getBaseName = delimited(UBound(delimited))
    
End Function

Comments

[nobu0377]

ありがとうございます。確かにログイン認証の手順が必要そうですね。また、sampleもありがとうございます。活用させていただきます！