範囲選択した空白セルに番地を入力したい

Question

前提・実現したいこと

範囲選択した空白のセルに番地（＄、：の記号を除く）を入力したいです。

該当のソースコード

Option Explicit
Option Base 1

Sub test()
    Dim a(3, 2) As Variant
    Dim i As Integer, j As Integer
    For i = 1 To 3
        For j = 1 To 2
        a(i, j) = Selection.Cells(i, j).Address
        a(i, j) = Replace(a(i, j), "$", ",")
        a(i, j) = Replace(a(i, j), ":", ",")
        Selection.Cells(i, j) = Split(a(i, j), ",")(1) & Split(a(i, j), ",")(2)
        Next j
    Next i

End Sub

試したこと

選択した範囲の行列数を取得する方法がわからず
あらかじめ決めた範囲（今回3行2列）の入力しか行えずそれを改善したいです。

補足情報（FW/ツールのバージョンなど）

Excel　2010

ここにより詳細な情報を記載してください。

Answer 1

選択した範囲の行列数を取得する方法がわからず

行数Selection.Rows.Count 列数Selection.Columns.Countで取得できます。
配列とセル範囲にアドレスを入力するだけなら、下記でOKです。
ddress(False, False)で＄のないアドレスになります。

Sub test()
    Dim a() As Variant
    Dim i As Integer, j As Integer
    
    ReDim a(Selection.Rows.Count, Selection.Columns.Count)
    For i = 1 To Selection.Rows.Count
        For j = 1 To Selection.Columns.Count
            a(i, j) = Selection.Cells(i, j).Address(False, False)
            Selection.Cells(i, j) = a(i, j)
        Next j
    Next i
End Sub

---

配列に格納する必要がないなら、

Sub test()
    
    Dim c As Range
    For Each c In Selection
        c.Value = c.Address(False, False)
    Next c
End Sub

Comments

[nhrhrs]

ご回答いただき感謝いたします。
欲しかったこと、知りたかったことすべて得ることができました。

Answer 2

Sub test2()
    With Selection
        .Formula = "=ADDRESS(ROW(),COLUMN(),4,TRUE)"
        .Value = .Value
    End With
End Sub

で、「空白セル」はコードに反映されてないですけど、
選択しなくても、探せると思いますが、
ホントはどうしたいんですか？

Comments

[nhrhrs]

ご回答いただき感謝いたします。
したかったことは「選択した範囲にセルの番地を入力する」ことで
そのあとの用途は特にありませんでした。
VBA初心者でして、上記のことをしたいと不意に思いつき、
出来なかったのでご意見いただきたかった所存です。
他のお二方とは違ったコードで勉強になりました。
ありがとうございました。

Answer 3

以下ではいかがでしょうか。

Option Explicit

Sub test()
    Dim selrg As Range
    Dim rg As Range
    Set selrg = Selection
    For Each rg In selrg
        rg.Value = rg.Address(False, False)
    Next

End Sub

Comments

[nhrhrs]

ご回答いただき感謝いたします。
やりたい事実践することができました！