同じシートに5か所最終行に貼り付けをしたい

Question

別のシートから列の最終行に5か所貼り付けたい。
試しに３か所してみましたが、
１か所目のD列の下に３個コピーされます。
どうすれば別の列の最終行に貼り付けられますか？
よろしくお願いします。

Sub cell?コピー ()
ActiveSheet.Range("S9").Select
Selection.Copy
Sheets("1").Select

   n = Cells(Rows.Count, "D").End(xlUp).Row + 1
   Range("D" & n).Select
  Sheets("1").Paste

 ActiveSheet.Range("S28").Select
   Selection.Copy
    Sheets("1").Select
   
   n = Cells(Rows.Count, "E").End(xlUp).Row + 1
   Range("E" & n).Select
  Sheets("1").Paste
  
   ActiveSheet.Range("S18").Select
   Selection.Copy
    Sheets("1").Select
   
   n = Cells(Rows.Count, "F").End(xlUp).Row + 1
   Range("F" & n).Select
  Sheets("1").Paste

Comments

[coco_bauer]

質問のタイトルは「同じシートに5か所最終行に貼り付けをしたい」、質問の最初の行は「別のシートから列の最終行に5か所貼り付けたい」となっていますが、質問者がしたいことは「別のシートの異なる５つのセルの値を、それとは違うシートの５つの列の最終行のセルに貼り付けたい」という事でしょうか？

質問のコードでは、『ActiveSheet.Range("S9").Select』となっていて、現在開いているシート(ActiveSheet)のセルから値をコピーしているようですが、これは質問の最初に書かれている「別のシートから」と矛盾します。

また、最初の値のコピーは起動時に開いていたシート(ActiveSheet)からですが、その後は『Sheet("1").Select』されているので、ワークシート"１”の中のセルからセルへのCopy&Pasteになっています（別のシートからになっていません）。

まず、どのような事をしたいのかを質問に判りやすく追加して下さい。

[退会済みユーザー]

activeシートから5か所sheet("1")の最終行にコピーをしたいです。

[退会済みユーザー]

activシートからsheet("1")に最終行の下に5か所貼り付けをしたいです。わかりにくくてすみません。

Answer 1

Sub test()
    Dim rngFrom As Range    '転記元
    Dim rngTo As Range      '転記先
    
    Set rngFrom = Worksheets("Sheet2").Range("S9,S28,S18")
    'シートの使っているセル範囲に対して
    With Worksheets("Sheet1").UsedRange
        Set rngTo = .Rows(.Rows.Count + 1)  '最終行の次の「行」
    End With
    
    '転記先の「行」のn番目のセルの値へ
    '転記元の「飛び飛びの範囲(Areas)」のn番目の範囲の値を入れる
    With rngTo
        .Cells(4).Value = rngFrom.Areas(1).Value
        .Cells(5).Value = rngFrom.Areas(2).Value
        .Cells(6).Value = rngFrom.Areas(3).Value
    End With
End Sub

こういうことですかね？
セルの位置の指定にはさまざまな表現方法が用意されていますので、
勉強して語彙を増やしてください。
事前にそのセル範囲を指定して変数に記録しておけば、
あとは「それ」のどの位置か「相対位置」を指定するように、
考える癖をつけておけば、今後に応用が効くと思います。

それから、
手動では、操作したいセルを「選択」することで指示しますが、
VBAでは、文章で遠隔操作するようにシートやセルを指定できる（する）ので、
選択することはやりたいことではないので、選択の命令をすることは無意味です。
また、選択されていることを前提にコードを書くと、
冗舌な文章になってあとで読みにくかったり、
意図していない選択で誤動作の原因になったりしますので、
Selectしない書き方を覚えましょう。
マクロの記録では、手動の操作をほぼそのままコードに翻訳しますので、
Selectが記録されてしまいます。
マクロの記録は手動の動作あるいは機能が、
VBAではどのような命令になるのかを探るための一つの
手段として割り切ってください。

Comments

[退会済みユーザー]

回答ありがとうございます。勉強していきます。

Answer 2

Select や Selection は使わないというのが基本です。
また、Copyメソッドは引数でコピー先を指定できます。これを使うとPasteは不要です。

Range.Copy メソッド (Excel)

Sub cell_コピー()
    'コピー元シート=アクティブシート
    Dim fromWs As Worksheet
    Set fromWs = ActiveSheet
    'コピー先シート=Sheets("1")
    Dim toWs As Worksheet
    Set toWs = Sheets("1")

    'コピー元のセルデータをコピー先(Destination)にコピー
    fromWs.Range("S9").Copy _
        Destination:=toWs.Cells(Rows.Count, "D").End(xlUp).Offset(1)

    fromWs.Range("S28").Copy _
        Destination:=toWs.Cells(Rows.Count, "E").End(xlUp).Offset(1)
    
    fromWs.Range("S18").Copy _
        Destination:=toWs.Cells(Rows.Count, "F").End(xlUp).Offset(1)

End Sub

Comments

[退会済みユーザー]

ありがとうございます。数式を入れずに値だけをコピーできるようにがんばります。

Answer 3

だいたい、次のようなプログラムになります。何をしているのかはコメントで説明しています。
（動作確認はしていませんので、使ってみてエラーが出たら対処してください。）

Sub cell?コピー ()
   'ActuveSheetとシート"1"を保存する変数を定義(DIM)し、値を設定する。(複数のシートの間の操作を行うプログラムでは、この一手間が大切。)
   Dim fromSheet as Worksheet, toSheet as Worksheet
   Set fromSheet = ActiveSheet
   Set toSheet = Sheets("1")
   Dim n as Long

   ' １つ目のコピー
   '　シート(fromSheet)とRangeでセルを特定しているので、Copyで値をコピーできる。
   fromSheet.Range("S9").Copy
   ' シート"1"(toSheet)に移って(Selectして)、D列の最終行に貼り付け
   toSheet.Select
   n = Cells(Rows.Count, "D").End(xlUp).Row + 1
   Range("D" & n).Select
   selection.paste

   ' ２つめのコピー
   fromSheet.Range("S28").Copy
   ' シート"1"に移って(Selectして)、E列の最終行に貼り付け
   toSheet.Select
   n = Cells(Rows.Count, "E").End(xlUp).Row + 1
   Range("E" & n).Select
   Selection.Paste

   ' ３つ目以降のコピーも同様のコードなので省略します。

Comments

[退会済みユーザー]

ありがとうございます。数式を入れずに値だけで貼り付けもできるように、がんばります。