オーバーフローのエラーを消したい

Question

前提・実現したいこと

この写真のような出力ができるコードを書いています

発生している問題・エラーメッセージ

実行時エラー'6':
オーバーフローしました。

と
intRowCnt = Range("B1").End(xlDown).Row + 1
にエラーが出てしまいます

該当のソースコード

Option Explicit

Sub main()
    '＝＝＝＝＝宣言＝＝＝＝＝＝
    Dim objIE As InternetExplorer
    Dim strUrl As String
    Dim intRowCnt As Integer
    Dim objLink As Variant
    Dim bLoopEnd As Boolean
    Dim htmlDoc As HTMLDocument
    Dim Lists As Variant
    Dim rng As Range
    
    
    
        
    Application.OnTime Now() + TimeValue("00:01:00"), "main"
    
    Range("B1") = "スポーツ"
    
    Range("C1") = "自然哲学"
    
    Range("D1") = "健康法"
    
    strUrl = "https://www.amazon.co.jp/dp/4910001050"
    
    Call getpage(objIE, strUrl)
    
    Set htmlDoc = objIE.document
   
    intRowCnt = Range("B1").End(xlDown).Row + 1
    
    Call WaitResponse(objIE)
    Call set_webdata(objIE, intRowCnt)
        
End Sub

Sub set_webdata(objIE As InternetExplorer, rowcnt As Integer)

    With objIE.document
        Cells(rowcnt, 1).Value = Now
        Cells(rowcnt, 2).Value = .getElementsByClassName("zg_hrsr_rank")(0).innerHTML
        Cells(rowcnt, 3).Value = .getElementsByClassName("zg_hrsr_rank")(1).innerHTML
        Cells(rowcnt, 4).Value = .getElementsByClassName("zg_hrsr_rank")(2).innerHTML
    End With

End Sub

Sub getpage(ByRef objIE As Object, strUrl As String)

    Set objIE = CreateObject("Internetexplorer.Application")
    
    objIE.Visible = True
    
    objIE.navigate (strUrl)
    
    Call WaitResponse(objIE)
    
End Sub
Sub WaitResponse(objIE As Object)

    Do While objIE.Busy = True Or objIE.readyState < READYSTATE_COMPLETE
        DoEvents
    Loop
End Sub

補足情報（FW/ツールのバージョンなど）

ofice365 標準モジュール

Answer 1

Dim intRowCnt As Integer

を

Dim intRowCnt As Long

に変更することで解決します
(変数の命名規則が変ですので、それも修正したほうがいいかと)

Comments

[admn]

それに変更すると
Call set_webdata(objIE, intRowCnt)
にコンパイルエラーByRefの型が一致しませんと出てしまいます。

[admn]

Sub set_webdata(objIE As InternetExplorer, rowcnt As Long)に直したら先ほど質問したコンパイルエラーは出なくなりましたが
Cells(rowcnt, 1).Value = Now
に実行時エラー’１００４’：アプリケーション定義またはオブジェクト定義のエラーですと出てしまいます、どうすればいいでしょうか。

Answer 2

現状では2行目のデータがない場合、最下行+1が選択されるのでエラーになります。
こちらではいかがでしょうか。

intRowCnt = Cells(Rows.Count, 2).End(xlUp).Row+1

Comments

[admn]

回答ありがとうございます。

Answer 3

すみません、私の回答が不十分でしたね。
以下に置き換えてください。

intRowCnt = Cells(Rows.Count, 1).End(xlUp).Row + 1

Comments

[admn]

すいませんこのサイトを使うのが初めてだったので新しい質問は新規で立ち上げた方がいいのかと思ってこのようにしました。わかりやすかったです

[admn]

ありがとうございます！しっかりと動きました！

[ttyp03]

この件だけで言えば、前の質問のコメントでやりとりした方がよかったですね。
本来なら最終行の取得方法として質問を立ち上げるのがベストですが、まったくわからないと丸投げになってしまい良くない評価がつきますので、ご注意を。

[admn]

わかりましたほかの人のものも見てこのサイトの利用のモラルを学んできます。今回は親切にありがとうございました。