VBA(Access)におけるイベント実装を機能毎に分割する方法についてご相談です。

Question

前提・実現したいこと

言語:
VBA(Access2016)

実現したいこと:

• 1 Access.TextBoxに対して共通のイベント処理を実装したい。
• 2 機能毎に実装するクラスを分割したい。
  (テキストボックス毎に機能を付け外ししたい)

Access.TextBoxを複数のInterface実装クラスのメンバに持たせ、
その各実装クラスをInterface型の配列に格納すれば
一つのテキストボックスのイベントを同時に拾えるのではないかと考えて
以下のコードを作成してみたところ、
想定していたような動作をしてはいるのですが、
何か問題になりそうな箇所はありますでしょうか。

尚、下記のコードは以下のような想定で作成しました。
MyTextBoxクラスが基本機能を提供するクラス
NumberCheckTextBoxクラスが入力値が数値かどうかをチェックする機能を提供するクラス
RequiredTextBoxクラスが入力必須項目であるかどうかを判定し、画面上の挙動を変更するクラス

該当のソースコード

IControl クラス

Public Sub TestSub()
End Sub

IControl_MyTextBoxクラス

Implements IControl

Private WithEvents m_TextBox As Access.TextBox
Public Sub IControl_TestSub()
    Debug.Print "IControl_MyTextBox_TestSub!"
End Sub
Private Sub m_TextBox_Click()
    Debug.Print "IControl_MyTextBox_OnClick!"
End Sub
Public Sub Initialize(value As Access.TextBox)
    Set m_TextBox = value
    m_TextBox.OnClick = "[EVENT PROCEDURE]"
End Sub

IControl_NumberCheckTextBoxクラス

Implements IControl

Private WithEvents m_TextBox As Access.TextBox

Public Sub IControl_TestSub()
    Debug.Print "IControl_RequiredTextBox_TestSub!"
End Sub

Private Sub m_TextBox_Click()
    Debug.Print "IControl_NumberCheckTextBox_OnClick!"
End Sub

Public Sub Initialize(value As Access.TextBox)
    Set m_TextBox = value
End Sub

IControl_RequiredTextBoxクラス

Implements IControl

Private WithEvents m_TextBox As Access.TextBox

Public Sub IControl_TestSub()
    Debug.Print "IControl_RequiredTextBox_TestSub!"
End Sub

Private Sub m_TextBox_Click()
    Debug.Print "IControl_RequiredTextBox_OnClick!"
End Sub

Public Sub Initialize(value As Access.TextBox)
    Set m_TextBox = value
End Sub

テスト用フォーム (Me.txtはフォーム上に配置されたテキストボックスです)

Private TestTextBox(2) As IControl

Private Sub Form_Open(Cancel As Integer)
    Dim myText As IControl_MyTextBox
    Set myText = New IControl_MyTextBox
    myText.Initialize Me.txt
    
    Dim myRequired As IControl_RequiredTextBox
    Set myRequired = New IControl_RequiredTextBox
    myRequired.Initialize Me.txt
    
    Dim myNumberCheck As IControl_NumberCheckTextBox
    Set myNumberCheck = New IControl_NumberCheckTextBox
    myNumberCheck.Initialize Me.txt
    
    Set TestTextBox(0) = myText
    Set TestTextBox(1) = myRequired
    Set TestTextBox(2) = myNumberCheck
End Sub

試したこと

上記のコードを実行し
フォーム上のテキストボックスをクリックすると
イミディエイトウィンドウに以下の文字列が出力されました。

IControl_MyTextBox_OnClick!
IControl_RequiredTextBox_OnClick!
IControl_NumberCheckTextBox_OnClick!

補足情報（FW/ツールのバージョンなど）

言語:VBA(Access2016 32bit)

Answer 1

そういうことに関しては一度擬似からの脱却を読むことをオヌヌメ。

問題点としてはリンク内にもありますが「フォーム側にイベントを書けないこと」です。
クラス側にロジックのすべてを実装することになり「条件分岐」がしにくいので
結局「その画面専用クラス」になりやすいです。配列にWithEventsを書けない問題点は
上記リンクで改善方法が書いてあります。

問題点ではないですがもう一つやり方があって
フォームのVBAのPrivate Functionなどはコントロールから直接Callできる
ということです。そこまで大仰なことをしないでもいいかもしれません。
ただ「基本機能を提供し、さらに入力必須項目を」というような「重ね掛け」は
うまくやらないとできないかもしれません。

こうして

こう。

直接関係ないですがそこまでやるんなら

IConstructorクラス作って

Public Function Init(ByVal Args As Variant) As Boolean

End Function

標準モジュールにfunction書いて

Public Function Init(ClassObject As IConstructor, ParamArray Args() As Variant) As IConstructor
    Call ClassObject.Init(Args)
    Set Init = ClassObject
End Function

クラスでIConstructorをImplementsして

Implements IControl
Implements IConstructor

Private WithEvents m_TextBox As Access.TextBox

' Initiarizeの代わり
Private Function IConstructor_Init(ByVal Args As Variant) As Boolean
    Set m_TextBox = Args(0)
    m_TextBox.OnClick = "[EVENT PROCEDURE]"
End Function

Public Sub IControl_TestSub()
    Debug.Print "IControl_MyTextBox_TestSub!"
End Sub

Private Sub m_TextBox_Click()
    Debug.Print "IControl_MyTextBox_OnClick!"
End Sub

フォーム側

Private TestTextBox(2) As IControl

Private Sub Form_Open(Cancel As Integer)
'    Dim myText As IControl_MyTextBox
'    Set myText = New IControl_MyTextBox
'    myText.Initialize Me.txt

    ' 上3行が１行に！初期化の引数も初期化ロジックもクラス側に書けるしかっこいい、それだけ
    Set TestTextBox(0) = Init(New IControl_MyTextBox, Me.txt)

'    Dim myRequired As IControl_RequiredTextBox
'    Set myRequired = New IControl_RequiredTextBox
'    myRequired.Initialize Me.txt
'
'    Dim myNumberCheck As IControl_NumberCheckTextBox
'    Set myNumberCheck = New IControl_NumberCheckTextBox
'    myNumberCheck.Initialize Me.txt
'
'    Set TestTextBox(0) = myText
'    Set TestTextBox(1) = myRequired
'    Set TestTextBox(2) = myNumberCheck
End Sub

VBAはオブジェクトの破棄に参照カウント制を使っているといわれています。
相互参照がされると永続的に破棄されない状態になる場合もあるので

Set obj = Nothing

はしっかり意識したほうがメモリリークしないでいい…かも。

Comments

[kanntyuu]

回答ありがとうございます。
確かにフォーム側にイベント記述がなくなってしまうのは問題かも知れません。
別の人がメンテする際混乱しそうですしね...。

紹介頂いた[疑似からの脱却]をざっと読んでみましたが、
こちらで紹介されている手法であれば、
クラス数の爆発も避けられそうな気がしますので、
もう少ししっかり読み込んでみます。

2つ目の方法についても
単純な処理であれば利用できそうなので
参考にさせて頂きます。

回答ありがとうございました。

[sousuke]

質問者さんはvbaは初心者っぽいのですが考え方が完全に他の言語のそれな気がしますね～
擬似からの脱却を使う時点で別の人のメンテはほぼ諦めたほうがいいかもしれません…
VBAで作ってあるから！って言われてこのコード見せられたら沈黙しそう笑

私が使っているコンストラクタのメソッドも提示しておきますね。ﾅｶｰﾏ

[kanntyuu]

なるほど...。
コンストラクタ自体ををInterfaceとしてしまうのは思い付きませんでした。
毎回インスタンスの初期化をするだけで3行も書かないといけないのは
見栄え上もあまり綺麗ではないなぁと思いながら
何か方法が無いのかと悩んでおりましたので非常に勉強になりました。

また、オブジェクト破棄のタイミングを参照カウント制で判断しているのであれば
終了処理のNothingを意識したほうが良いですね...。
つい忘れがちなので気を付けたいと思います。

VBAにおけるクラスモジュールを使用する実装例というのは
Web上でもあまり見かけない上、
私自身、周囲にこういった質問が出来る人がおりませんので
本当に助かりました。
ありがとうございます。

また何か分からないことがありましたら
質問させて頂ければ幸いです。