描画されない原因について

Question

前提・実現したいこと

追加したコードを動かしたい。

発生している問題・エラーメッセージ

下記のコード中に記してある(←追加したもの)コードを追加した所、
実行しても描画されなくなってしまいました。
エラーメッセージも出ておらず、何が原因なのか分かりません。
追加する場所を間違えているのでしょうか？

該当のソースコード

import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;
import ddf.minim.signals.*;
import ddf.minim.spi.*;
import ddf.minim.ugens.*;

Minim minim;
AudioPlayer player;
int buffersize = 512;

class Note {
  final float x;
  final float y;
  final float w;
  final float h;

  final float r;
  final float r2;

  final color col;//HSB, alpha

  boolean isAlive = true;

  Note(final float x, final float y, final float playerIn) {
    this.x = random(minx, maxx); //横　←追加したもの
    this.y = random(miny, maxy); //縦　←追加したもの
    this.w = playerIn/2;
    this.h = playerIn/2;
    this.r = this.w / 2;
    this.r2 = this.r * this.r;
    this.col = color(random(360), 100, 100, 70);
  }

  void draw() {
    colorMode(HSB, 360, 100, 100, 100);
    noStroke();
    fill(col);
    // ellipse(x, y, w, h);
  }

  void update() {
  }

  boolean isExpired() {
    return !isAlive;
  }

  void toggle() {
    isAlive = !isAlive;
  }
}

abstract class Effect {
  protected float time;
  protected float t = 0;
  final float dt = 1.0;

  Effect() {
  }

  abstract void draw();

  abstract void update();

  void dec() {
    time -= dt;
    t += dt;
  }

  boolean isExpired() {
    return time < 0;
  }
}

abstract class MultiEffect extends Effect {
  ArrayList<Effect> chidren = new ArrayList<Effect>();

  MultiEffect() {
  }

  @Override
    void draw() {
    for (Effect eff : chidren) {
      eff.draw();
    }
  }

  @Override
    void update() {
    for (Effect eff : chidren) {
      eff.update();
    }
  }

  @Override
    boolean isExpired() {
    for (Effect eff : chidren) {
      if (!eff.isExpired()) return false;
    }
    return true;
  }
}

class Bakuhatu extends Effect {
  final float x;
  final float y;
  float r;
  float dr = 1;
  final float ddr = 0.5;

  final int R, G, B;
  int alpha;
  int da = 0;
  final int dda = 1;

  Bakuhatu(final float x, final float y, final float r, final color col, final float time) {
    this.x = x;
    this.y = y;
    this.r = r;

    final int mask = 0xFF;
    alpha = (col>>24) & mask;
    alpha /= 2;
    R = (col>>16) & mask;
    G = (col>>8) & mask;
    B = col & mask;

    this.time = time;
  }

  @Override
    void draw() {
    noStroke();
    //fill(col);
    colorMode(RGB);
    fill(R, G, B, alpha);
    ellipse(x, y, 2*r, 2*r);
  }

  @Override
    void update() {
    dec();
    r += dr;
    dr += ddr;

    alpha -= da;
    da += dda;
  }
}

final float g = 0.2;

class Hinoko extends Effect {
  float x;
  float y;
  final float r = 2;
  final float v0 = 5;
  float vx;
  float vy;

  final float theta;

  final color col;
  int R, G, B;
  int alpha;
  float da = 1;
  final float dda = 0.05;
  float drx, dry;
  float ddrx, ddry;

  Hinoko(final float x, final float y, final float r, final color col, final float theta, final float time) {

    this.x = x;
    this.y = y;
    this.vx = v0 * cos(theta);
    this.vy = v0 * sin(theta);
    this.col = col;

    final int mask = 0xFF;
    alpha = (col>>24) & mask;
    //alpha /= 2;
    R = (col>>16) & mask;
    G = (col>>8) & mask;
    B = col & mask;

    this.drx = 0.5;
    this.dry = 0.05;
    this.ddrx = 0.5;
    this.ddry = 0.05;

    this.time = time;
    this.theta = theta;
  }

  @Override
    void draw() {
    noStroke();
    colorMode(RGB);
    fill(R, G, B, alpha);
    ellipse(x, y, r, r);
  }

  @Override
    void update() {
    dec();

    alpha -= da;
    da += dda;

    x += vx;
    y += vy;
    y += g*t;

    drx += ddrx;
    dry += ddry;
  }
}

class Hanabi extends MultiEffect {
  Hanabi(final float x, final float y, final float r, final color col) {
    super();

    final float timeB = 30;
    chidren.add(new Bakuhatu(x, y, r, col, timeB));

    final float timeH = 50;
    final int max = 32;
    final float dtheta = TWO_PI / max;
    for (int i=0; i<max; i++) {
      chidren.add(new Hinoko(x, y, r, col, dtheta*i, timeH));
    }
  }
}

class Effects extends ArrayList<Effect> {
  Effects() {
    //do nothing
  }

  void add(Effects temp) {
    this.addAll(temp);
  }

  void draw() {
    for (Effect eff : this) {
      eff.draw();
    }
  }

  void update() {
    ArrayList<Effect> temp = new ArrayList<Effect>();
    for (Effect eff : this) {
      eff.update();
      if (!eff.isExpired()) temp.add(eff);
    }
    this.clear();
    this.addAll(temp);
  }
}

class NoteController {
  ArrayList<Note> notes = new ArrayList<Note>();

  final float margin = 100;
  final float xmin = margin;
  final float xmax = width-margin;
  final float ymin = margin;
  final float ymax = height-margin;

  NoteController() {
    //
  }
  //円の制御
  void add(final float playerIn) {
    if (notes.size() > 100) return;//check
    if (playerIn < 20) return;
    if (frameCount % 20 != 0) return;

    final float x = random(xmin, xmax); 
    final float y = random(ymin, ymax);
    notes.add(new Note(x, y, playerIn));
  }

  void draw() {
    for (Note note : notes) {
      note.draw();
    }
  }

  ArrayList<Note> update() {
    ArrayList<Note> next = new ArrayList<Note>();
    ArrayList<Note> del = new ArrayList<Note>();
    for (Note note : notes) {
      note.update();
      if (note.isExpired()) {
        del.add(note);
      } else {
        next.add(note);
      }
    }
    notes.clear();
    notes.addAll(next);
    return del;
  }

  //真偽を使って判断
  boolean isHit(final Note note) {
    return true;
  }
  //全指定
  void mouseClicked() {
    for (Note note : notes) {
      note.toggle();
    }
  }
}

class Converter {
  Effects makeHanabis(ArrayList<Note> notes) {
    Effects temp = new Effects();
    for (Note note : notes) {
      temp.add(makeHanabi(note));
    }
    return temp;
  }

  Hanabi makeHanabi(Note note) {
    Hanabi temp = new Hanabi(note.x, note.y, note.r, note.col);
    return temp;
  }
}

NoteController controller;
Effects effects;
Converter converter;

float minx, maxx;
float miny, maxy;
ArrayList<PVector> bow=new ArrayList<PVector>();

void setup() {
  fullScreen();
  frameRate(60);
  colorMode(HSB, 360, 100, 100, 100);
  controller = new NoteController();
  effects = new Effects();
  converter = new Converter();

  minim = new Minim(this);
  //in = minim.getLineIn(Minim.STEREO,buffersize);
  final String fn = "Mountain.mp3";
  player = minim.loadFile(fn);
  player.loop();
}

void draw(float x, float y) {
  background(200);

  Tree(30, width/2, height, PI, width/7);

  //↓追加したもの
EXIT:
  while (true) {
    x = random(minx, maxx); //横
    y = random(miny, maxy); //縦
    for (PVector p : bow) {
      if (dist(x, y, p.x, p.y )<20) {

        noStroke();
        fill(random(255), random(255), random(255), 50);
        ellipse(x, y, 10, 10);

        fill(#959592);
        rect(0, 1030, 2000, 50);
        break EXIT;
      }
    }
  }
  //↑追加したもの

  final float playerIn = player.mix.level()*150;
  controller.add(playerIn);
  controller.draw();
  ArrayList<Note> temp = controller.update();

  effects.add(converter.makeHanabis(temp));
  effects.draw();
  effects.update();
}

//木の生成
void Tree(float strokeWeight, float x, float y, float rotate, float length) {
  pushMatrix();  //座標を一時保存
  translate(x, y);  //座標移動
  rotate(rotate);  //座標回転
  strokeWeight(strokeWeight);  //線の輪郭線の太さ
  stroke(70, 0, 0);  //線の色
  line(0, 0, 0, length);  //線の描画,配列の長さ
  popMatrix();  //変更した座標を元に戻す

  //↓追加したもの
  if (strokeWeight<2 || x%5>3 && strokeWeight<3) {
    float xx=x-sin(rotate)*length;
    float yy=y+cos(rotate)*length;
    if (xx<minx) {
      minx=xx;
    }
    if (xx>maxx) {
      maxx=xx;
    }
    if (yy<miny) {
      miny=yy;
    }
    if (yy>maxy) {
      maxy=yy;
    }
    PVector endp=new PVector(xx, yy);
    bow.add(endp);
    return;
  }
  //↑追加したもの

  Tree(strokeWeight*2/3, x-sin(rotate)*length, y+cos(rotate)*length, rotate-PI/10, length*2/3);
  Tree(strokeWeight*2/3, x-sin(rotate)*length, y+cos(rotate)*length, rotate+PI/10, length*2/3);
}

void  keyPressed() {
  if (key  ==  's') { //音楽ストップ
    player.pause();
  } else  if (key  ==  'r') { //音楽リスタート
    player.rewind();
    player.play();
  }
}

void stop() {
  minim.stop();
  super.stop();
}

void mouseClicked() {
  controller.mouseClicked();
}

補足情報（FW/ツールのバージョンなど）

Processing 3.5.3

Answer 1

1日掛けてなんとかプログラムを動かす事が出来ました！
まだ過去の試行錯誤による余計な残りものや書き方が汚い点がありますが、
これから仕上げて完成形にしたいと思います。
thkana様には大変お世話になりました。心より感謝申し上げます。

import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;
import ddf.minim.signals.*;
import ddf.minim.spi.*;
import ddf.minim.ugens.*;

float minx, maxx;
float miny, maxy;
ArrayList<PVector> bow=new ArrayList<PVector>();

Minim minim;
//AudioInput in;
AudioPlayer player;
//float volumeIn;
int buffersize = 512;

class Note {
  final float x;
  final float y;
  final float w;
  final float h;
  final float r;
  final float r2;

  final color col;//HSB, alpha

  boolean isAlive = true;

  Note(final float x, final float y, final float playerIn) {
    int n=(int)random(0, bow.size());
    float r=random(0, 10);
    float th=random(0, PI*2);
    this.x = bow.get(n).x+r*cos(th);
    this.y = bow.get(n).y+r*sin(th);
    this.w = playerIn/3;
    this.h = playerIn/3;

    this.r = this.w / 2;
    this.r2 = this.r * this.r;

    this.col = color(random(360), 100, 100, 200);
  }

  void draw() {
    colorMode(HSB, 360, 100, 100, 200);
    noStroke();
    fill(col);
    ellipse(x, y, w, h);
  }

  void update() {
  }

  boolean isExpired() {
    return !isAlive;
  }

  void toggle() {
    isAlive = !isAlive;
  }
}

abstract class Effect {
  protected float time;
  protected float t = 0;
  final float dt = 1.0;

  Effect() {
  }

  abstract void draw();

  abstract void update();

  void dec() {
    time -= dt;
    t += dt;
  }

  boolean isExpired() {
    return time < 0;
  }
}

abstract class MultiEffect extends Effect {
  ArrayList<Effect> chidren = new ArrayList<Effect>();

  MultiEffect() {
  }

  @Override
    void draw() {
    for (Effect eff : chidren) {
      eff.draw();
    }
  }

  @Override
    void update() {
    for (Effect eff : chidren) {
      eff.update();
    }
  }

  @Override
    boolean isExpired() {
    for (Effect eff : chidren) {
      if (!eff.isExpired()) return false;
    }
    return true;
  }
}

class Bakuhatu extends Effect {
  final float x;
  final float y;
  float r;
  float dr = 1;
  final float ddr = 0.5;
  //color col;

  final int R, G, B;
  int alpha;
  int da = 0;
  final int dda = 1;

  Bakuhatu(final float x, final float y, final float r, final color col, final float time) {
    this.x = x;
    this.y = y;
    this.r = r;

    final int mask = 0xFF;
    alpha = (col>>24) & mask;
    alpha /= 2;
    R = (col>>16) & mask;
    G = (col>>8) & mask;
    B = col & mask;

    this.time = time;
  }

  @Override
    void draw() {
    noStroke();
    //fill(col);
    colorMode(RGB);
    fill(R, G, B, alpha);
    ellipse(x, y, 2*r, 2*r);
  }

  @Override
    void update() {
    dec();
    r += dr;
    dr += ddr;

    alpha -= da;
    da += dda;
  }
}

final float g = 0.2;

class Hinoko extends Effect {
  float x;
  float y;
  final float r = 2;
  final float v0 = 5;
  float vx;
  float vy;

  final float theta;

  final color col;
  int R, G, B;
  int alpha;
  float da = 1;
  final float dda = 0.05;

  //final float start;

  float drx, dry;
  float ddrx, ddry;

  Hinoko(final float x, final float y, final float r, final color col, final float theta, final float time) {

    this.x = x;
    this.y = y;

    this.vx = v0 * cos(theta);
    this.vy = v0 * sin(theta);

    this.col = col;
    //this.col = color(h,s,b,alpha);

    final int mask = 0xFF;
    alpha = (col>>24) & mask;
    //alpha /= 2;
    R = (col>>16) & mask;
    G = (col>>8) & mask;
    B = col & mask;

    this.drx = 0.5;
    this.dry = 0.05;
    this.ddrx = 0.5;
    this.ddry = 0.05;

    this.time = time;
    //this.start = time;
    this.theta = theta;
  }

  @Override
    void draw() {
    noStroke();
    colorMode(RGB);
    fill(R, G, B, alpha);
    //fill(col);
    ellipse(x, y, r, r);
  }

  @Override
    void update() {
    dec();

    alpha -= da;
    da += dda;

    x += vx;
    y += vy;
    y += g*t;

    drx += ddrx;
    dry += ddry;
  }
}

class Hanabi extends MultiEffect {
  Hanabi(final float x, final float y, final float r, final color col) {
    super();

    final float timeB = 30;
    chidren.add(new Bakuhatu(x, y, r, col, timeB));

    final float timeH = 50;
    final int max = 32;
    final float dtheta = TWO_PI / max;
    for (int i=0; i<max; i++) {
      chidren.add(new Hinoko(x, y, r, col, dtheta*i, timeH));
    }
  }
}

class Effects extends ArrayList<Effect> {
  Effects() {
    //do nothing
  }

  void add(Effects temp) {
    this.addAll(temp);
  }

  void draw() {
    for (Effect eff : this) {
      eff.draw();
    }
  }

  void update() {
    ArrayList<Effect> temp = new ArrayList<Effect>();
    for (Effect eff : this) {
      eff.update();
      if (!eff.isExpired()) temp.add(eff);
    }
    this.clear();
    this.addAll(temp);
  }
}

class NoteController {
  ArrayList<Note> notes = new ArrayList<Note>();

  final float margin = 100;
  final float xmin = margin;
  final float xmax = width-margin;
  final float ymin = margin;
  final float ymax = height-margin;

  NoteController() {
    //
  }
  //円の制御
  void add(final float playerIn) {
    if (notes.size() > 100) return;//check
    if (playerIn < 20) return;
    if (frameCount % 20 != 0) return;
    //if (frameCount  % (int)random(10, 40) != 0) return;

    final float x = random(xmin, xmax); 
    final float y = random(ymin, ymax);
    notes.add(new Note(x, y, playerIn));
  }

  void draw() {
    for (Note note : notes) {
      note.draw();
    }
  }

  ArrayList<Note> update() {
    ArrayList<Note> next = new ArrayList<Note>();
    ArrayList<Note> del = new ArrayList<Note>();
    for (Note note : notes) {
      note.update();
      if (note.isExpired()) {
        del.add(note);
      } else {
        next.add(note);
      }
    }
    notes.clear();
    notes.addAll(next);
    return del;
  }

  //真偽を使って判断
  boolean isHit(final Note note) {
    return true;
  }
  //全指定
  void mouseClicked() {
    for (Note note : notes) {
      note.toggle();
    }
  }
}

class Converter {
  Effects makeHanabis(ArrayList<Note> notes) {
    Effects temp = new Effects();
    for (Note note : notes) {
      temp.add(makeHanabi(note));
    }
    return temp;
  }

  Hanabi makeHanabi(Note note) {
    Hanabi temp = new Hanabi(note.x, note.y, note.r,note.col);
    return temp;
  }
}

NoteController controller;
Effects effects;
Converter converter;

void setup() {
  fullScreen();
  frameRate(60);

  /*Tree(30, width/2, height, PI, width/8);
   fill(#8B7250);
   rect(0, 1030, 2000, 50); */

  colorMode(HSB, 360, 100, 100, 100);
  controller = new NoteController();
  effects = new Effects();
  converter = new Converter();

  minim = new Minim(this);
  //in = minim.getLineIn(Minim.STEREO,buffersize);
  final String fn = "Mountain.mp3";
  player = minim.loadFile(fn);
  player.loop();
}

void draw() {
  background(200);

  Tree(30, width/2, height, PI, width/7);
  noStroke();
  fill(#8B7250);
  rect(0, 1030, 2000, 50); 

  // volumeIn = in.mix.level()*200;
  final float playerIn = player.mix.level()*150;
  controller.add(playerIn);
  controller.draw();
  ArrayList<Note> temp = controller.update();

  effects.add(converter.makeHanabis(temp));
  effects.draw();
  effects.update();
}

//木の生成
void Tree(float strokeWeight, float x, float y, float rotate, float length) {
  pushMatrix();  //座標を一時保存
  translate(x, y);  //座標移動
  rotate(rotate);  //座標回転
  strokeWeight(strokeWeight);  //線の輪郭線の太さ
  stroke(#64482A);  //線の色
  line(0, 0, 0, length);  //線の描画,配列の長さ
  popMatrix();  //変更した座標を元に戻す
  if (strokeWeight<2 || x%5>3 && strokeWeight<3) {
    float xx=x-sin(rotate)*length;
    float yy=y+cos(rotate)*length;
    if (xx<minx) {
      minx=xx;
    }
    if (xx>maxx) {
      maxx=xx;
    }
    if (yy<miny) {
      miny=yy;
    }
    if (yy>maxy) {
      maxy=yy;
    }
    PVector endp=new PVector(xx, yy);
    bow.add(endp);
    return;
  }
  Tree(strokeWeight*2/3, x-sin(rotate)*length, y+cos(rotate)*length, rotate-PI/10, length*2/3);
  Tree(strokeWeight*2/3, x-sin(rotate)*length, y+cos(rotate)*length, rotate+PI/10, length*2/3);
}

int count = 1;

void  keyPressed() {
  if (key  ==  's') { //音楽ストップ
    player.pause();
  } else  if (key  ==  'r') { //音楽リスタート
    player.rewind();
    player.play();
  }
  
  // Pのキーが入力された時に保存
  if (key == 'p' || key == 'P') {

    // デスクトップのパスを取得
    String path  = System.getProperty("user.home") + "/Desktop/screenshot" + count + ".jpg";

    // 保存
    save(path);

    // 番号を加算
    count++;

    // ログ用途
    println("screen saved." + path);
  }
}

void stop() {
  minim.stop();
  super.stop();
}

void mouseClicked() {
  controller.mouseClicked();
}

Answer 2

出来ればgitとかを導入してプログラムの変更履歴を残して、常に「動かなくなる直前」に戻せるようにしておくといいと思うけど。

「追加したもの」とコメントがついてなくて、しかし変わっているところがミソだと思う。前のプログラムとよく比べてみましょう。