Excelで選択した複数のセルすべてにオートシェイプの円を挿入したい

Question

前提・実現したいこと

エクセルで７列・４-５行の一般的な形のカレンダーがあり、
日付はセルの右揃えで並んでいます。

このカレンダーの選択した任意の日付を太字で強調し、赤丸で囲むようにしたいです。

発生している問題・エラーメッセージ

一つのセル（アクティブセル）に丸を付けるのはできるのですが、
セルを複数選択して、一度に複数の日付を丸で囲むことができません。
複数選択してマクロを実行しても、円が一つしか挿入されない状態です。

該当のソースコード

VBA

Sub 数字に丸()
'
' Macro13 Macro
'

'
Selection.Font.Bold = True

ActiveSheet.Shapes.AddShape(msoShapeOval, Selection.Left, Selection.Top, 17, 17).Select
Selection.ShapeRange.Fill.Visible = msoFalse
Selection.ShapeRange.IncrementLeft 40
Selection.ShapeRange.IncrementTop -1
With Selection.ShapeRange.Line
    .Visible = msoTrue
    .ForeColor.RGB = RGB(255, 0, 0)
    .Transparency = 0
    .Weight = 1.5
End With

End Sub

試したこと

ネットでさんざん検索しても複数のオートシェイプを挿入する方法が見つかりませんでした。

補足情報（FW/ツールのバージョンなど）

Excel2013です。

Answer 1

選択されているセルひとつずつに対して処理を行う必要があります。
SelectionをFor Eachで回すと各セルの情報を取り出せます。

Sub 数字に丸()
    For Each r In Selection
        r.Font.Bold = True
        Set s = ActiveSheet.Shapes.AddShape(msoShapeOval, r.Left, r.Top, 17, 17)
        s.Fill.Visible = msoFalse
        s.IncrementLeft 40
        s.IncrementTop -1
        With s.Line
            .Visible = msoTrue
            .ForeColor.RGB = RGB(255, 0, 0)
            .Transparency = 0
            .Weight = 1.5
        End With
    Next
End Sub

Comments

[daiching]

ttyp03 様

おかげさまで思い通りの動作になりました。
心から感謝申し上げます。