Excell VBAで項目単位での集計方法について

Question

表題の件

SQLのgloupbyの様に指定された項目で集計し、アウトプット用のシートにコピーをExcel VBAで実現する場合の
考え方について教えて下さい。

私が考えたやり方は下記の通りになります。

①集計用の変数を用意する。
②データが入っているシートを、集計したい項目をキーにしてソートする。
③forの中にIFを入れ項目の変わり目で分岐させる。
for i=1 to 最終行
集計用変数=集計用変数+集計項目
if 「項目行」<>「項目行+1」 then　→集計する項目セルをA列とした場合「if range("A" & i) <> range("A" & i + 1) then」
アウトプット用シートへコピー
集計用変数=0
End If
next
④印刷

この様に考えましたが、集計項目が複数になってくると下記の様に項目数だけfor文を回せなければならず、何か他に方法はないのかと考えております。
お知恵をお貸し下さい。

for i=1 to 最終行
集計用変数=集計用変数+集計項目
if 「項目行」<>「項目行+1」 then
アウトプット用シートへコピー
集計用変数=0
End If
next
for i=1 to 最終行
集計用変数=集計用変数+集計項目
if 「項目2行」<>「項目2行+1」 then
アウトプット用シートへコピー
集計用変数=0
End If
next
----追記-----
元データサンプル画像です。
![]

対象のキーとしたいのは「出庫日」及び「商品コード」になり集計項目は「出庫ケース数」「出庫バラ数」になります。

出庫日毎の商品明細を一表にまとめ印刷する仕組みを考えております。

出庫日（ヘッダー）が変わると印刷し、明細項目をクリアする。

印刷フォームイメージ

また、別の表では「出庫日」「コード」をヘッダー情報として改ページして「商品コード」と「出庫ケース数」「出庫バラ数」を明細として一表にまとめ印刷

各別モジュールで考えております。

Comments

[tatsu99]

集計項目が複数の実際の例を画像にして貼り付けていいただけませんでしょうか。
Sheet1が集計元、Sheet2が集計結果としてください。
集計の方法も「集計した項目○○をキーにして、項目XXを集計する。」のように具体的に書いてください。

[shinyakita]

tatsu99様
早速の返信ありがとうございます。

[tatsu99]

補足ありがとうございました。
nextで示された画像と元データの画像が同じです。
nextの画像は「元データを「出庫日」及び「商品コード」をキーとして「出庫ケース数」及び「出庫バラ数」を集計した結果」のはずですので、その画像を提示していただけますでしょうか。

[shinyakita]

nextの画像は貼り付けた覚えがないで、操作を間違えたようです。

Answer 1

印刷までは考慮せず、日付+商品コード単位で出力する方法です。
印刷についてはあなたの方で、工夫してください。
「集計結果」シートに、添付図のような形で出力されます。

尚、実行時、元データは日付でソートされている前提ですので、必要であれば
日付でソートする処理をあなたの方で付加してください。
以下のようになります。不明点があれば補足してください。
集計結果の1行目は予め設定されている前提です。

Public Sub 日付商品コード集計()
    Dim sh1 As Worksheet
    Dim sh2 As Worksheet
    Dim dictCase As Object      '出庫ケース数用
    Dim dictBara As Object      '出庫バラ数用
    Dim key As Variant
    Dim maxrow1 As Long
    Dim row1 As Long
    Dim row2 As Long
    Dim keys As Variant
    Set dictCase = CreateObject("Scripting.Dictionary") ' 連想配列の定義
    Set dictBara = CreateObject("Scripting.Dictionary") ' 連想配列の定義
    Set sh1 = Worksheets("元データ")
    Set sh2 = Worksheets("集計結果")
    maxrow1 = sh1.Cells(Rows.Count, "A").End(xlUp).row '元データ 最終行を求める
    For row1 = 2 To maxrow1
        '日付＋商品コードをキーとする
        key = sh1.Cells(row1, "N").Value & "|" & sh1.Cells(row1, "H").Value
        '最初のキーの場合、値を０で初期化する
        If dictCase.exists(key) = False Then
            dictCase(key) = 0
            dictBara(key) = 0
        End If
        dictCase(key) = dictCase(key) + sh1.Cells(row1, "K").Value   '出庫ケース数を加算
        dictBara(key) = dictBara(key) + sh1.Cells(row1, "L").Value   '出庫バラ数を加算
    Next
    '集計結果へ出力する
    '2行目以降をクリアする
    sh2.Rows("2:" & Rows.Count).ClearContents                     'Sheet2の2行目以降をクリア
    row2 = 2
    For Each key In dictCase
        keys = Split(key, "|")  'キーを日付と商品コードにばらす
        sh2.Cells(row2, "A").Value = keys(0)            '日付
        sh2.Cells(row2, "B").Value = keys(1)            '商品コード
        sh2.Cells(row2, "C").Value = dictCase(key)      '出庫ケース数
        sh2.Cells(row2, "D").Value = dictBara(key)      '出庫バラ数
        row2 = row2 + 1
    Next
    MsgBox ("完了")
End Sub

Comments

[shinyakita]

コードまで作っていただきありがとうございます。

配列を使うのですね。
すごく勉強になります。

配列の使い方をもう一度勉強してみます。

Answer 2

出力形式にこだわらなければ、簡易的な方法としてピボットテーブルを使用する方法があると思います。