VBAで2つのテキストデータ(.txt)をExcelの指定したセルにそれぞれコピーする

Question

前提・実現したいこと

初めて質問します。
A.txtとB.txtのデータをエクセルファイルに取り込み、指定のセル、例えば、AのデータをA11以降のセル、
BのデータをB11以降のセルに貼り付けたいと思っています。ちなみにAとBは行数が同じで、Aは外国語、
Bはその日本語訳です。また、コードでファイルを指定するのではなく、ダイアログを開いて別々にファイルを
選択するようにしたいです。なお、テキストデータの文字コードはUTF-8になっており、文字化けしないように
する必要があります。

発生している問題・エラーメッセージ

色々と試行錯誤しながら、1ファイルのデータをA11以降のセルに書き込むことはできましたが、
文字コードの指定の仕方がよくわからず、文字化けになってしまいます。特に、Bの日本語データは
壊滅的な状態です。
2ファイルのデータを書き込むには、どうすればよいのやら...
どうかお力添えください。よろしくお願いいたします。

該当のソースコード

Sub Load_Souce()

Dim txtName As String
txtName = Application.GetOpenFilename("テキストファイル,*.txt")

If txtName <> "False" Then
    Open txtName For Input As #1
End If

Dim X As Double
Dim TXT As String

X = 0

 Do While Not EOF(1)
 Line Input #1, TXT
 Cells(11, 1).Offset(X, 0) = TXT
 X = X + 1
 Loop

Close #1

試したこと

ここに問題に対して試したことを記載してください。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

面倒な文字コード変換などはExcelにまかせてしまってはいかがでしょうか。
つまりテキストファイルをワークブックとして扱うということです。

Sub PasteText(fn As String, dst As Range)
    Application.ScreenUpdating = False
    Dim wb As Workbook
    Set wb = Workbooks.Open(fn)
    wb.Worksheets(1).Cells(1, 1).CurrentRegion.Copy
    dst.PasteSpecial xlPasteValues
    wb.Close
    Application.ScreenUpdating = True
End Sub

Sub Load_Souce()
    Dim txtName As String
    
    ' 1つ目のファイル
    txtName = Application.GetOpenFilename("テキストファイル,*.txt")
    If txtName <> "False" Then
        Call PasteText(txtName, Range("A11"))
    End If
    
    ' 2つ目のファイル
    txtName = Application.GetOpenFilename("テキストファイル,*.txt")
    If txtName <> "False" Then
        Call PasteText(txtName, Range("B11"))
    End If
End Sub

---

改良版です。
あまり変わっていませんが、文字コードは明確に指定しないといけなくなってしまいました。

Sub PasteText(fn As String, cp As Variant, dst As Range)
    Application.ScreenUpdating = False
    Dim wb As Workbook
    Workbooks.OpenText Filename:=fn, Origin:=cp, FieldInfo:=Array(1, xlTextFormat)
    Set wb = ActiveWorkbook
    wb.Worksheets(1).Cells(1, 1).CurrentRegion.Copy
    dst.PasteSpecial xlPasteValues
    wb.Close
    Application.ScreenUpdating = True
End Sub

Sub Load_Souce()
    Dim txtName As String

    ' 1つ目のファイル(ANSI)
    txtName = Application.GetOpenFilename("テキストファイル,*.txt")
    If txtName <> "False" Then
        Call PasteText(txtName, 932, Range("A11"))
    End If

    ' 2つ目のファイル(UTF8)
    txtName = Application.GetOpenFilename("テキストファイル,*.txt")
    If txtName <> "False" Then
        Call PasteText(txtName, 65001, Range("B11"))
    End If
End Sub

Comments

[nbotnk]

早速ご回答くださり、ありがとうございます。
ご紹介いただいたコードで実行したところ、ほぼ期待どおりの結果が得られました。
ただ、先頭がハイフンで始まっているテキストは「#NAME?」が貼り付けられ、
日本語は全て文字化けしているので、これらを解消したいです。
何かよいアイデアがございましたら、引き続きご教示ください。

[ttyp03]

ハイフンについては盲点でした。
改良版を追記してみましたので、こちらで試していただけますか。

[nbotnk]

改良版ありがとうございます。
説明が足りなかったのか、1ファイル目の外国語の文字が文字化けして
しまいましたが、65001に変更すると、どちらも正常に開くことができ
ました。迅速にご回答いただき、助かりました。

[ttyp03]

外国語=英語、と勝手に思ってましたが違ったのですね。
何にしても無事に出来てよかったです。