【ACCESS】VBAでリンクテーブルのリンク先を変更したい

Question

accessVBAを使い、リンクテーブルのリンク先を変更したいです。
現在調べながら下記のようなコードを書いておりますが、設定ができません。
途中で止めてltb.Connectの部分をマウスオーバーして見てみてると、
＜オブジェクトが正しくないか、現在設定されていません。＞
と表示されます。
どうしたら解決できるのでしょうか。
ちなみにエラーは出ずに最後まで動くが設定はされていないという状況です。

    If fpath <> "" Then
        Dim ltb As DAO.TableDef
        Dim ltbnm As String
        ltbnm = "hoge"
        Set ltb = CurrentDb.TableDefs(ltbnm)
        ltb.Connect = ";DATABASE=" & fpath & ";TABLE=" & ltbnm
        ltb.RefreshLink
        MsgBox fpath & "にリンク先を変更しました"
    End If

Comments

[sazi]

fpathに正しくフルパスが格納されているのは確認していますか？

[kakerukyun]

ありがとうございます。
確認しましたが正しく格納されていました。
気になったのは、参考にしたサイトではリンク先のaccessファイルが拡張子.mdbだったのですが、
私の方では.accdbを指定しています。
もしかしてこれが悪いのでしょうか。

[sazi]

拡張子は関係ありません。

Answer 1

fpathが正しくフルパスなのを前提に、以下の様に変更してデバッグしてみて下さい。

    If fpath <> "" Then
        Dim ltb As DAO.TableDef
        Dim ltbnm As String
        ltbnm = "hoge"
        Set ltb = CurrentDb.TableDefs(ltbnm)
        If ltb.Attributes And dbAttachedTable Then
          ltb.Connect = ";DATABASE=" & fpath
          ltb.RefreshLink
          MsgBox fpath & "にリンク先を変更しました"
        End If
    End If

Comments

[kakerukyun]

ありがとうございます。
fpathはフルパスで格納されていることを確認しました。
ご提示の通りにしてみたのですが、設定できませんでした。
今回もltb.Attributesやltb.Connectにマウスオーバーすると
＜オブジェクトが正しくないか、現在設定されていません。＞
と表示されました。

Answer 2

下記で動作することを確認しました。

    If fpath <> "" Then
        Dim db As DAO.Database
        Set db = CurrentDb
        
        Dim ltb As DAO.TableDef
        Dim ltbnm As String
        ltbnm = "hoge"
        Set ltb = db.TableDefs(ltbnm)
        ltb.Connect = ";DATABASE=" & fpath
        ltb.RefreshLink
        MsgBox fpath & "にリンク先を変更しました"
    End If

CurrentDb をいったん変数に格納してそれを使用する必要があるようです。

Comments

[kakerukyun]

ありがとうございます。
試してみたのですが設定できませんでした。

[hatena19]

サンプルでテストしてみたら同じエラーがでたので、いろいろトライして解決できました。回答を修正しましたので、参照ください。

[kakerukyun]

ありがとうございます。
currentDbを変数に格納してみたら設定できました。
お世話になりました。