結合セルの配列化について

Question

環境：Excel2013

結合セルの配列化について質問です。

	A	B	C
1	１	A	あ
2	↑と結合	B
3	2	↑と結合	う

この様な結合セルを配列化した時に、結合セルがブランクにならない様にしたいです。

    Dim varList() As Variant
    
    Cells(1, 1).CurrentRegion.Select
    varList = Selection

varList の格納値

1	A	あ
ブランク	B	ブランク
2	ブランク	う

理想

1	A	あ
1	B	ブランク
2	B	う

セルをループ処理で参照し、MergeAreaの使用することも考えましたが、
処理速度の面から、一括の配列化が出来たらと思っております。
（一括で無くでも、出来るだけセルの参照は減らしたいです）

解決策がありましたら、
御教授いただければ幸いです。

Answer 1

Option Explicit
Sub test()
Dim varList() As Variant
    varList = Cells(1, 1).CurrentRegion.Value
    Dim i As Long, j As Long, Temp As Variant
    For j = 1 To UBound(varList, 2)
        For i = 1 To UBound(varList, 1)
            If IsEmpty(varList(i, j)) Then
                varList(i, j) = Temp
            Else
                Temp = varList(i, j)
            End If
        Next i
    Next j
End Sub

ではいかが。

Comments

[t-yoshi]

ご回答有難うございます！

ご回答いただいた内容ですと、
元がブランク値のデータも結合セルと同様に
前回値がセットされてしまいます。

すみません、質問の内容が不十分でした。
質問内容を少し修正させていただきます。

Answer 2

解決済ですが、頭の体操で考えてみました。

処理速度の面から、一括の配列化が出来たらと思っております。
（一括で無くでも、出来るだけセルの参照は減らしたいです）

一活　→　VBAでループ処理を書かない。

というテーマで書いてみました。

シートのコピーをしてるので、どれくらい時間が掛かるか不明ですが、
高速化が出来ないでしょうか？

時間を測ってもらって、みんなで情報を共有できたら幸いかと思います。

Option Explicit

Sub test002()
    Dim v()
    
    v = cnvMeageCellToValue(ActiveSheet.Range("A1").CurrentRegion)
    
    Stop
End Sub

Function cnvMeageCellToValue(ByRef Rng As Range) As Variant
    Const cnsFlag As String = "<空白>"
    Const cnsBlank As String = ""
    
    'Application.ScreenUpdating = False
    
    Rng.Worksheet.Copy
    With Workbooks(Workbooks.Count).Worksheets(1).Range(Rng.Address)
        .Replace cnsBlank, cnsFlag
        .UnMerge
        On Error Resume Next
        .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
        On Error GoTo 0
        .Replace cnsFlag, cnsBlank
        cnvMeageCellToValue = .Value
        .Worksheet.Parent.Close False
    End With
    
    'Application.ScreenUpdating = True
End Function

Answer 3

（一括で無くでも、出来るだけセルの参照は減らしたいです）

解決済みですが、
ttyp03さんのコードは全セルを参照して再代入してるのがちょっと気になります。

ttyp03さんとiruyasさんのコードの折衷案（いいとこどり）のコードを書いてみました。

配列を走査して、空欄(IsEmpty)かつ結合セル(MergeCells)の時のみ代入するようにしてます。
セル参照は空欄セルのみです。

Sub sample()
    Dim rng As Range
    Set rng = Range("A1").CurrentRegion
    Dim varList() As Variant
    varList = rng.Value
    Dim r As Long, c As Long
    For r = 1 To UBound(varList, 1)
        For c = 1 To UBound(varList, 2)
            If IsEmpty(varList(r, c)) Then
                If rng(r, c).MergeCells Then
                    varList(r, c) = rng(r, c).MergeArea.Item(1).Value
                End If
            End If
        Next c
    Next r
End Sub

Comments

[ttyp03]

hatena19さん、どうも。
> 全セルを参照して再代入してるのがちょっと気になります。
これはわかっていることなので、一応「データ量によっては少々遅いかも」と断り書きをしております。
コードのシンプルさを求めただけですので、速度を気にするときは少々長くてもhatena19さんのようなコードになりますね。

[hatena19]

よほど大きいデータ量でないと体感できる差はでないと思いますので、ttyp03さんのコードで問題ないと私も思います。

Answer 4

書いてみました。
なるべくセルの状態を気にせずに処理できるコードを目指してみました。
ただデータ量によっては少々遅いかも。

Sub sample()
    Dim varList As Variant
    Dim r As Range
    Dim v As Range
    Set r = Range("A1").CurrentRegion
    varList = r
    For Each v In r
        varList(v.Row, v.Column) = v.MergeArea.Item(1).Text
    Next
End Sub

Comments

[t-yoshi]

ご回答有難うございます！

頂いたコードを組み込んで動作させてみました。
今回制作のアプリケーションでのデータ量ですと、
充分な許容範囲内の速度でした。

よって、ttyp03様より頂いた回答内容にて
プログラム制作を進めて参りたく存じます。

ありがとうございました！