検索結果を別のサブフォームに一覧表示させたい。

Question

Access初心者です。
現在、下記のVBAで分割フォームに商品と売上日の検索結果一覧を表示しています。
分割フォームではなく、検索ボタンを押す→サブフォームが立ち上がる→サブフォームに検索結果が表示されるというVBAにしたいのですがどのようにすれば良いでしょうか？
ご教授いただければ幸いです。
宜しくお願い致します。

Private Sub cmd_filter_Click()

    Dim strFilter As String

    '[商品名]の条件の指定
    If Nz(Me![商品名検索], "") <> "" Then
        strFilter = strFilter & _
                    " AND ([商品名]Like '*" & Replace(Me![商品名検索], "'", "''", , , vbBinaryCompare) & "*')"
    Me.cmd_filter.SetFocus
    End If

 '[売上日]の範囲条件（最小値）の指定
    If IsDate(Me![売上日1検索]) Then
        strFilter = strFilter & _
                    " AND ([売上日] >= #" & Format(Me![売上日1検索], "yyyy/mm/dd") & "#)"
    Me.[売上日2検索].SetFocus
    End If

    '[売上日]の範囲条件（最大値）の指定
    If IsDate(Me![売上日2検索]) Then
        strFilter = strFilter & _
                    " AND ([売上日] <= #" & Format(Me![売上日2検索], "yyyy/mm/dd") & "#)"
    Me.cmd_filter.SetFocus
    End If

    '先頭の" AND "を取り除く
    strFilter = Mid(strFilter, 6)

    'フィルター条件の設定
    Me.Filter = strFilter
    'フィルターの実行(もしくは解除)
    Me.FilterOn = (strFilter <> "")

End Sub
コード
```

Answer 1

分割フォームではなく、検索ボタンを押す→サブフォームが立ち上がる→サブフォームに検索結果が表示されるというVBAにしたいのですがどのようにすれば良いでしょうか？

Accessの用語でサブフォームというのは、単票フォーム上のコントロールに埋め込まれているフォームのことですが、そういう意味のものではなく、単に別のフォームを開くということでいいでしょうか。

だとしたら、提示のコードの最後の部分を下記のように書き換えるだけです。
提示のコードの 'フィルター条件の設定 移行を削除して、下記の１行を追加するだけです。

    '先頭の" AND "を取り除く
    strFilter = Mid(strFilter, 6)

    DoCmd.OpenForm "別フォーム名", acFormDS, , strFilter '別フォームをデータシートで開く

End Sub

Comments

[tkyk.]

hatena19様

ありがとうございます！
教えていただいたコードの前に下記コードを入れたら別フォームで開きました。
ちなみに開く際にデータシートビューで開くにはどこにどのようなコードを入れれば良いのでしょうか？

DoCmd.OpenForm "別フォーム名"

[hatena19]

回答を修正しましたのでご参照ください。

[tkyk.]

ありがとうございます！
教えていただいたコードで無事に出来ました。
大変参考になりました。