ADODB.RecordsetのField順を入れ替えたい

Question

前提・実現したいこと

ExcelVBAでADODB.Recordsetを利用してデータを収集、加工して出力を行います。
CopyFromRecordsetする際に、RecordsetのField順が例えば「ID,日付,数量,金額」となっている場合、「ID,数量,金額,日付」となるようにRecordsetの順番を変える、
もしくは編集したRecordsetに対し、「SELECT ID,数量,金額,日付 FROM [hoge.csv] 」のようなSQLで列名を指定して出力するなどできるでしょうか。

該当のソースコード

Option Explicit

'参照設定：Microsoft ActiveX Data Objects 6.1 Library
#Const REF_CSVOperator = True 'プリプロセッサディレクティブ '参照設定しない場合はFalse

#If REF_CSVOperator Then
    Dim adoConn As ADODB.Connection
    Dim adoRs As ADODB.Recordset
    Dim FSO As FileSystemObject
#Else
    Dim adoConn As Object
    Dim adoRs As Object
    Dim FSO As Object
#End If

Private mCSVPath As String

Private Sub Class_Initialize()
    Set adoConn = CreateObject("ADODB.Connection")
    Set adoRs = CreateObject("ADODB.Recordset")
    Set FSO = CreateObject("Scripting.FileSystemObject")
End Sub

Public Property Let CSVPath(Path As String, Header As Boolean)
    mCSVPath = Path
    With adoConn
        .Provider = "Microsoft.ACE.OLEDB.12.0"
        If Header Then
            .Properties("Extended Properties") = "Text;HDR=Yes;FMT=Delimited"
        Else
            .Properties("Extended Properties") = "Text;HDR=No;FMT=Delimited"
        End If
        .Open FSO.GetParentFolderName(mCSVPath) & "\"
        
        Set adoRs = .Execute("SELECT * FROM [" & FSO.GetFileName(mCSVPath) & "]")
    End With
End Property

Public Sub CopyFromRecordset(ByRef rng As Range)
    rng.CopyFromRecordset adoRs
End Sub

Private Sub Class_Terminate()
    On Error Resume Next
    adoRs.Close: Set adoRs = Nothing
    adoConn.Close: Set adoConn = Nothing
    On Error GoTo 0
End Sub

補足情報（FW/ツールのバージョンなど）

参照設定：Microsoft Scripting Runtime, Micorosoft ActiveX Data Objects 6.1 Library

Answer 1

SELECTを変えられないのであれば、GetRows メソッド (ADO)を使うのも手です。

GetRowsにフィールドの配列を渡せば、そのフィールドの値だけを持った2次元配列を取得できるため、それをセルに代入します。

GetRowsの欠点として縦横逆という点がありますが、Excel側でカバーできます。

動作検証していないですが、以下のようなイメージです。

Public Sub CopyFromRecordset2(rng As Range) ''ByRefでもByValでもどっちでもいい。
    '出力したいフィールドの名前(要Variant型配列)。
    Dim columnNames() As Variant
    columnNames = VBA.Array("ID", "数量", "金額", "日付")
    
    'GetRowsでcolumnNamesの列の値を抽出した配列を取得(縦横逆=横に長い配列)。
    Dim records() As Variant
    records = adoRs.GetRows(Fields:=columnNames)
    
    'ワークシート関数のTRANSPOSEで縦横逆転。
    Dim transposedRecords() As Variant
    transposedRecords = rng.Application.WorksheetFunction.Transpose(records)
    
    '配列で出力するため、配列の大きさの取得が必要。
    Dim rowSize As Long, colSize As Long
    rowSize = UBound(transposedRecords, 1) - LBound(transposedRecords, 1) + 1
    colSize = UBound(transposedRecords, 2) - LBound(transposedRecords, 2) + 1
    
    'セルへ出力。
    rng.Resize(rowSize, colSize).Value = transposedRecords
    
End Sub

Answer 2

SELECT * の*の箇所に、フィールド名をカンマ区切りで列挙すればよいです
SELECT ID,数量,金額,日付 FROMみたいな

Comments

[woria]

adoConn.ExecuteでadoRsにSetした後からフィールドの順番を変更することは可能ですか？

[退会済みユーザー]

データ取得する時点で並べ替えをするには、SELECT文で工夫できますが。
取得後に順序を変えたいなら、CopyFromRecordset などと横着せず、
ForあるいはFor Eachループでフィールドごとに転記する処理を丁寧に書くしか無いかと。

[woria]

わかりました。ありがとうございます。