VBAでFilesコレクションからオブジェクトを逆順に取得する方法

Question

VBAでFilesコレクションからオブジェクトを逆順に取得する方法

初めてVBAで開発をしている者です。

現在、フォルダ内の画像を取得し、エクセルシートに張り付けるマクロを書いています。
フォルダ内の画像を順番（昇順）に取得することは、以下のコードで実現することができました。

 For Each objFile In objFldr.GetFolder(strSelect).Files
            Debug.Print TypeName(objFile)
            ActiveSheet.Shapes.AddPicture _
                Filename:=objFile, _
                LinkToFile:=False, _
                SaveWithDocument:=True, _
                Left:=c.Left, _
                Top:=c.Top, _
                Width:=c.Width, _
                Height:=c.Height
                count = count + 1
                
            If flag = True Then
                flag = False
                Set c = c.Offset(0, 2)
            Else
                flag = True
                Set c = c.Offset(3, -2)
            End If
            If count = 8 Then
                Set c = c.Offset(3, 0)
                count = 0
            End If
Next

しかし、画像を逆順（降順）に取得するため、以下のコードを記述した場合、エラーが発生してしまいます。

Set objFile = objFldr.GetFolder(strSelect).Files
        Dim i As Long
        For i = objFile.count To 1 Step -1
                ActiveSheet.Shapes.AddPicture _
                    Filename:=objFile.Item(i), _ 'エラーが発生している部分
                    LinkToFile:=False, _
                    SaveWithDocument:=True, _
                    Left:=c.Left, _
                    Top:=c.Top, _
                    Width:=c.Width, _
                    Height:=c.Height
                    count = count + 1
                    
                If flag = True Then
                    flag = False
                    Set c = c.Offset(0, 2)
                Else
                    flag = True
                    Set c = c.Offset(3, -2)
                End If
                If count = 8 Then
                    Set c = c.Offset(3, 0)
                    count = 0
                End If
        Next i

filesコレクションの要素を取得するやり方として、（filesコレクション）.Itemという
書き方がそもそも違うのでしょうか？
それともfilesコレクションに対してインデックスを指定して取得することはできないのでしょうか？

解決策が見つけられず質問致しました。
稚拙な質問で申し訳ないですが、よろしくお願い致します。

発生している問題・エラーメッセージ

実行時エラー'5':
プロシージャの呼び出し、または引数が不正です。

Comments

[Zuishin]

http://wsh.style-mods.net/ref_files/index.htm

Item はありますね。ただ数値ではなくファイル名を指定します。

http://wsh.style-mods.net/ref_files/item.htm

配列に入れてソートするのが良いでしょう。

[naonaoki]

回答ありがとうございます！
無事解決しました！

Answer 1

Microsoftのオフィシャルな記事ではないと思いますが
以下のURLに記述があります。

https://www.moug.net/tech/exvba/0060001.html (mougモーグ)

実は、FileSystemObjectのFilesコレクションは、

「Fles("Sample.xls")」

のようにメンバー名で特定することはできても、

「Files(1)」

のような、インデックス値による特定はできないのです。

Comments

[naonaoki]

インデックス取得できないのは何となく不便ですね…
回答ありがとうございます！

Answer 2

降順も昇順もソートを行うことをすすめます。
NTFSはソートされて取得できますが
FAT32の場合ファイルの作成された順に取得されます。

Comments

[dodox86]

質問自体は「Itemが使えないのか」と言うことに関してですが、ソート順について触れられていたので高評価させていただきました。
sinzouさんが指摘されているように、Filesコレクションでの列挙でファイル名がソートされて取得できるかどうかは、意外と考慮に入れられていないことが多いようです。
https://docs.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/files-collection
でも、公式には並び順に触れられていません。USBメモリなどファイルシステムが違う場合に問題が発覚します。

[sinzou]

ソートすることを省略せずに
NTFSでもFAT32でも誤動作がないプログラム組めますよー

との意味で投稿しました　すみません。

[naonaoki]

回答ありがとうございます！
ファイルシステムによってソートの違いがあるんですね…
勉強になりました。
降順貼り付けが解決したので昇順の方でもソートすることにしてみます。

Answer 3

ドキュメントを見たところ、Itemメソッドはなさそうですね。
一旦、配列にファイル名を格納してから逆順でファイル名を取得するのが良いかと思います。

Comments

[naonaoki]

回答ありがとうございます！
無事解決することができました！

Answer 4

出来ないなら自作するまでかなぁ。。。。

Option Explicit

Sub test()
    Dim FSO As FileSystemObject
    Dim myFiles As Collection
    Dim i As Long
    Dim f As File

    Set FSO = New FileSystemObject
    Set myFiles = New Collection

    If GetMyFiles(FSO.GetFolder("C:\Users\hiraigumit\Pictures"), myFiles) Then
        For Each f In myFiles
            i = i + 1
            SetDeploy f, i
        Next
    End If
End Sub

Function GetMyFiles(ByRef objFolder As Folder, _
                    ByRef objResult As Collection) As Boolean
    Dim i As Long
    Dim f As File

    For Each f In objFolder.Files
        If objResult.Count > 1 Then
            objResult.Add Item:=f, Key:=f.Name, before:=1
        Else
            objResult.Add Item:=f, Key:=f.Name
        End If
    Next

    GetMyFiles = objResult.Count
End Function

Sub SetDeploy(ByRef pFile As File, _
              ByVal ix As Long)
    Dim Rng As Range
    Dim c As Range
    Dim Pic As Shape

    Set Rng = ThisWorkbook.Worksheets(1).Range("D:G")
    Set c = Rng(ix)

    On Error Resume Next
    With c
        Set Pic = .Worksheet.Shapes.AddPicture( _
                  Filename:=pFile.Path, _
                  LinkToFile:=False, _
                  SaveWithDocument:=True, _
                  Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
    End With
End Sub

Comments

[naonaoki]

回答ありがとうございます！
解決するにあたって参考にさせていただきました！

[naonaoki]

どれもベストアンサーにしたかったのですが、
わざわざコードを書いてくださっていたので今回はこちらを
ベストアンサーにさせていただきました…