エクセルVBAにてリスト名から一括でシートを生成したい

Question

エクセルVBAにてシート1のA2セル以降のA列にずらっとリストを作成し、それを元にシート2を原本としたシートを
リスト名分複製・その時シート名は各リストの名前とし、生成したシートのF9セルにもリスト名を入力したいです。

以前同じような質問があり、コードが解説されていましたが、

5行目で（FOR EACHの行）実行時エラー’9’：
インデックスが有効範囲ではありません。

とでてしまします。

何が間違っているのでしょうか？

Sub Name_to_Make()
Dim Name As Range
Dim r As Integer
r = Cells(Rows.Count, 1).End(xlUp).Row
For Each Name In Worksheets("シート1").Range(Cells(2, 1), Cells(r, 1))
Worksheets("シート2").Copy After:=Worksheets(Worksheets.Count)
With ActiveSheet
.Name = Name.Value
.Range("F9") = Name.Value
End With
Next Name
End Sub

Answer 1

たぶんこう。

For Each Name In Worksheets("シート1").Range(Cells(2, 1), Cells(r, 1))
↓
For Each Name In Worksheets("シート1").Range(Worksheets("シート1").Cells(2, 1), Worksheets("シート1").Cells(r, 1))

長ったらしいからこう書いては。

For Each Name In Worksheets("シート1").Range("A2:A"&r)

Answer 2

Worksheets("シート1")は存在しますか？
存在するのであれば選択されていますか？
そうであれば提示のコードで問題ありませんでした。

下記なら選択されていなくても実行可能です。

Sub Name_to_Make()
Dim Name As Range
Dim r As Integer
Dim ws As Worksheet: Set ws = Worksheets("シート1")

r = ws.Cells(Rows.Count, 1).End(xlUp).Row
For Each Name In ws.Range(ws.Cells(2, 1), ws.Cells(r, 1))
    Worksheets("シート2").Copy After:=Worksheets(Worksheets.Count)
    With ActiveSheet
        .Name = Name.Value
        .Range("F9") = Name.Value
    End With
Next Name
End Sub

Comments

[ryouheiabe]

ありがとうございます。
出来ました。

シート１は存在しているのですが動きませんでした。
もっと勉強します。