VBAでGmailの操作をしたい

Question

VBAでIE起動からGmailの新規メール送信までを自動化したいと考えております。
IE起動～宛先入力までは上手くいくのですが、本文に文字を入力する処理がうまくいきません。

原因、解決方法がわかる方がいましたらご教授をお願い致します。

発生している問題・エラーメッセージ

実行時エラー'438': オブジェクトは、このプロパティまたはメソッドをサポートしていません。

該当のソースコード

    Dim objInpTxtHonbun
    Set objInpTxtHonbun = .document.getElementsByClassName("Am Al editable LW-avf tS-tW")
    objInpTxtHonbun.Value = "test"

※宛先については下記コードで正常に処理されます。
    Dim objInpTxtArea As HTMLTextAreaElement
    Set objInpTxtArea = .document.getElementsByName("to")(0)
    objInpTxtArea.Value = "test"

Answer 1

IEでやりたいとのことでしたのでわかったことを追記します。

取ろうとしているクラスの「Am Al editable LW-avf tS-tW」ですが、
firefoxの開発者ツールで確認したところこれはdivです。
divはinputではないためそもそもvalueを持っておらず、そのため
このアプローチでは入力することはできないと思います。

objInpTxtHonbun.Value = "test"

元の回答文

質問に対する直接の回答ではありませんがどうしてもVBAで
「IE起動からGmailの新規メール送信」
をしないといけないのでしょうか？

CDOを使えばメールの送信ならできるはずですが、いかがでしょうか。
GmailはやったことはありませんがSMTPサーバーの設定が正しければ通ると思います。

送信履歴を残したい場合はCC等で送信元のアドレスにもメールを送信することで済ませています。

私はこんな感じでメールを送ることが多いです。

Option Compare Database
Option Explicit

Private Const cdoSMTP As String = "http://schemas.microsoft.com/cdo/configuration/"
Private Const cdoSMTPServer As String = cdoSMTP & "smtpserver"
Private Const cdoSMTPServerPort As String = cdoSMTP & "smtpserverport"
Private Const cdoSendUsingMethod As String = cdoSMTP & "sendusing"
Private Const cdoSendUsingPort As Long = 2
Private Const cdoBasic As Long = 1
Private Const cdoSMTPConnectionTimeout As String = cdoSMTP & "smtpconnectiontimeout"
Private Const cdoSMTPAuthenticate As String = cdoSMTP & "smtpauthenticate"
Private Const cdoSendUserName As String = cdoSMTP & "sendusername"
Private Const cdoSendPassword As String = cdoSMTP & "sendpassword"
Private Const cdoLanguageCode As String = cdoSMTP & "languagecode"
Private Const cdoXMailer As String = "urn:schemas:mailheader:X-Mailer"
Private Const CustomXMailer As String = "VBA"
Private Const cdoAnonymous = 0

Public Function fncメール送信(ByVal ToAddress As String, ByVal FromAddress As String, ByVal Subject As String, ByVal TextBody As String, _
                Optional CcAddress As Variant, Optional BccAddress As Variant, _
                Optional ByVal Charset As String = "shift-jis", Optional Attachments As Variant)

    Dim CDO_Message As Object
    Set CDO_Message = CreateObject("CDO.Message")
    
    Dim Attachment As Variant
    
    With CDO_Message
        With .Configuration.Fields
            .Item(cdoSMTPServer).Value = SMTPサーバー 'SMTPサーバ
            .Item(cdoSMTPServerPort).Value = 587 'ポート
            .Item(cdoSendUsingMethod).Value = cdoSendUsingPort
            .Item(cdoSMTPConnectionTimeout).Value = 60
            .Item(cdoSMTPAuthenticate).Value = cdoBasic '認証
            .Item(cdoSendUserName).Value = SMTPユーザー名 'ユーザー名
            .Item(cdoSendPassword).Value = SMTPパスワード 'ユーザーのパスワード
            .Item(cdoLanguageCode).Value = "shift-jis" '文字コード
            .Update
        End With
        
        .MimeFormatted = True
        .From = FromAddress
        .To = ToAddress
        
        If Not IsMissing(CcAddress) Then
            .CC = CcAddress
        End If
        
        If Not IsMissing(BccAddress) Then
            .BCC = BccAddress
        End If
        
        .Subject = Subject
        .TextBody = TextBody
        .TextBodyPart.Charset = Charset
        .Fields.Item(cdoXMailer).Value = CustomXMailer
        .Fields.Update
    
        '添付ファイル
        For Each Attachment In Attachments
            .AddAttachment Attachment
        Next
    
        .Send
    End With

    Set CDO_Message = Nothing
    
    Exit Function
End Function

Comments

[engawa_oishii]

ご回答いただきありがとうございます。

＞「IE起動からGmailの新規メール送信」をしないといけないのでしょうか？
そうですね・・・。
今回は勉強目的で作ったプログラムなので、IE上の本文欄にテキストを入れる方法を知りたいです。。。

ただ、ご回答いただいたCDOを使ったメール送信の方法は知らなかったので、
これはこれで自分も使用させていただきますw

Answer 2

遅くなりましたが、自己解決しました。

検証ツールを使用したところ、Gmailの本文のテキストは、divのタグで囲まれた要素に入ることがわかりました。
そこで、指定した要素オブジェクトの要素内のテキスト部分のHTMLコードを取得する「innerText」プロパティを使用したところ、本文にテキストが入ることが確認できました。

Set objInpTxtHonbun = .document.getElementsByClassName("Am Al editable LW-avf tS-tW")(0)
objInpTxtHonbun.innerText = Honbun

下記の回答が参考になりました。
ありがとうございます。

＞firefoxの開発者ツールで確認したところこれはdivです。
＞divはinputではないためそもそもvalueを持っておらず、そのため
＞このアプローチでは入力することはできないと思います。