別ブックのシートに行を追加する方法

Question

Book2.xlsmのシート（シート名：売却）に表があります。
その一番下に最終行をコピーして追加したいです。

上記操作をBook1.xlsmで行いたいのですが、開くブックがその都度変わります。
開くブックはBook1のC1に記載されています。

これを実行したく、以下のようなコードを作成してみましたが、何も変化がありませんでした。
エラーも出てきません。

どこをどうしたら実行できるようになるか教えていただけませんでしょうか？
よろしくお願いいたします。

Sub 追加()
Dim wb1 As Workbook
Workbooks.Open Filename:= _
"C:\Users\ファイル\" & Range("C1").Value
Set wb1 = ActiveWorkbook

With wb1.Worksheets("売却")
    With Cells(Rows.Count, "A").End(xlUp).Resize(1, 30)
        .Copy .Offset(.Rows.Count)
        With .Columns(1)
            .AutoFill .Resize(.Rows.Count * 2), xlFillMonths
        End With
    End With
  End With
End Sub

Answer 1

Option Explicit

Sub 追加2()
    Dim wbkNew As Workbook
    Dim rngNew As Range
    Dim rngList As Range
    Const cmyPath As String = "C:\Users\ファイル\"
    Const cmyCount As Long = 30

    Set rngList = ThisWorkbook.Worksheets(1).UsedRange
    Set wbkNew = Workbooks.Open(cmyPath & rngList.Range("C4").Value)
    With wbNew.Worksheets("売却").UsedRange
        Set rngNew = .Resize(cmyCount).Offset(.Rows.Count - cmyCount)
    End With

    With rngList(rngList.Rows.Count + 1, 1)
        rngNew.Copy .Cells
        With .Resize(cmyCount + 1).Offset(-1)
            .Cells(1).AutoFill .Cells, xlFillMonths
        End With
    End With
    
    wbkNew.Close False
End Sub

こういうことでしょうか？
もう少し丁寧に手順を書いた方がいいかも？

開いたブックがアクティブになる前に、次々命令が実行されても、
アクティブブックは開いたブックとは限りません。
Workbooks.Openメソッドは、関数と同様に返り値があるので、
それを変数に受けて再利用しましょう。

Comments

[mi_ku]

mattuwanさん、ありがとうございました。
いただいたコードでパスを変更して実行してみたところ、「オブジェクトが必要です」と出てしました。
他にどこか変更すべき点はございましたでしょうか？

[mattuwan]

あ、しつれいしました。
どの行でエラーが出ましたか？

＞With wbNew.Worksheets("売却").UsedRange
With wbkNew.Worksheets("売却").UsedRange

タイプミスですね。

[mi_ku]

wbkは修正したのですが、9行目でエラーになりました。

[mattuwan]

9行目ってどこから数えて9行目でしょうか？

[mattuwan]

＞Set rngNew = .Resize(cmyCount).Offset(.Rows.Count - cmyCount)
ここですかね？

貼り付け先の左上のセルがわかればいいから、
Set rngNew = .cells(1).Offset(.Rows.Count)
こうですね＾＾；失礼しました。
-30したら、元の表が30より少なかったら、存在しないセルを指定することになるので、
「オブジェクトが必要です」と言われたんだと思われます。
言い訳すると、やりたいことがいまいちわかってないので動作確認ができません＾＾；

[mi_ku]

ありがとうございます。
勉強になりました。
説明下手ですみません。
また何かありましたらよろしくお願いいたします。

Answer 2

アクティブなオブジェクトを前提とするコードはバグの元ですので、明示的に対象オブジェクトを指定しましょう。

とりあえず下記のように変更して動作を確認してください。

Sub 追加()
    Dim wb1 As Workbook
    Set wb1 = Workbooks.Open(FileName:= _
                   "C:\Users\ファイル\" & Range("C1").Value)

    With wb1.Worksheets("売却")
        With .Cells(wb1.Rows.Count, "A").End(xlUp).Resize(1, 30)
            .Copy .Offset(1)
            With .Columns(1)
                .AutoFill .Resize(2), xlFillMonths
            End With
        End With
    End With
End Sub

Comments

[hatena19]

完全に被った(;^ω^)

[mi_ku]

hatena19さん、ありがとうございました。
色々調べながら作成してみたのですが、バグの元になるものだったのですね。
素早いアドバイスありがとうございました。

[mi_ku]

教えていただけてとても助かります。

Answer 3

アクティブ前提の作りになっているので、タイミング等でうまく思った通りに動いていないようです。
オブジェクト指定の作りにしたところ問題なく動きました。
また6行目のCellsにピリオドが抜けていたので追加しています。

Sub 追加()
	Dim wb1 As Workbook
	Set wb1 = Workbooks.Open("C:\Users\ファイル\" & Range("C1").Value)

	With wb1.Worksheets("売却")
		With .Cells(Rows.Count, "A").End(xlUp).Resize(1, 30)
			.Copy .Offset(.Rows.Count)
			With .Columns(1)
				.AutoFill .Resize(.Rows.Count * 2), xlFillMonths
			End With
		End With
	End With
End Sub

Comments

[mi_ku]

ttyp03さん、ありがとうございました。
おかげさまで希望通りになりました。

ピリオドが抜けていた件ですが、抜けたままでも動いてしまうものなのでしょうか？

[ttyp03]

ピリオドを付けないとWithで指定したシートではなく、現在アクティブのシートが対象になります。
ここの処理においてはアクティブのシートがたまたま目的のシートになっているようで、問題はないようですが、明示的にどのシートというのを指定すべきなので、ピリオドを追加しました。

[mi_ku]

そうだったのですね。
たまたまだったのですね。
アドバイスありがとうございます。