ユーザーフォームからの自動実行時と、VBA画面でのステップイン実行では挙動が違ってしまいます。

Question

前提・実現したいこと

Excelで作った集計表を印刷するため、
データテーブルにフィルターを掛ける前後で別々の印刷設定をしています。
フィルター後用の設定は問題なく適用されているのですが、
フィルター解除状態用の設定(フィルター状態をリセットしたあとに、印刷設定を元に戻すための設定)では
ヘッダー設定が適用されていません。
フィルター後用の設定が生きたままになっていしまいます。

ところが、VBA画面でF8を押しながらステップ実行していくと
しっかりフィルター解除状態用の設定が適用されています。

こうなってしまう原因と、解決方法がわかりません。
とにかく、自動実行時にフィルター解除状態用の設定が適用されるようにしたいです。
(ヘッダーの設定を初期化したいです)

ご協力お願いします。

該当のソースコード

Sub 印刷設定()
    On Error Resume Next
    ActiveSheet.PageSetup.LeftHeader = ""
    Application.PrintCommunication = False
    With ActiveWorkbook.ActiveSheet.PageSetup
        .LeftMargin = Application.CentimetersToPoints(2)
        .RightMargin = Application.CentimetersToPoints(2)
        .TopMargin = Application.CentimetersToPoints(4)
        .BottomMargin = Application.CentimetersToPoints(0)
        .HeaderMargin = Application.CentimetersToPoints(2.5)  
        .FooterMargin = Application.CentimetersToPoints(0)
        .PrintTitleRows = "$4:$4"
        .Zoom = 50                      
        .PaperSize = xlPaperA4         
        .BlackAndWhite = False          
        .Orientation = xlPortrait       
        .CenterHorizontally = False     
        .LeftHeader = "抽出条件" & Chr(10) & _　　　　　　　　　　　　'←このヘッダー設定は問題なく適用されます
                      "　氏名：" & name_input.Value & _
                      "　　№：" & const_num_input.Value & _
                      "　件名：" & const_name_input.Value & Chr(10) & _
                      "　期間：" & stdate & " ～ " & cldate
        .CenterHeader = Range("A1").Value & Chr(10) & "&P/&N"
        .RightHeader = "　分析" & Chr(10) & _
                      "カウント：" & day_counter.Caption & _
                      anlz
    End With
    Application.PrintCommunication = True
End Sub
'

Sub 印刷設定リセット()
    ActiveSheet.PageSetup.PrintArea = Range("データテーブル名").Address
    ActiveSheet.PageSetup.LeftHeader = ""
    Application.PrintCommunication = False
    With ActiveWorkbook.ActiveSheet.PageSetup
        .LeftHeader = ""　　　　　　　　　　　　　　　　　　　　　　　'←ここでヘッダー表示を空白に戻したいのですが、それが自動実行だと適用されません。
        .CenterHeader = "データテーブル名" & Chr(10) & "&P/&N"
        .RightHeader = ""
        .LeftMargin = Application.InchesToPoints(0.78740157480315)
        .RightMargin = Application.InchesToPoints(0.78740157480315)
        .TopMargin = Application.InchesToPoints(1.5748031496063)
        .BottomMargin = Application.InchesToPoints(0)
        .HeaderMargin = Application.InchesToPoints(0.984251968503937)
        .FooterMargin = Application.InchesToPoints(0)
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = False
        .PrintTitleRows = "$4:$4"
        .PaperSize = xlPaperA3      
        .BlackAndWhite = False      
        .Orientation = xlLandscape  
        .CenterHorizontally = True 
    End With
    Application.PrintCommunication = True
End Sub

Comments

[kenshirou]

この処理を行う間に、ActiveSheetが変わることはないですか？
例えば、別シートの内容を参照するために、別シートがActiveになってしまうようなことがあれば、別シートに対して設定が行われてしまいます。

[ats1]

はい。ActiveSheetが変わることはありません。
実は、上記のソースコードで
.RightHeader = ""
としているところを、試しに
.RightHeader = "(任意の値)"
に変更してみたところ、この右ヘッダーに変更が適用されるんです。
しかし、空白で上書きしようとするとそれができず、
ついでにいうと左ヘッダーに関しては右ヘッダーのような任意の値での上書きすらできない状態です。

乱暴な言い方になりますが、正直もうわけがわかりません。

ご教授ありがとうございました。

[kenshirou]

フィルタ設定・印刷設定・印刷・フィルタ解除・印刷設定解除がどのような流れで行われているかは分かりませんが、例えば、印刷設定解除を一連の処理では行わず、一呼吸おいてから印刷設定解除処理を行うとどうなるのでしょうか？
（例えば印刷設定解除を呼び出すボタンを用意して、適当なタイミングでボタン押下）

[ats1]

回答ありがとうございます。
ご指摘のとおりに、印刷設定解除処理を別タイミングで行うようにしたとき、今度はなぜか左ヘッダーだけが空白になりました…

というところで、この左ヘッダーの空白化設定だけが
withステートメントの前、
というよりは.PrintCommunication = Falseを行う前に書かれていることに気づき、色々試しました。

結果、解決することができました。
どうやら.PrintCommunication = trueの状態でないとヘッダーの設定のリセット(空白化)がうまく行かないらしいです…
どうしてこういうことになるのかはわからないです…

とりあえず、自分の意図していた動きをするようにはなりました。
ご協力感謝します。ありがとうございました。

[kenshirou]

解決したようで、良かったです。(^^)/

Answer 1

自己解決の形で処理してしまいすみません。
kenshirouさま、mattuwanさま、指示と回答をありがとうございました。

ヘッダーの空白化設定は、
.printcomunication = true　の状態でないと処理されないみたいです。

なぜこうなるのかはわかりませんが、上記のコードのヘッダー設定の部分だけ
.printcomunication = true　の記述の後の行に移動したら
上手く設定されるようになりました。

みなさん、本当にありがとうございました。

Answer 2

ところが、VBA画面でF8を押しながらステップ実行していくと
しっかりフィルター解除状態用の設定が適用されています。

印刷のページ設定は手動でやってわかると思いますが、
重いです。
なのでVBAで次々と命令を出していくと、
ページ設定の処理が終わる前に、次々命令が出されても
処理が追い付かないかと思います。
ステップ実行だと、ゆっくり、1行1行実行して結果を見ながら
実行していくので不具合がないのでしょう。
WaitやSleep等で少し待ってあげてはいかがでしょう？

それか、フィルターオプションでデータを別のシートに抽出して
そちらはそちらで印刷のページ設定をしておけば、
設定を頻繁に変える必要がなくなると思います。

Comments

[ats1]

ご回答ありがとうございます。
早速、作成中のVBAでwaitメソッドとsleepメソッドを試してみましたが
残念ながら相変わらずページ設定はリセットされませんでした。

フィルターオプションを利用する方法なら、確かに確実ですね。
ただ、シート管理が複雑になる可能性が考えられるので実際にその方法で対応するのは
最終手段にしておこうかと考えております。
ありがとうございました。