Windowsバッチ forのコマンド実行について

Question

下記のように記述するとfor内の
「IF EXIST　ファイル名～」のコマンドが実行されません。
forの外に出すと正常に実施されます。
どうしたら実行できるかヒントをくださるとうれしいです。

SET valueList=aaaaaaa,bbbbbbb,ddddddd

for %%a in (%valueList%) do (

IF EXIST test.csv SET existFlg=TRUE

IF %existFlg%==TRUE (
	ECHO ファイルが存在しました。
)

)

Answer 1

IF %existFlg%==TRUE (の%existFlg%の変数展開は、forの実行前に一度だけ行われます。

forの直前のこの変数の値がもし空なら、for文は、

for %%a in (aaaaaaa,bbbbbbb,ddddddd) do (

IF EXIST test.csv SET existFlg=TRUE

IF ==TRUE (
ECHO ファイルが存在しました。
)

)

となって、ifが文法エラーになるはずです。
これだけの処理なら、フラグを設けず、

SET valueList=aaaaaaa,bbbbbbb,ddddddd
for %%a in (%valueList%) do (
  IF EXIST test.csv (
    ECHO ファイルが存在しました。
  )
)

と書きます。

より複雑な処理で、どうしても変数更新と参照が必要なら、

for %%a in (%valueList%) do call :SUB "%%a"
exit /b

:SUB
SET existFlg=FALSE
IF EXIST test.csv SET existFlg=TRUE
IF %existFlg%==TRUE (
  ECHO ファイルが存在しました。
)
exit /b

と中身をサブルーチンに切り出すか、遅延環境変数展開というものを使います。

setlocal enabledelayedexpansion
SET valueList=aaaaaaa,bbbbbbb,ddddddd
for %%a in (%valueList%) do (
  SET existFlg=FALSE
  IF EXIST test.csv SET existFlg=TRUE
  IF !existFlg!==TRUE (
    ECHO ファイルが存在しました。
  )
)

遅延環境変数展開を使うと、それまで普通文字だった!が特殊文字になるので、データの中やファイル名などで!を使っていると駄目です。

#追記
今回だと、比較的影響の少ない変更としては、変数が未定義や空かどうかを調べるif definedを使う方法もあります。

SET valueList=aaaaaaa,bbbbbbb,ddddddd
for %%a in (%valueList%) do (
  SET existFlg=
rem   ↑ = の後に空白が入らないように注意
  IF EXIST test.csv SET existFlg=TRUE
  IF defined existFlg (
    ECHO ファイルが存在しました。
  )
)

Comments

[mugiko]

ご丁寧に教えてくださって大変ありがとうございます！！！！
そしていくつもの選択肢を、ご提案してくださり大変参考になりました。まずはIF EXIST ファイル〜(コマンド)の方法で実装してみたいと思います。
遅延環境変数など詳しくなかったので勉強になりました。

Answer 2

forの中かどうかは関係ありません。
existFlgが空の場合にIF ==TRUE (となりエラーになっているだけです。
空の場合に空白とならないよう"で囲ってやればよいです。

-IF %existFlg%==TRUE (
+IF "%existFlg%"=="TRUE" (

始めに環境変数が展開されることを忘れていました…
otnさんの回答をご参照ください。

Comments

[mugiko]

ご回答ありがとうございます！！！
初心者のため、１つ１つとても勉強になります。if分の際はSHOMI様の教えてくださったことも気をつけて記述していこうと思います。参考になりました。