processingで鍵盤を作成したいです。

Question

processingでキーボードを鍵盤にするプログラムを見つけました。下のプログラムは、キーを押すと1秒間だけ鳴るプログラムです。これをキーを押し続ければ鳴り続け、離すと止まるプログラムにしたいのですが、どうすれば良いのかわかりません。

import ddf.minim.spi.;
import ddf.minim.signals.;
import ddf.minim.;
import ddf.minim.analysis.;
import ddf.minim.ugens.;
import ddf.minim.effects.;

Minim minim;
AudioOutput out;

void setup(){
size(600, 400);
minim = new Minim(this);
out = minim.getLineOut();
}

void draw(){

}

void keyPressed(){
String pitchName = "";
switch(key){
case 'z':
pitchName += "C"; break;
case 's':
pitchName += "C#"; break;
case 'x':
pitchName += "D"; break;
case 'd':
pitchName += "D#"; break;
case 'c':
pitchName += "E"; break;
case 'v':
pitchName += "F"; break;
case 'g':
pitchName += "F#"; break;
case 'b':
pitchName += "G"; break;
case 'h':
pitchName += "G#"; break;
case 'n':
pitchName += "A"; break;
case 'j':
pitchName += "A#"; break;
case 'm':
pitchName += "B"; break;
}
if(pitchName != ""){
out.playNote(0.0, 1.0, new Keyboard(Frequency.ofPitch(pitchName + "4").asHz()));
}
}

class Keyboard implements Instrument {

Oscil osc;

Keyboard(float pitch){
osc = new Oscil(pitch, 1.0, Waves.SAW);
}

void noteOn(float duration){
osc.patch(out);
}

void noteOff(){
osc.unpatch(out);
}

}

Answer 1

out.playNoteは鳴らす長さを入れて音を出すみたいなので、任意の長さで鳴らすのはちょっと難しそうですねぇ（何か方法はあるかもしれませんが）

代わりにMidiで鳴らすのはどうでしょう？最近のPCであれば標準で対応しているはずです。

import themidibus.*; // 注１
import ddf.minim.ugens.Frequency;

MidiBus myBus;
HashMap<String, Boolean> pressedKeys = new HashMap<String, Boolean>();

void setup() {
  size(600, 400);
  MidiBus.list();
  myBus = new MidiBus(this, -1, 1); // 注２
  myBus.sendMessage(192, 3); // 注３
}

void draw() {
}

void keyPressed() {
  String pitchName = getPitchName();
  if (pitchName == null) return;
  if (pressedKeys.getOrDefault(pitchName, false)) return;

  myBus.sendNoteOn(0, (int) Frequency.ofPitch(pitchName).asMidiNote(), 127);
  pressedKeys.put(pitchName, true);
}

void keyReleased() {
  String pitchName = getPitchName();
  if (pitchName == null) return;

  myBus.sendNoteOff(0, (int) Frequency.ofPitch(pitchName).asMidiNote(), 127);
  pressedKeys.put(pitchName, false);
}

String getPitchName() {
  switch (key) {
    case 'z': return "C4";
    case 's': return "C#4";
    case 'x': return "D4";
    case 'd': return "D#4";
    case 'c': return "E4";
    case 'v': return "F4";
    case 'g': return "F#4";
    case 'b': return "G4";
    case 'h': return "G#4";
    case 'n': return "A4";
    case 'j': return "A#4";
    case 'm': return "B4";
  }

  return null;
}

注１
The MidiBusを「ライブラリを追加」からインストールしてください。

注２
プログラムを実行したときに、

Available MIDI Devices:
----------Input----------
[0] "Real Time Sequencer"
----------Output----------
[0] "Gervill"
[1] "Microsoft MIDI Mapper"
[2] "Microsoft GS Wavetable Synth"
[3] "Real Time Sequencer"

のよう表示が出ます。
音が出なかったときはnew MidiBus(this, -1, 1)の1を、Outputにある数字の中から変えて試してください。

注３
sendMessage(192, 3)の3は音色です（192は気にしないでいいです）
楽器のNo.の数字からいろいろ試してみてください。

---

追記

やっぱり気になったのでminimバージョンも。無駄にややこしくしてる気もする^^;

import ddf.minim.spi.*;
import ddf.minim.signals.*;
import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.ugens.*;
import ddf.minim.effects.*;

Minim minim;
AudioOutput out;
HashMap<String, Keyboard> pressedKeys = new HashMap<String, Keyboard>();

void setup() {
  size(600, 400);
  minim = new Minim(this);
  out = minim.getLineOut();
}

void draw() {
}

void keyPressed() {
  String pitchName = getPitchName();
  if (pitchName == null) return;

  Keyboard k = pressedKeys.get(pitchName);
  if (k == null) {
    k = new Keyboard(pitchName);
    pressedKeys.put(pitchName, k);
  }

  k.noteOn();
}

void keyReleased() {
  String pitchName = getPitchName();
  if (pitchName == null) return;

  pressedKeys.get(pitchName).noteOff();
}

String getPitchName() {
  switch (key) {
    case 'z': return "C4";
    case 's': return "C#4";
    case 'x': return "D4";
    case 'd': return "D#4";
    case 'c': return "E4";
    case 'v': return "F4";
    case 'g': return "F#4";
    case 'b': return "G4";
    case 'h': return "G#4";
    case 'n': return "A4";
    case 'j': return "A#4";
    case 'm': return "B4";
  }

  return null;
}

class Keyboard {
  Oscil osc;
  boolean pressed;

  Keyboard(String pitchName) {
    osc = new Oscil(Frequency.ofPitch(pitchName), 1.0, Waves.SAW);
  }

  void noteOn() {
    if (pressed) return;

    osc.patch(out);
    pressed = true;
  }

  void noteOff() {
    osc.unpatch(out);
    pressed = false;
  }
}

Comments

[thkana]

> 任意の長さで鳴らすのはちょっと難しそう
私もminimは機能豊富過ぎてついていけていませんが。
midiでNoteOnとかOffとかあるわけで、そこから類推して質問のプログラムのKeyboard.noteOnとかnoteOffというメソッドを(playNoteを経由せず)呼んでやればそのように動作したりします。

[TN8001]

あぁなるほどInstrumentはそう使うわけですか。流してましたｗ
Midiのほうが音を変えやすそうなので、このままにしときます。
補足ありがとうございます。

Answer 2

keyReleased()関数でキーボードが離されたことを検知できるみたいですから、keyPressed()では音を出すだけにして、keyReleased()で離されたら音を止める、ようにすればよいのでは。