excel VBA MSDASQL でシートの内容をSQLで取得したら文字化けが発生する

Question

エクセルマクロで以下コードを組み指定したシートからデータを取得しようとしています。

取得元のシートでは多言語（中国語など）が入力されており
データ取得時（Recordset内で確認）に文字化けが発生しています。
取得時の文字コードをUtf-8などに指定して取得したいのですが
以下コードの場合何処のタイミングで
どのように指定するのかご教授願えますでしょうか

    Dim cn As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim xl_file As String
    Dim sql As String
    Dim curRow As Integer
    
    'エクセルファイル指定（ここでは自分のBOOK）
    xl_file = ThisWorkbook.FullName
 
    Set cn = New ADODB.Connection
    cn.Provider = "MSDASQL"

    ' 64bit
    cn.ConnectionString = "Driver={Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)}; " & "DBQ=" & xl_file & "; ReadOnly=False;"

    cn.Open

    Set rs = New ADODB.Recordset

    sql = " SELECT" _
        & "  A.カラム１ AS A," _
        & "  A.カラム２ AS B" _
        & " FROM" _
        & "  [シート1$] A"

    rs.Open sql, cn, adOpenStatic
 
    ' 表示データクリア
    Sheets("TEST").Range("A2:AZ100000").Value = ""
 
    curRow = 2
    Do Until rs.EOF
        Sheets("TEST").Range("A" & curRow).Value = rs!A
        Sheets("TEST").Range("B" & curRow).Value = rs!B
        rs.MoveNext
        curRow = curRow + 1
    Loop
 
    rs.Close
    cn.Close
    Set rs = Nothing
    Set cn = Nothing

Answer 1

ExcelのシートはUnicode対応ですが、VBAエディターはshift_JISですので、
Shift_JISにない文字はVBAエディター上では表示されません(？で表示されます)

ただ、ADO接続でシート転記時には表示されると思います。
※提示のコードでは転記時も文字化けのままになるかと思います。

Provider/ConnectionStringを下記に変更

cn.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;" _
                      & "Data Source=" & xl_file & ";" _
                      & "Extended Properties=""Excel 8.0;" _
                      & "HDR=Yes"";"

[補足]
Provider、Extended Propertiesの部分は環境によっては変更が必要
になるかもしれません。

Comments

[KKEENN]

Provider=Microsoft.ACE.OLEDB.12.0;　に変更したところ文字化けは起こりませんでした。

ご回答ありがとうございます。