vbaの辞書内の値が、配列の場合書き換えられない

Question

前提・実現したいこと

vbaの辞書内の配列の値を変更したい。

発生している問題・エラーメッセージ

非配列の場合は、変更が行えましたが、
配列になると、値を代入しても値が更新されていませんでした。

該当のソースコード

Sheet1のA1～C10を読み取る、A1には「test1」という値が入っています。
範囲の読み込みは成功・・・範囲の値変更に失敗
単一の読み込みは成功・・・単一の値変更に成功
という流れになっています。

Dim dic As Object
Set dic = CreateObject("Scripting.Dictionary")
dic.Add "範囲", ThisWorkbook.Worksheets("Sheet1").Range("A1:C10").value
Debug.Print dic.Item("範囲")(1, 1)
' >>> test1
dic.Item("範囲")(1, 1) = "test2"
Debug.Print dic.Item("範囲")(1, 1)
' >>> test1

dic.Add "単一", "test1"
Debug.Print dic.Item("単一")
' >>> test1
dic.Item("単一") = "test2"
Debug.Print dic.Item("単一")
' >>> test2

試したこと

辞書に代入するのではなく、Variant型で用意したものに配列を入れると、
問題なく値の変更が行えました

Dim hoge As Variant
hoge = ThisWorkbook.Worksheets("setting").Range("A1:C10").value
Debug.Print hoge(1, 1)
hoge(1, 1) = "test2"
Debug.Print hoge(1, 1)

配列が変更できない理由、またこの辞書内配列を変更する方法をご教示願いたく存じます。

補足情報

Excel2013

Answer 1

Dictionaryに格納された配列の要素を直接更新はできないようです。
いったん配列に取り出ししてそれを更新して、Dictionaryに戻すという手順が必要です。

' >>> test1
Dim ary As Variant
ary = dic.Item("範囲")
ary(1, 1) = "test2"
dic.Item("範囲") = ary
Debug.Print dic.Item("範囲")(1, 1)
' >>> test1

理由はわかりませんが、Variant配列は配列が直接格納されているわけではなく、配列のアドレスのみが格納されているということが関係しているような気がします。

Comments

[funmas]

ご回答ありがとうございます！
やはり直接更新はできない作りになっているんですね･･･。
なるほど、、アドレス格納の旨憶えておくようにします。

ttyp03さんにもご回答いただきましたが、やはり出して変更して入れて～の手順が、
現状の最善手のようで安心しました。ありがとうございました！

Answer 2

理由はわかりませんが、配列の場合は取り出した値を格納している領域を更新しているだけっぽいですね。
以下のように一旦配列に取り出して、それを再設定することで更新は可能です。

Dim dic As Object
Dim tmp() As Variant

Set dic = CreateObject("Scripting.Dictionary")
dic.Add "範囲", ThisWorkbook.Worksheets("Sheet1").Range("A1:C10").Value
Debug.Print dic.Item("範囲")(1, 1)

tmp = dic.Item("範囲")
tmp(1, 1) = "test2" '★
dic.Item("範囲") = tmp
Debug.Print dic.Item("範囲")(1, 1)

イメージ的には上記★の行までを内部的に実行しているような感じがします。
つまりこんな感じで別々に処理されていると思います。
dic.Item("範囲") (1, 1)

Comments

[funmas]

ご回答ありがとうございます！
なぜこういう動きになるのか謎ですね。
考慮されていなかった作りなのか･･･。

しかし、ご提示いただいた案で問題はクリアできました。
非常に助かりました。ありがとうございます！