Q&A
色々と条件が不足しているため適切な方法を提示できない状態です。下記について教えてください。
1.作業セルは使用可能ですか？（D列以降で数式を入れるのは可能か
2.行の追加はありますか？
2.1（ある場合）グラフ範囲は自動で変更したいですか？手動でもOKですか？
3.グラフは詰めて表示する必要がありますか？（FALSEの分間隔があくのはOKかNGか
他にも何か条件や状況があればあらかじめお知らせください。
以下のようなデータセットがあった場合に、TRUEであるデータのみをグラフに表示させたいのですが方法がわかりません。
| A1 | B1 | C1 |
|---|---|---|
| みかん | 100 | TRUE |
| りんご | 200 | TRUE |
| ぶどう | 300 | FALSE |
| メロン | 400 | TRUE |
このときに、みかん-100~メロン-400を選択してグラフ(集合横棒)にしたときに、ぶどうのみを自動的に除外(C列がfalseのため)したいです。グラフの選択時に特定の条件のデータのみグラフ表示させたい(今回の場合はC列がtrueのとき)のですがどうしたら良いでしょうか？マクロはあまり使いたくないです。
補足
上記の状態のときに表示されるグラフの項目は
みかん・りんご・メロン
次に、ぶどうのtrue -> falseに切り替え、メロンをFALSEに切り替える(入力し直す)と、
グラフに表示される項目は
みかん・りんご・ぶどう
のみになっていてほしいです。このときに、自動でグラフが反映されていてほしいです。
1. 可能です。あくまで掲示したのはグラフに反映したいデータのみにしてます。
2. 行の追加は考えていません。
3. 可能であれば詰めてほしいですが、間隔があいていても大丈夫です。
質問したいこととしては、C列内のfalse/trueを切り替えた場合(手動であっても自動であっても)、グラフにはtrueのものだけが常に表示するよう自動的に更新できないかということです。
回答2件
0
ベストアンサー
二つのパターンを記載しますね。
系列などはとりあえず仮でこちらで指定していますが
ご自分の好みで変更なさってください。
1.FALSE欄の間隔があく場合（お手軽コース）
D1
1=IF($C1,A1,"")
E4までコピーし、D1からE4でグラフ作成。
系列名：ブランク
系列値：=Sheet1!$F$1:$F$4
軸ラベル：=Sheet1!$E$1:$E$4
2.間隔はあかないしTRUE、FALSEの切り替えにも対応
（ただし少しややこしい）
D1
1=IF(C1,COUNTIF($C$1:C1,TRUE),0)
D4までコピー
E1
1=IFERROR(INDEX(A:A,MATCH(ROW(),$D:$D,0)),"")
F4までコピー
■名前の定義の作成（二つ）
※名前は仮でつけています、シート名は該当するものに変更してください
・一つ目
名前：くだもの
範囲：ブック
参照範囲：
=OFFSET(Sheet1!$E$1,0,0,ROWS(A:A)-COUNTBLANK(Sheet1!$E:$E),1)
・二つ目
名前：値段
範囲：ブック
参照範囲：
=OFFSET(Sheet1!$F$1,0,0,ROWS(A:A)-COUNTBLANK(Sheet1!$F:$F),1)
一旦E1:F4でグラフ作成
系列名：ブランク
系列値：=Sheet1!$F$1:$F$4
軸ラベル：=Sheet1!$E$1:$E$4
グラフをクリック（棒の部分）
そうすると数式バーに下記数式が表示されているはず。
=SERIES(,Sheet1!$E$1:$E$4,Sheet1!$F$1:$F$4,1)
これを下記の通り変更する
=SERIES(,Book1!くだもの,Book1!値段,1)
名前の定義の「範囲」をシートにしていた場合は「Book1!」の部分を
該当するシート名に変更する必要があります。
以上です。
投稿2020/02/17 14:42
総合スコア1925
0
対象データをフィルタします。
（フィルタするために１行目を追加する必要があります）
A2:B5を対象にしてグラフを作成する。
フィルタでFALSEを除外する。
という方法なら可能でした。
データの方はFALSEも表示しつつ、グラフで非表示はちょっとわかりませんでした。
投稿2020/02/17 05:19
総合スコア17000
あなたの回答
tips
プレビュー
