エクセル 関数 条件一致セルに〇を付ける 条件変更

Question

セルをダブルクリックすると、A2:A301セルに〇がつく仕組み。
ダブルクリックは、A2:L301の範囲で可能。
A列に〇がついた場合は、同じ行のMセルにも〇が付く。
また、Aセルに〇が入っている同じ行のBセルの数字をL列で検索し、Mセルにも〇が付く。
M2セルの数式
=IF(A2="〇","〇",IF(L2>0,IF(INDEX($A:$A,MATCH(L2,$B:$B))="〇","〇"," ")," "))
以下コピー

Dim rngTarget As Range
Dim rngFind As Range
Dim Trow As Long
    If Target.Count > 1 Then Exit Sub  '複数セル選択禁止?
    If Intersect(Target, Range("A2:L301")) Is Nothing Then Exit Sub
    Trow = Target.Row
    If Cells(Trow, 1).Value = "" Then
        Cells(Trow, 1).Value = "〇"
    Else
        Cells(Trow, 1).Value = ""
    End If

    MaxRow = Cells(Rows.Count, 2).End(xlUp).Row
    For Trow = 2 To MaxRow
         '=IF(A3="〇","〇",IF(L3>0,IF(INDEX($A:$A,MATCH(L3,$B:$B))="〇","〇"," ")," "))
         Cells(Trow, 13).Formula = "=IF(RC[-12]=""〇"",""〇"",IF(RC[-1]>0,IF(INDEX(C1:C1,MATCH(RC[-1],C2:C2))=""〇"",""〇"","" ""),"" ""))"
    Next
End Sub

コード

実際に使ってみて、A列とM列と〇が付く列がいくつもあって見にくいと思いました。
ダブルクリックで、B列とＬ列に含まれる数字両方をＡセルに〇を付けることは可能でしょうか。
現在Ｍ列で表示させている機能も、Ａ列に表示したいのですが、うまく変更できません。
Ａ列に今Ｍセルで〇にしているものも表示させられたら、Ｍ列はなくせると思ったからです。

アドバイスお願いします。

〇の付き方は、動きと違うところがありますが、エクセル画面のイメージです。

動きのイメージのお伝えががわかりにくいので追加いたします。
A2:C11セルをダブルクリックするとその行のAセルに〇がつく。
ダブルクリックした列のB列、C列にある数字がをB列、C列で検索して、数字が1つでも合致すれば、その行のAセルにも〇をつける。
という動きです。

Answer 1

こういうことでしょうか？

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim rngTarget As Range
    Dim rngFind As Range
    Dim Trow As Long
    Dim Prow As Long
    Dim mark As String
    
    If Target.Count > 1 Then Exit Sub  '複数セル選択禁止?
    If Intersect(Target, Range("A2:L301")) Is Nothing Then Exit Sub
    
    Trow = Target.Row
    Prow = Cells(Trow, 12).Value
    
    mark = IIf(Cells(Trow, 1).Value = "", "〇", "")
    
    Cells(Trow, 1).Value = mark
    If Prow > 0 Then
        Cells(Prow, 1).Value = mark
    End If

End Sub

推測第二弾

Dim rngTarget As Range
Dim rngFind As Range
Dim Trow As Long
Dim Tnum As Long
Dim Pnum As Long
Dim mark As String

If Target.Count > 1 Then Exit Sub  '複数セル選択禁止?
If Intersect(Target, Range("A2:L301")) Is Nothing Then Exit Sub

Tnum = Cells(Target.Row, 2).Value
Pnum = Cells(Target.Row, 12).Value

mark = IIf(Cells(Target.Row, 1).Value = "", "〇", "")

MaxRow = Cells(Rows.Count, 2).End(xlUp).Row
For Trow = 2 To MaxRow
    If Cells(Trow, 2).Value = Tnum Or Cells(Trow, 12).Value = Tnum Or _
        (Pnum > 0 And (Cells(Trow, 2).Value = Pnum Or Cells(Trow, 12).Value = Pnum)) Then
        Cells(Trow, 1).Value = mark
    Else
        Cells(Trow, 1).Value = ""
    End If
Next

第三弾
チカチカ対策

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

    Dim rngTarget As Range
    Dim rngFind As Range
    Dim Trow As Long
    Dim Tnum As Long
    Dim Pnum As Long
    Dim mark As String
    Dim items() As Variant
    
    If Target.Count > 1 Then Exit Sub  '複数セル選択禁止?
    If Intersect(Target, Range("A2:L301")) Is Nothing Then Exit Sub
    
    Tnum = Cells(Target.Row, 2).Value
    Pnum = Cells(Target.Row, 12).Value
    
    mark = IIf(Cells(Target.Row, 1).Value = "", "〇", "")
    
    maxrow = Cells(Rows.Count, 2).End(xlUp).Row
    
    items = Range("A2:A" & maxrow).Value
    
    For Trow = 2 To maxrow
        If Cells(Trow, 2).Value = Tnum Or Cells(Trow, 12).Value = Tnum Or _
            (Pnum > 0 And (Cells(Trow, 2).Value = Pnum Or Cells(Trow, 12).Value = Pnum)) Then
            items(Trow - 1, 1) = mark
        Else
            items(Trow - 1, 1) = ""
        End If
    Next
        
    Range("A2:A" & maxrow).Value = items
    
End Sub

Comments

[Mkasai]

質問内容に、簡素化したイメージを追加させていただきました。
よろしくお願いします。

[ttyp03]

B列の番号は必ず連番ですか？

[ttyp03]

修正版を追記しました。
ご確認ください。

[Mkasai]

ありがとうございます。
試してみましたが、どこにも〇がつかなくなってしまいました。

[ttyp03]

シートの構成は最初のものでいいんですよね？
あとから追加されたのはあくまでも説明用の簡易版ということで。
一応こちらでは動作を確認しています。

[Mkasai]

はい。そうです。
そちらでお試ししただいた時には動くのですね。
こちらの何かがおかしいのだと思います。
もう少し試してみます。
お手数おかけします。

[ttyp03]

大した処理はしていないので、ちょっと見ていただければ何が問題かはわかると思います。

[Mkasai]

動くようになりました。
最初の
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
最後の　End Sub　を忘れていました。

動きは希望のとおりなのですが、カーソルのチカチカがずっと続くのと、ファイルを開く時にすごく時間がかかるようになってしまったのですが、改善する方法はあるのでしょうか。

[ttyp03]

チカチカ対策版を追記しました。
確かに300行とかデータがあると酷かった。

ファイルを開くときの件はダブルクリックイベントとは関係ないはずなので、別に原因があるのでは。

[Mkasai]

ありがとうございました。
スムーズに作業できそうです。