２つのリストボックスに複数列を表示させたい

Question

前提・実現したいこと

初めて投稿させて頂きます。
VBAで２つのリストボックスを連動させました。
2つ目のリストボックスで複数列を表示させようとした際、エラーが発生してしました。
（画像は架空の個人情報です）

発生している問題・エラーメッセージ

実行時エラー'381':
listプロパティを設定できません。プロパティの配列のインデックスが無効です。

該当のソースコード

Private Sub UserForm_Initialize()
    Dim i As Long
    Dim lastRow As Long
    With ListBox1
   
        .Clear
        .ColumnCount = 2
        .ColumnWidths = 20
    End With
    With Worksheets("リスト1")
        For i = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
            ListBox1.AddItem Cells(i, 1)
            ListBox1.List(i - 2, 1) = .Cells(i, 2)
        Next
        ListBox1.ListIndex = 0
    End With
End Sub

Private Sub ListBox1_Click()
    Dim i As Long
    ListBox2.Clear
    With Worksheets("リスト1")
        For i = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
            If ListBox1.Text = .Cells(i, 1) Then
                ListBox2.AddItem .Cells(i, 3)
                'ListBox2.List(i - 2, 1) = .Cells(i, 4) ここでエラーになる
            End If
        Next
    End With
End Sub

Answer 1

一例です。

Option Explicit

Private Sub ListBox1_Change()
    Dim v As Variant
    
    With Me.ListBox1
        v = WorksheetFunction.Index(.List, .ListIndex + 1, 0)
    End With
    
    With Me.ListBox2
        .Clear
        .AddItem v(1)
        .AddItem v(2)
        .AddItem v(4)
        .AddItem v(5)
    End With
End Sub

Private Sub UserForm_Initialize()
    With Worksheets(1).Range("A1").CurrentRegion
        Me.ListBox1.List = Intersect(.Resize(, 7), .Offset(1, 1)).Value
    End With
End Sub

こういうことがやりたいのかな？

---

Option Explicit

Private Sub UserForm_Initialize()
    With Worksheets(1).Range("A1").CurrentRegion
        Me.ListBox1.List = Intersect(.Resize(, 7), .Offset(1, 1)).Value
    End With
    Me.ListBox1.MultiSelect = fmMultiSelectExtended
    With Me.ListBox2
        .ColumnCount = 4
        .ColumnWidths = "20;20;20;20"
    End With
End Sub

Private Sub ListBox1_Change()
    Dim ix As Long
    Dim v As Variant
    Dim i As Long, j As Long

    Me.ListBox2.Clear

    With Me.ListBox1
        For ix = 0 To .ListCount - 1
            If .Selected(ix) Then
                Me.ListBox2.AddItem ""
                i = 0
                j = 0
                For Each v In WorksheetFunction.Index(.List, ix + 1, 0)
                    j = j + 1
                    If j <> 3 Then
                        Me.ListBox2.List(Me.ListBox2.ListCount - 1, i) = v
                        i = i + 1
                    End If
                Next
            End If
        Next
    End With
End Sub

説明の言葉が難しくてよくわかんないけど。。。

Comments

[gumiPons]

ありがとうございます！intersectメソッドを知らなかったので、試して勉強になりました！
質問が悪かったのですが、一意のリストボックス１に対し、リストボックス2は複数の行を返すように作成を目指していました！
ListBox2.List(i - 2, 1) = .Cells(i, 4)　を
ListBox2.List(ListBox2.ListCount - 1, 1) = .Cells(i, ４)　に変更することでできました。

Answer 2

Private Sub UserForm_Initialize()
    Dim i As Long
    With ListBox1
        .ColumnCount = 2
        .ColumnWidths = "15;50"
    End With

    '↓ListBox2の列数と列幅を設定する必要がある
    With ListBox2
        .ColumnCount = 2
        .ColumnWidths = "50;50"
    End With
    With Worksheets("リスト1")
        For i = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
            ListBox1.AddItem Cells(i, 1)
            ListBox1.List(i - 2, 1) = .Cells(i, 2)
        Next
        ListBox1.ListIndex = 0
    End With
End Sub

Private Sub ListBox1_Click()
    Dim i As Long
    
    ListBox2.Clear
    With Worksheets("リスト1")
        For i = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
            If ListBox1.Text = .Cells(i, 1) Then
                ListBox2.AddItem .Cells(i, 3)
                '↓１行しかないので１行目の２列目に代入
                ListBox2.List(0, 1) = .Cells(i, 4)
                Exit For
            End If
        Next
    End With
End Sub

---

別案

Private Sub UserForm_Initialize()
    With ListBox1
        .ColumnCount = 4
        .ColumnWidths = "20;100;0;0"
    End With
    
    With ListBox2
        .ColumnCount = 2
        .ColumnWidths = "50;50"
    End With
    
    With Worksheets("リスト1").Range("A1").CurrentRegion
        ListBox1.List = .Offset(1).Resize(.Rows.Count - 1, 4).Value
        ListBox1.ListIndex = 0
    End With
End Sub

Private Sub ListBox1_Click()
    With ListBox1
        ListBox2.Clear
        ListBox2.AddItem .List(.ListIndex, 2)
        ListBox2.List(0, 1) = .List(.ListIndex, 3)
    End With
End Sub

Comments

[gumiPons]

初めて質問サイトで質問しましたが、詳しく記載頂き感動しました。
案１を走らせて動いたため更に感動しました。
２列目に１行しか入らなかったためエラーが発生したと理解できました。
別案は明日、試させていただきます。

[gumiPons]

ListBox2.List(i - 2, 1) = .Cells(i, 4)　がエラーなのに、どうしてListBox2.List(0, 1) = .Cells(i, 4)で可能なのか考えた結果、ループすることで配列の数がズレるのかな？と思い
ListBox2.List(ListBox2.ListCount - 1, 1) = .Cells(i, ４)にすることで実現できました！

別案も試させていただきました。
簡素にコーディングが記述してあり、素晴らしいです。
初投稿ということもあり、質問が悪かったのですがリスト１の一意の数をもとにリスト２は複数の行を抽出し連動させたいということでした！
とても助かりました。ありがとうございます！