VBAでMySQLに接続して、エクセルファイルのシートにデータを抽出したい

Question

前提・実現したいこと

VBAでMySQLに接続して、エクセルファイルのシートにデータを取得したいのですが、
エラーが出てしまい、解決方法がわかりません。
アドバイスをいただけませんでしょうか。

現状としては、
・MySQLに接続は出来ました
・テーブル作成、データ登録は出来ました
・DBからデータを取得して【mysql_odbc】シートに表示させることが出来ません
※実行した際に「CommandオブジェクトのCommandText設定されていません」とエラーが表示され、解決できません。

どうぞ、よろしくお願いいたします。

発生している問題・エラーメッセージ

実行時エラー '-2147217908(80040e0c)';
CommandオブジェクトのCommandText設定されていません。

該当のソースコード

Option Explicit

Sub db()

    Const MYDRIVER = "Driver={MySQL ODBC 5.3 Unicode Driver};"      'ドライバー
    Const MYSERVER = "Server=localhost;"                            'サーバー
    Const MYPORT = "Port=3306;"                                     'ポート
    Const MYDATABASE = "Database=*****;"                           'データベース名
    Const MYCCODE = "STMT=SET NAMES sjis;"                          '文字コード（Excel側）
    Const MYUSER = "UID=root;"                                    'ユーザー名
    Const MYPASS = "PWD=******;"                                    'パスワード
 
    Dim cn As New ADODB.Connection
    Dim rs As New ADODB.Recordset
    Dim constr As String
    Dim strSQL As String
    Dim i As Long
    Dim j As Long
    Dim CMD As ADODB.Command
            
    constr = MYDRIVER & MYSERVER & MYPORT & MYDATABASE & MYCCODE & MYUSER & MYPASS
    
    cn.ConnectionString = constr
    cn.Open
    
    テーブル作成
    strSQL = "Create Table 西暦和暦(" & _
             "始期 nchar(8)," & _
             "元号 nchar(5));"
    rs.Source = strSQL
    rs.ActiveConnection = cn
    'Set rs = New ADODB.Command
    'rs.CommandText = "SELECT * FROM 西暦和暦;"
    rs.Open
    
    'データ追加
    strSQL = "insert into 西暦和暦 values " & _
             "('20190501', '令和'), " & _
             "('19890108', '平成'), " & _
             "('19261225', '昭和'), " & _
             "('19120730', '大正'), " & _
             "('18680908', '明治');"
    rs.Source = strSQL
    rs.Open
    
    'データ表示
    With Worksheets("mysql_odbc")
        .Cells.Clear
        i = 1
        Do Until rs.EOF
           For j = 0 To rs.Fields.Count - 1
                If i = 1 Then .Cells(i, j + 1) = rs.Fields(j).Name
                .Cells(i + 1, j + 1) = rs(j).Value
                .Cells(i + 1, j + 1).Errors(xlNumberAsText).Ignore = True
            Next j
            rs.MoveNext
            i = i + 1
        Loop
    End With
    
    rs.Close
    Set rs = Nothing
    cn.Close
    Set cn = Nothing
    
End Sub

Answer 1

'データ表示
With Worksheets("mysql_odbc")
この前に下記を追加してみて下さい。

strSQL = "SELECT * FROM 西暦和暦;"
rs.Open strSQL, cn, adOpenDynamic, adLockOptimistic

Comments

[shogakusha]

ありがとうございます。
エラー解消されました。
なぜエラー解消されたかはわからないので、調べてみます。
ありがとうございました。