vba エクセルページ数 取得 について

Question

下記のプログラムを参考にして、各ブックごとのページ数の合計を出力するには、どうしたら良いでしようか。宜しくお願いします。
各ブックごととは、指定したフォルダ内にある複数のブックです。どうぞ宜しくお願いします。 指定したフォルダ内にあるファイル名とページ数を取得するのが目的です。ファイル名までは出力されますが、ページ数の取得でうまくいかず、下記のプログラムを参考に作成したいと考えております。
出力イメージ
テーマ 工程 ファイル名 ページ数
1 設計 .xlsx 3ページ
2 設計 .xlsx 2ページ

'=============================================
' ページ数を取得してシート一覧表を作成
'=============================================
Sub ページ数を取得してシート一覧表を作成()

Dim mysheet As Worksheet    '各シート
Dim page_sum As Integer     'ページ数
Dim list() As Variant       'シート名とページ数格納用
Dim i As Integer            '配列添え字用
Dim maxi As Integer         '配列最大添え字用

'-----------------------------------------
' シート名とページ数を配列に代入
'-----------------------------------------
maxi = 0

'ブックの各シートごとに
For Each mysheet In Worksheets

    'シートのページ数取得
    mysheet.Activate
    page_sum = Application.ExecuteExcel4Macro("get.document(50)")

    '配列にシート名とページ数を代入
    ReDim Preserve list(1, maxi)
    list(0, maxi) = mysheet.Name
    list(1, maxi) = page_sum
    maxi = maxi + 1

Next mysheet

'-----------------------------------------
' 配列をブックに転記
'-----------------------------------------

'リストタイトル設定
Range("A1").Value = "シート名"
Range("B1").Value = "ページ数"

'配列転記
For i = 0 To maxi - 1
    Range("A" & i + 2) = list(0, i)
    Range("B" & i + 2) = list(1, i)
Next

End Sub

Comments

[hsk]

おはようございます。「各ブックごと」とご質問にありますが、自分のブックだけではなくて、どこかほかにある複数のブック（ファイル）について処理を行うと考えて合っているでしょうか？どこかのフォルダ内に入っているブック群でしょうか？もしくは、集計シートに対象のブックのファイル名を書いておいたりするのでしょうか？

[sehiro]

おはようございます。質問内容が不足しており申し訳ありません。
各ブックごととは、指定したフォルダ内にある複数のブックです。どうぞ宜しくお願いします。

指定したフォルダ内にあるファイル名とページ数を取得するのが目的です。ファイル名までは出力されますが、ページ数の取得でうまくいかず、上記のプログラムを参考に作成したいと考えております。

出力イメージ

テーマ 工程 ファイル名 ページ数
1 設計 .xlsx 3ページ
2 設計 .xlsx 2ページ

Answer 1

ご質問の内容、拝見しました。サンプルを作成してみました。説明が冗長でしたらスミマセン...
自分のブック内を参照するときはWorksheetsと書くだけで自分自身のWorkbookオブジェクト(ActiveWorkbookあるいはThisWorkbook)を暗黙的に参照しているのですが
(つまり For Each mysheet In Worksheets は、（省略せずに書くと）内部的には For Each mysheet In Application.ActiveWorkbook.Worksheets のようになっています)
他のブックを参照するときは、OpenやAdd関数で明示的に開いて、そこで得たオブジェクト変数から参照や操作を行います。

Option Explicit

Public Sub Sample()
    ' 転記先（アクティブなシート？）をオブジェクト変数myWsにセットしておきます。
    Dim myWs as Excel.Worksheet
    Set myWs = ActiveSheet

    '※ファイルパスは投稿時バックスラッシュ(\)になってしまいましたが、円マーク(￥)です
    Dim folderPath As String
    folderPath = "(フォルダ)\*.xls*"
    
    ' Dir関数でフォルダ内のファイルを列挙します
    Dim fileName As String
    fileName = Dir(folderPath)
    
    Do Until (fileName = "")
        ' ブックのファイルパスをxlsFilePathに生成します。
        Dim xlsFilePath As String
        xlsFilePath = folderPath & "\" & fileName
    
        ' ブックを開き、参照用につかうオブジェクト変数wbへ格納します（念のために、今回はReadOnly=True)
        Dim wb As Excel.Workbook
        Set wb = Workbooks.Open(xlsFilePath, , True)
    
        ' ブックwbの各シートをFor Eachで列挙して、参照用につかうオブジェクト変数wsに格納して操作します。
        Dim ws As Excel.Worksheet
        For Each ws In wb.Worksheets
            ' ここに、処理（ページ数の計算と、集計セルへの出力）を書きます。
            MsgBox ws.Name
            myWs.Range("A1").Value = "サンプル" ' 例
        Next
    
        ' ブックの操作が終わったので閉じます。
        wb.Close
    
        fileName = Dir()    ' これ以上ブックがなければ fileName = ""
    Loop
End Sub

Comments

[sehiro]

ありがとうございます。参考にさせて頂きます。

[sehiro]

たびたびすいません。下記のvbaで、 ' ここに、処理（ページ数の計算と、集計セルへの出力）を書きます。
とありますが、今回はブック内の総ページ数のみ、出力したいので、総ページのみ出力するには、どのような処理にすれば良いかもアドバイス頂けないでしようか。宜しくお願い致します。

' ブックwbの各シートをFor Eachで列挙して、参照用につかうオブジェクト変数wsに格納して操作します。
Dim ws As Excel.Worksheet
For Each ws In wb.Worksheets
' ここに、処理（ページ数の計算と、集計セルへの出力）を書きます。
MsgBox ws.Name
myWs.Range("A1").Value = "サンプル" ' 例
Next

[hsk]

ブックの総ページ数＝ブック内の全シートの合計ページ数、で合っているでしょうか？
でしたら、
シートを列挙するループの前にpage_sumをゼロクリアして

page_sum = page_sum + Application.ExecuteExcel4Macro("get.document(50)")

で、地道に加算していくことになるかと思います。

調べてみましたら、ほぼズバリのページが見つかりましたよ！

http://d.hatena.ne.jp/asuka0801/20110605/1307232920

'ページ数を取得にゃー
のあたりが、ページ数加算の箇所ですね。

[sehiro]

ありがとうございます。参考にさせて頂きます。

[sehiro]

ブックの総ページが出力されるようになりました。ありがとうございます。後、総ページ出力時に下記のように表示させたいのですが、ページ数の書式設定について教えて頂けないでしようか。宜しくお願いします。

総ページ数
3ページ

[hsk]

セルに Range.NumberFormat プロパティを指定することで、VBAから書式設定が可能です。

https://msdn.microsoft.com/ja-jp/library/office/ff196401.aspx

手操作でセルに書式設定（ユーザー定義）する方法と同じ書式指定文字列を指定します。
##0"ページ" のような感じでしょうか。

ちなみに「マクロの記録」機能から、自分が行った実際の操作をVBAのコードに自動生成してくれますので、VBAでどう書けばよいかわからない場合に有用ですよ。

http://www.eurus.dti.ne.jp/~yoneyama/Excel/vba/vba_01_2007.html

http://kokodane.com/2010/excel2010macro_05.htm

http://www.eurus.dti.ne.jp/~yoneyama/Excel/vba/vba_01.html

[sehiro]

ありがとうございます。「マクロの記録」機能を利用して無事に作成できました。

Answer 2

対象のブックを既に開いているのであれば、シートをループする前にブックをループしてあげればいいと思います。

  'ブックのループ
  For Each mybook In Workbooks
      'ブックごとに合計ページ数をリセット
      page_sum = 0
      '取得したブックのシートをループ
      For Each mysheet In mybook.Worksheets
          
          ・・・
          
          '合計ページ数にシートのページ数を加算
          page_sum = page_sum + Application.ExecuteExcel4Macro("get.document(50)")
          
  ・
  ・
  ・

対象ブックを開きながら処理する場合も、やはりシートをループする前に対象ブック数分のループを行い、ブックのオープン・クローズをしながらページ数を加算していけばいいと思います。

  'ブックのループ
  For ～ ブック数分のループ
      Set mybook = Workbooks.Open("xxx.xlsx")
      'シートのループ
      For ～ ブック数分のループ
          'ページ数の加算
      Next シート
      mybook.Close
  Next ブック

完成形のコードは提示していませんが、がんばってみてください。

Comments

[sehiro]

ありがとうございます。参考にさせて頂きます。