accessのvbaでSQLを実行するがうまく動かない。

Question

前提・実現したいこと`````

accessのクエリーをSQLに変更しているのですが、rs.open mySQL3はうまく動くのですが、
rs2.open mySQL5 がスルーしてしまします。
SQLの書き方に問題があるのでしょうか。

エラーメッセージ
表示なし　スルーして終了

### 該当のソースコード

access vba

Sub Sample1()

    Dim cn     As New ADODB.Connection
    Dim rs     As New ADODB.Recordset
    Dim rs2    As New ADODB.Recordset
    Dim mySQL  As String
    Dim mySQL2 As String
    Dim mySQL3 As String
    Dim mySQL4 As String
    Dim mySQL5 As String
    Dim mySQL6 As String
    
    
    Set cn = CurrentProject.Connection
    Set rs = New ADODB.Recordset
    Set rs2 = New ADODB.Recordset
    
    mySQL = "SELECT T_stock.発注Ｎｏ FROM T_stock GROUP BY T_stock.発注Ｎｏ;"
    mySQL2 = "SELECT '400000' AS 発注会社コード, '400000' AS 発注担当者コード, [T_stock]!発注Ｎｏ AS 伝票番号, '0' AS 配送区分, [T_stock]!納期日 AS 希望納期, '1' AS 納期区分, '1' AS [AM/PM区分], '' AS 納地コード, [T_stock]!送付先郵便番号 AS 納入先郵便番号, [T_stock]!送付先住所 AS 納地住所１, '' AS 納地住所２, [T_stock]!送付先事業所 AS 納入先名称, [T_stock]!連絡先電話番号 AS 電話番号, '' AS FAX番号, '' AS 携帯電話番号, [T_stock]!工事コード AS 工事番号, [T_stock]!工事名 AS 工事名称, [T_stock]![荷受人名] AS 納入先責任者名, '' AS 協力会社名称１, '' AS 協力会社名称２, '' AS 全体備考, Count([T_stock]!行) AS 明細レコード数 FROM T_stock Group BY '400014', [T_stock]!発注Ｎｏ, '0', [T_stock]!納期日, '1', [T_stock]!送付先郵便番号, [T_stock]!送付先住所, [T_stock]!送付先事業所, [T_stock]!連絡先電話番号, [T_stock]!工事コード, [T_stock]!工事名, [T_stock]![荷受人名], '', '400014', '1', '', '', '', '', '', '' "
    mySQL3 = mySQL2 & "like (([T_stock]!発注Ｎｏ)='mySQL');"
    mySQL4 = "SELECT T_stock.発注Ｎｏ FROM T_stock GROUP BY T_stock.発注Ｎｏ;"
    mySQL5 = "SELECT T_stock.発注Ｎｏ, T_stock.商品コード, '' AS 商品名称, Format([T_stock]!発注数量,'.00') AS 注文数量, '' AS ab長, '' AS 注文単価, '' AS 注文単位, '' AS 注文時明細行, '' AS 備考 FROM T_stock where (([T_stock]!発注Ｎｏ)='mySQL');"
   
    
    rs.Open mySQL3, cn, adOpenKeyset, adLockOptimistic

    Do Until rs.EOF
            
        Debug.Print rs!伝票番号 & "," & rs!納入先名称
            
            rs2.Open mySQL5, cn, adOpenKeyset, adLockOptimistic
                Do Until rs2.EOF
            
                Debug.Print rs2!希望納期 & "," & rs2!納入先郵便番号
            
                rs2.MoveNext
            
                Loop
            rs2.Close
                  
        rs.MoveNext
        
    Loop

    rs.Close



End Sub

試したこと

mySQL5のmySQLを実値にすると動きます。

補足情報（FW/ツールのバージョンなど）

os:win10 Access2013

Answer 1

mySQL5のmySQLを実値にすると動きます。

下記の部分ですね。

mySQL5 = "SELECT ・・・  where (([T_stock]!発注Ｎｏ)='mySQL');"  

これは、発注Ｎｏ が "mySQL"というテキストのレコードを抽出することになりますが、やりたいことはそういうことではないでよすね。当然、"mySQL"というレコードがなければ何も出力されません。

mySQL = "SELECT T_stock.発注Ｎｏ FROM T_stock GROUP BY T_stock.発注Ｎｏ;"  

このSQLの結果をmySQL5 の抽出条件にしたいということでしょうか。
だとしたら、下記のようなサブクエリにする必要があります。

mySQL = "SELECT T_stock.発注Ｎｏ FROM T_stock GROUP BY T_stock.発注Ｎｏ"
  
mySQL5 = "SELECT ・・・  where (([T_stock]!発注Ｎｏ) In (" & mySQL & ");"  

しかし、これも無意味な処理ですね。mySQLの処理は T_stock の発注Ｎｏをすべて出力するということになります。それを mySQL5 の抽出条件にしたら全レコードを出力するとこになりますので、抽出条件の意味がありません。

ざっとみて、他にも矛盾しているところがあります。
何をしたいのかもう一度整理して、ロジックを組みなおした方がいいと思います。

Answer 2

生成されたSQL文字列をクエリーデザインに張り付けて実行してみてください。

そのクエリーで動作確認されたもののSQLをコードにリバースして下さい。

※SQLの内容は意味不明で理解できません。

追記

多分以下の様な事がしたいのだと思います。

Sub Sample1()

Dim cn     As New ADODB.Connection
Dim rs     As New ADODB.Recordset
Dim rs2    As New ADODB.Recordset
Dim mySQL  As String
Dim mySQL2 As String

Set cn = CurrentProject.Connection
Set rs = New ADODB.Recordset
Set rs2 = New ADODB.Recordset

mySQL = "SELECT 発注Ｎｏ, Count(行) AS 明細レコード数 FROM T_stock Group BY 発注Ｎｏ"
rs.Open mySQL, cn, adOpenKeyset, adLockOptimistic
Do Until rs.EOF
  Debug.Print rs!発注Ｎｏ
  mySQL2 = "SELECT * FROM T_stock where 発注Ｎｏ='" & rs!発注No & "'"
  rs2.Open mySQL2, cn, adOpenKeyset, adLockOptimistic
  Do Until rs2.EOF
    Debug.Print rs2!納期日 & "," & rs2!送付先郵便番号
    rs2.MoveNext
  Loop
  rs2.Close
  rs.MoveNext
Loop
rs.Close
End Sub

ただ、2重ループだと発注Ｎｏ毎にSQLを発行する事になるので、ループ内で発注Ｎｏでキーブレイクするようにすれば、SQLの発行自体は1回で済みます。

Sub Sample1()

Dim cn     As New ADODB.Connection
Dim rs     As New ADODB.Recordset
Dim mySQL  As String
Dim myKey  As String

Set cn = CurrentProject.Connection
Set rs = New ADODB.Recordset

mySQL = "SELECT *, (select count(*) from T_stock where 発注No=stk.発注No) as 明細件数  FROM T_stock As stk"
rs.Open mySQL, cn, adOpenKeyset, adLockOptimistic

myKey = ""
Do Until rs.EOF

  If myKey! <> rs!発注No Then
    myKey! = rs!発注No
    '以下発注No毎の処理
    Debug.Print rs!発注No & "," & rs!納入先名称
  End If
  '以下明細毎の処理
  Debug.Print rs!納期日 & "," & rs!納入先郵便番号

  rs.MoveNext

Loop

rs.Close

End Sub

ループ内で何をしたいかによっては、ループせずに単にクエリーの実行だけで済む場合もあります。