VBAのマクロ印刷について

Question

自動印刷のため以下のようなマクロを書いてみました。

Sub Printing()
Dim print_start, print_end, counter As Integer
print_start = InputBox("put the first page number")
print_end = InputBox("put the last page number")
For counter = print_start To print_end
Cells(4, 2) = counter
ActiveWindow.SelectedSheets.PrintOut Copies:=1
Next
End Sub

すると、下のようなエラーになります。

どのように直せばいいのでしょうか。
よろしくお願いします。

Comments

[mattuwan]

エラーが再現できません。が、回数分数字を変えて印刷でいいのですか？
やりたいことも合わせて書いて下さい。

[mdaigo]

どうもコメントありがとうございます。
はい、やりたいことは一人一人の個票を印刷していくものです。
エラーに関してなんですが、実行してみると上のようなエラーがでるときもあれば、デバックして
For counter = print_start To print_end
のところが黄色くなることもあります。
最近マクロの勉強を始めて、参考に先人のブログに貼り付けてあるコードをそのままコピペさせていただいたりするのですが、それでも結構エラーがでたりします（メモリが足りないやコンパイルエラーなど）。これはエクセルやパソコンに問題があるのかなと思ってしまいます。

[mattuwan]

メモリが足りないのはパソコンではなくエクセルの問題ですね。
回避の方法があるとは思いますが、状況を再現できないと、
代わりに原因を突き止めるということは難しくなります。
一人一人の個票と言われても解りません。
業務の用語ではなく、エクセルのシート上の説明をお願いします。

[mdaigo]

うー、初心者でどう説明していいかわからないのですが、エクセルで、vlook関数を使って、番号を打ち込むと、別シートのリストを参照して、その人のデータが表示されるものです。

[mdaigo]

すいません、調べてみたところ、おそらくmacのエクセルであることが原因の可能性がたかそうです。
どうもありがとうございました。

[mattuwan]

？
番号を打込むのは手動でやって、マクロの中でやってるのは、
始まりと終わりのページ番号のいみですか？
あと、複数シートは手動で選択しているのですか？

そちらが初心者かどうかで、僕の対応は変わりません。ただし、解決に向かうようアドバイスはしたいと思ってます。
まずは、エクセル君に仕事をしてもらうんじゃなくて、回答者に、
その仕事を手動でしてもらうつもりで、説明してください。

[mdaigo]

エクセルくん、なるほど。そうやってちゃんと説明することが大事なんですね。
作りたいマクロは、初めの番号と最後の番号を手入力すれば、その範囲のシートを自動で印刷してくれるものです。Cells(4,2)のところに印刷している番号がでるようにしました。「あと、複数シートは手動で選択しているのですか？」ということでしたが、これに関してはよく理解できていません。上で番号を入れれば、自動で１つずつ1が足されていくのかなと思ったのですが、もしや1+=のようなものをどこかに入れなければいけないのでしょうか。

ネットで調べていたら、ActiveWindow.SelectedSheets.PrintOut Copies:=1は、Macの場合はThisWorkbook.ActiveSheet.PrintOutにしないといけないというのを見つけました。ただそうやっても上と同じエラーがでました。

お時間をとっていただき感謝です。

[mattuwan]

>ActiveWindow.SelectedSheets
アクティブなシートの選択されたシート群（1つの場合も含む）という意味です。
なので、マクロ実行前に意図するシートを複数選択してあると読みましたが、
そういう事ではないのですね。
印刷したいのは、特定の決まったシート1つ。
で、
Cells(4, 2) = counter
とセルに数値を入力したら、
それによって、シート上の数式が再計算されて、
その結果を次々印刷したいといことですかね？

[mdaigo]

はい、シートは１つです。手動でやれば、セルの番号を変えれば、vlookupで別のシートにあるデータをもってきれくれて表示してくれるので、それを印刷するのですが、いちいち番号を変えることを自動でできたらなと。Cells(4,2)には、印刷されるシートの番号が表示されるようにしたつもりでした。

Answer 1

Worksheets("Sheet1").PrintOut

と、ちゃんと印刷したいシートを明示したらいかがでしょうか？

Option Explicit

Sub test()
    Dim n As Variant
    Dim s As String
    Dim flg As Boolean

    s = InputBox("番号入力" & vbLf & _
                 "例）連番1-5、飛び番5,10,12、混合1-5,8,10-25")
    If StrPtr(s) = 0 Then Exit Sub
                 
    If GetNumber(s) Then
        For Each n In Split(s, ",")
            flg = True
            Worksheets("Sheet1").Cells(4, 2).Value = n
            'Worksheets("Sheet1").PrintOut
            Worksheets("Sheet1").PrintPreview
        Next
    End If
    
    If flg = False Then
        MsgBox "入力が不正です。"
    End If
End Sub

'連番を生成する自作関数
Private Function GetNumber(ByRef ss As String) As Boolean
    Dim r As String
    Dim v As Variant
    Dim s As Variant
    Dim n As Variant
    Dim i As Long

    r = ss
    
    '不要なカンマを除去
    If Right(r, 1) = "," Then r = Left(r, Len(r) - 1)
    If Left(r, 2) = "," Then r = Mid(r, 2)
    r = Replace(r, ",", " ")
    r = WorksheetFunction.Trim(r)
    r = Replace(r, " ", ",")
    
    'ハイホンの文字列を連番に変換
    For Each v In Split(r, ",")
        If InStr(v, "-") Then
            s = Split(v, "-")
            For Each n In s
                If Not IsNumeric(n) Then GoTo WayOut
            Next
            For i = s(0) To s(1)
                n = n & "," & i
            Next
            r = Replace(r, v, Mid(n, 2))
        End If
    Next
    ss = r
    GetNumber = True
    Exit Function

WayOut:
End Function

Comments

[mdaigo]

mattuwan様、これほど丁寧に書いていただいてありがとうございます。実行したら
PrintPreviewのところでエラーがでてしまいましたので調べたら、macではPreviewできないというコメントを見つけました。そこを抜いて実行してみたら、何のエラーもなくなりました。
それにしても「不要なカンマを除去」のところと「ハイホンの文字列を連番に変換」のところはすごいですね。こんなの自分には到底かけそうもありません。