九九の表を出力するアルゴリズムについて

Question

前提・実現したいこと

VBAで九九の表を出力するにあたってロジックと言えるような物を考えたいのですが、どういったアルゴリズムであれば可能なのかを知りたいと思っています。
Excelへ九九の表が出力できれば方法や効率は一切問わないという条件で考えています。

試したこと

通常のLoopステートメント(ForNext/DoLoop/DoWhile)等の方法は書けました。他に、再帰を利用した方法なども実現出来ましたが、ロジックと言えるようなアルゴリズムがまだ勉強不足で思いつかないです。

こういった考え方があるというのがあればお教えいただければ嬉しいです。

追記：
回答有難う御座います。
手元に20通り程の上記結果が得られるコードは残せているのですが、そういった物は一般的に紹介されているような物ばかりで、何か特殊な書き方がないかと書き込ませて頂いた次第でした。

Comments

[Zuishin]

ロジックも何も二重ループの一番単純なサンプルになるような問題です。これが書けないのなら、もう一段階前からやり直した方が効率的です。

[kaina]

>Excelへ九九の表が出力できれば方法や効率は一切問わないという条件で考えています。
と最初に書いておきながら、
>手元に20通り程の上記結果が得られるコードは残せているのですが、そういった物は一般的に紹介され>ているような物ばかりで、何か特殊な書き方がないかと書き込ませて頂いた次第でした。
と追記するようなことはやめましょう。
その20通りの方法も書かないと、あなたが知らない書き方があるかどうかも分からないのでは？

Answer 1

36回のループで出力する方法

For x = 1 To 9
    Sheet1.Cells(x, x) = x * x
    For y = x + 1 To 9
        Sheet1.Cells(x, y) = x * y
        Sheet1.Cells(y, x) = x * y
    Next
Next

Comments

[xebme]

簡潔で美しい。

Answer 2

数式のみでやってみた :-p

Range("A1").Resize(9, 9).FormulaR1C1 = "=ROW()*COLUMN()"

A1からの相対指定なら

With Range("A1") 
    .Resize(9, 9).FormulaR1C1 = "=(ROW()-ROW(R" & .Row & "C" & .Column & ")+1)*(COLUMN()-COLUMN(R" & .Row & "C" & .Column & ")+1)"
End With

Comments

[Y.H.]

A1セルを起点にするなら全セルに数式「=ROW()*COLUMN()」を設定するだけでOK。
理屈はxebmeさんの回答で説明されてる :-)

[Y.H.]

あぁ、結局この質問者さんも退会済み・・・

Answer 3

45パターンだけ計算する方法
ネスト有のサンプル

Option Explicit

Sub main():
    Dim multiplication_table(1 To 9, 1 To 9) As Integer
    Dim a As Long, b As Long, c As Long
    For a = 1 To 9
        For b = a To 9
            c = a * b
            multiplication_table(a, b) = c
            multiplication_table(b, a) = c
        Next b
    Next a
    Range("A1:I9") = multiplication_table
End Sub

Answer 4

連続する10進数を９進数に変換

0 <= i < 9 X 9
0から８0までの連続する10進数(i)を順に読み、２桁の９進数(nm)に変換する。

９進数の１桁目mは、0-8 までの数を繰り返す（周期を生じる）。
同様に９進数の２桁目のnは 0-8 まで１周期動く。

これにより、九九表は、n+1: 行番号、m+1: 列番号で表すことができる。
九九表の各値は (n+1) X (m+1)

この計算で行列のネストループは必要ない。（数学科出身の女の子の解答を参考にしました）

Comments

[momon-ga]

同じこと考えてました。こんな感じっすね。
For i = 1 To 81
x = Fix((i - 1) / 9) + 1
y = (i - 1) Mod 9 + 1
Sheet1.Cells(x, y) = x * y
Next

Answer 5

Sub Macro1()
    With Range("A1").Resize(9, 9)
        .Cells(1).Value = 1
        .Cells(1).AutoFill Destination:=.Rows(1), Type:=xlFillSeries
        .Rows(1).Offset(, 1).Copy
        .Offset(1).PasteSpecial Paste:=xlPasteAll, Transpose:=True
        .Rows(1).Copy
        .Offset(1).Resize(8).PasteSpecial Operation:=xlMultiply
    End With
End Sub

一応書いてみた。。。。

Answer 6

こんな感じで

ループ１　変数１が1から9まで
　ループ２　変数２が1から9まで
　　変数３ = 変数１ * 変数２
　　出力
　ループ２終わり
ループ１終わり