他ブック読込時にActivateが効かない

Question

開発環境：Excel 2013

他ブックから、複数シートのデータを取り込むマクロを作成しております。

    Dim wbRead As Workbook                      'ワークブック（読込）
    Dim wbMe As Workbook                        'ワークブック (自分)
    dim varList as Variant
    dim i as integer

    Set wbMe = ThisWorkbook　
    Set wbRead = Workbooks.Open(ファイル名)

    For i = 1 to シート数
       With wbRead.Sheets(シート名(i))
           .Activate

           'データ取込処理
           .cells(1,1).CurrentRegion.select
           Selection.Offset(1, 0).Select
           Selection.Resize(Selection.Rows.Count - 1, Selection.Columns.Count).Select
           varData = Selection
       End With

　　　 wbMe.Activate
       With wbMe.Sheets(シート名(i))
           .Activate
 
           'データ書き込み処理
           .cells(1,1).CurrentRegion.select
           Selection.Offset(1, 0).Select
           Selection.Resize(Selection.Rows.Count - 1, Selection.Columns.Count).Select
           Selection = varData
       End With
    Next i

　　wbRead.Close SaveChanges:=False

このような処理を組んでいます。
（実際の読込処理、書込処理では取込データの加工や、書き込み位置の計算処理なども行っています）

対象シートをActivateの後に表からデータ部を配列化していますが、
データ書き込み処理でのActivateが動作されず、
書き込み処理が正常に行われません。

ただし、.Activateの箇所でブレイクポイントを貼って
デバッグで動作させる場合は、正常に動作します。
（.Activateでステップを進めると、
自ブックの対象シートが画面最善面に表示されます）
また、.Activate以外の箇所にブレイクポイントを張ると、
必ず読込ブックが最前面に居る状態でブレイクされます。

このような現象の際の対処法について、
御教授いただければ幸いです。

Answer 1

解決済みですが、あえて補足を。

Activateは避けるべきですが、同様の理由でSelectも避けるべきです。
どちらも大抵の場合なくても処理できます。
その方が安定、高速、シンプルです。

それぞれのオブジェクトを変数に代入してそれに対して操作するようにします。
また Withステートメントをうまく使うと、変数なしにオブジェクトを直接操作できるので、シンプルかつ読みやすいコードになります。

    Dim wbMe As Workbook                        'ワークブック (自分)
    Set wbMe = ThisWorkbook
    Dim wbRead As Workbook                      'ワークブック（読込）
    Set wbRead = Workbooks.Open(ファイル名)

    Dim i As Integer, varData As Variant
    For i = 1 To シート数
        With wbRead.Sheets(シート名(i)).Cells(1, 1).CurrentRegion
        'データ取込処理
            varData = .Offset(1, 0).Resize(.Rows.Count - 1).Value
        End With

       'データ書き込み処理
        wbMe.Sheets(シート名(i)).Cells(2, 1) _
            .Resize(UBound(varData, 1), UBound(varData, 2)).Value = varData
    Next i

    wbRead.Close SaveChanges:=False

ちなみに書き込み処理は配列のサイズでセル範囲をResizeしないとだめです。
また、私は変数はなるべく使う直前で宣言する派です。

Comments

[t-yoshi]

いま、まさにSelectでの動作不具合が出ていました。
ご提示頂いたプログラムコードを参考に解決しました。
ありがとうございます！

CurrentRegionをWithステートメントで纏めるという考えが
全く無かったので、とても勉強になりました。

Answer 2

アクティブ前提の作りはやめましょう。
環境に左右されやすく安定した動作は望めません。
ワークシートはオブジェクト変数に代入しておくことで操作が可能です。

例

Dim ws As Worksheet
Set ws = wbMe.Sheets(1)
ws.cells(1,1).CurrentRegion.select

Comments

[t-yoshi]

ご回答ありがとうございます！
Activateとはそういうものなのですね…。
不勉強でした。
いつも御助言いただき、ありがとうございます。