時計プログラムの一部分をfor文を使って短縮したいです

Question

以前も同じプログラムで質問したのですが、また別の方法で書きたく再度質問させてもらいました。

mm = minute();
rad =radians(mm*(360/60)-90);
strokeWeight(2);
x = cos(rad)*200+250;
y = sin(rad)*200+250;
line(250,250,x,y);

の
x = cos(rad)*200+250;
y = sin(rad)*200+250;
line(250,250,x,y);
部分をfor文で繰り返し文を作りたいです
細かく指定させて貰いますと、

for(int i =1; i<3; i++)で始まるfor文を作りたいのです。
for文とif文の組み合わせで、中心を動かさないように指定させる方法が詰んでまして・・・。

Comments

[thkana]

どういう観点から「別の方法」を知りたいと思ったのですか。
以前教わった方法で一旦は満足したので解決にしたのだと思いますが、
それで問題となることがあったのならそれを知ればより適切な回答が出来そうな気がします。
#関数は教わってないから使っちゃダメって言われた、とかじゃないですよね?

[thkana]

> for(int i =1; i<3; i++)
iは1と2でループしますが、それでどうしろというのでしょうか。

> for文とif文の組み合わせで、中心を動かさないように指定させる
意味がわかりません...「中心を動かす」とはどういうことでしょうか。

なにかの課題なら、問題文をそのまま示して下さい。伝言ゲームになるとお互い時間の無駄です。

Answer 1

何を求めているのかわからないのでこれでいいのかどうか。
とにかく、for(int i=0;i<3;i++)とif文は使った。
中心云々はなにを欲しているのかわからない。

void setup() {
  size(500, 500);
  background(0);
  smooth();
  stroke(255);
}

void draw() {
  background(0);
  float[] rads={radians(second()*360/60.0-90), 
    radians(minute()*360/60.0-90), 
    radians(hour()*360/12.0-90)};
  for (int i=0; i<3; i++) {
    strokeWeight(1<<i);
    int l=100;
    if (i!=2)l*=2;
    float x=cos(rads[i])*l+250;
    float y=sin(rads[i])*l+250;
    line(250, 250, x, y);
  }
}

Answer 2

懲りずに再挑戦しますw

前回と同内容だと仮定します。
変更点

• +250や-90がノイズになるので、translate・rotateで一括変更
• 数学苦手だとcos・sinがどっちってなるので、PVector.fromAngleでわかりやすく
• ループしやすいように事前に配列を準備

void setup() {
  size(500, 500);
  stroke(255);
  smooth();
}

void draw() {
  background(0);
  translate(250, 250);
  rotate(-PI / 2);

  float hands[][] = {
    // 値, 係数, strokeLength, strokeWeight
    { second(), 360 / 60, 200, 1 }, 
    { minute(), 360 / 60, 200, 2 }, 
    { hour() + (minute() / 60.0), 360 / 12, 100, 4 } };

  for (float[] hand : hands) {
    float rad = radians(hand[0] * hand[1]);
    PVector v = PVector.fromAngle(rad).mult(hand[2]);
    strokeWeight(hand[3]);
    line(0, 0, v.x, v.y);
  }
}

---

配列後半は固定値なので分けたほうが無駄がないが、スマートに分けにくかった。
名前付きタプルなんかが使えたらよかったが、ギリギリ許容範囲かなと。

四則演算が減って、個人的には意図が分かりやすくなったかなと思います。

Answer 3

前の質問の継続でいいのかな？
では前回の質問で回答されていたmaaiさんの処理をfor文で使った方式で修正したものです。
maaiさんが作られたメソッドは引数が全てdoubleで配列化できますので

void setup()
{
  size(500,500);
  background(0);
  smooth();

}
void draw()
{
  background(0);
  float ss; //second byo
  float mm; //minute hun
  float hh; //hour   jikan

  stroke(255);

  ss = second();
  mm = minute();
  hh = hour()+(mm/60.0);

  double[][] clocks = {
    {ss*(360/60)-90, 1, 200},
    {mm*(360/60)-90, 2, 200},
    {hh*(360/12)-90, 4, 100},
  };

  for (double[] ds : clocks) {
    double rad, x, y;
    rad =radians(ds[0]); 
    strokeWeight(ds[1]);
    x = cos(rad)*ds[2]+250;
    y = sin(rad)*ds[2]+250;
    line(250,250,x,y);
  }
}