ファイル内の行ごとにタブの数を数えたい

Question

以下のtest.txtの行ごとのタブの数を数えたいです。（windows環境）

--test.txtの内容
value11(半角スペース)value12
value21(タブ)value22
value31(タブ)value32(タブ)value33

--testbat.batの内容
@echo off
for /f "delims=" %%a in (test.txt) do (
echo %%a | find " " /C
)
pause;

testbat.batを実行すると以下のような結果となります。

0
1
1

タブのない行に対して0と返却されるのは良いのですが
test.txtの3行目のようにタブを2個含む場合は2と返却してほしいのです。
アドバイス頂けるでしょうか。

Answer 1

for /fのdelimsに文字を設定することで区切って取得することができますが、
forと付いた処理にも関わらず一回しか回らずinの前の変数に区切られた文字が格納されるだけなので、
tokensに「1*」と指定し、区切り文字の一つ目とその後の全ての文字を取得し、
その後の全ての文字を再度区切り対象にすることをgoto文で繰り返して回った数だけカウントすることで、
検索したい文字がいくつあるかを割り出しています。
コマンドプロンプトだとこの程度の処理でもこれだけ手間がかかります。

素直にPowershellとか使った方が楽だとは思いますが参考になれば。

@echo off
rem テキストの行毎にループする
for /f "delims=" %%a in (test.txt) do (
  rem 文字列カウントサブルーチンを呼び出す
  call :str_count "%%a"
)
pause;
exit /b


rem 文字列カウントサブルーチン
:str_count
set var=%~1
set num=-1
rem 処理ループラベル
:str_count_loop
rem 区切り文字がなくなったら処理終了ラベルに飛ぶ
if "%var%" EQU "" goto str_count_end
rem タブ文字で区切って取得する
for /F "tokens=1* delims=	" %%a in ("%var%") do (
  rem 区切り文字の後の文字を全て取得する
  set var=%%b
  rem カウンターを1加算する
  set /a num=num+1
)
rem 処理ループラベルに飛ぶ
goto :str_count_loop

rem 処理終了ラベル
:str_count_end
echo %num%

Comments

[999turbulence]

yureighostさん
ご回答頂きありがとうございます。
他の方のコメントでもあるようにpowershellを検討してみます。

Answer 2

まっとうな言語で書いた方が良いと思いますが。上限がタブ9個とか決まっていれば面倒だけど可能です。

for /f "tokens=1-10 delims=ここにタブ文字" %%A in (test.txt) do (
  if "%%B" == "" (
    echo 0個
  ) else if "%%C" == "" (
    echo 1個
  ) else if "%%D" == "" (
    echo 2個
  中略
  ) else if "%%I" == "" (
    echo 7個
  ) else if "%%J" == "" (
    echo 8個
  ) else echo 9個以上
)

#追記

foreach($x in Get-Content test.txt){
  Write-Host ($x.Split("`t").Length - 1)
}

タブで分割して、分割数-1。

Comments

[999turbulence]

otnさん、回答頂きありがとうございます。
タブの上限は決まっていないです。
また、tokenの最大値は31までらしく、31は超えそうな見込みです。。。

＞＞まっとうな言語で書いた方が良いと思いますが
他の方法も検討してみます。
ありがとうございます。

[otn]

それだと、こうするしか無いかと思ったら、すでにその回答が付いていました。

[otn]

> 他の方法も検討してみます。
とりあえず、PowerShellで。

[Y.H.]

bat(cmd)ファイル内からpowershellスクリプト実行するならこんな感じ
※やってることはotnさん回答と同じです。
[TOF test.bat]
powershell -command "get-content test.txt | %%{ $_.split("""`t""").length - 1}"
[EOF]

[999turbulence]

Y.H.さん
ご回答頂きありがとうございます。
powershellだとあっさりですね。これで行きたいと思います。
勉強します。

[Y.H.]

すみませんlengthに-1するの抜けてたので上のコード修正しておきました。