Windows バッチ ファイルのコピー処理が動きません

Question

特定の拡張子付きのファイルがあるフォルダの中身を別の場所にコピーする処理が動きません。
2回目のfor文がなぜか実行されません。
3つ目のecho(ORG_COPY_PATH)は値が取れているのはログで確認できました。
2回目のfor文のパスを3つ目のechoでログに出力されたパスで直書きすると動きます。

エラーも出力されない為、手詰まり状態です。。。

setlocal EnableDelayedExpansion
for /r %UNZIP_FILE_PATH% %%i in (*.txt) do (

	echo %%i>>log.txt
	SET ORG_COPY_PATH=%%~dpi
	
	findstr "Zone_10" "%%i" >NUL 2>&1 && (
		echo １０系です>>log.txt
		echo !ORG_COPY_PATH!>>log.txt
		
		for /r "!ORG_COPY_PATH!" %%a in (*.*) do (
			echo "%%a">>log.txt
			copy "%%a" D:\Data
		)
	)
)
endlocal

以上、ご教示よろしくお願いいたします。

Answer 1

forの構文解析より後で、遅延環境変数の展開が行われるため、for /rの開始ディレクトリは、!ORG_COPY_PATH!という文字通りの名前のディレクトリから行われることになります。
で、そんなものは無いので、ループは0回で終わります。

mkdir !ZZZ!
echo > !ZZZ!\sample
setlocal EnableDelayedExpansion
set ZZZ=%TEMP%
for /r !ZZZ! %%A in (*) do echo %%A

というシンプルなケースで確認できます(ディレクトリは後で消しておいてください)。

一般に、複雑なケースでは、括弧による複文を使うのは苦労が多いです。
for ～～～ do call :subproc1 %%Aのように内部サブルーチンに飛ばして、そこで処理するのが楽です。多くの場合は遅延環境変数展開も不要です。

今回は、ちょっとの手直しでできます。また、本題とは関係ないですが、遅延環境展開も不要です。

for /r %UNZIP_FILE_PATH% %%i in (*.txt) do (

    echo %%i>>log.txt

    findstr "Zone_10" "%%i" >NUL 2>&1 && (
        echo １０系です>>log.txt
        echo %%~dpi>>log.txt

        pushd %%~dpi
        for /r %%a in (*.*) do (
            echo "%%a">>log.txt
            copy "%%a" D:\Data
        )
        popd
    )
)

for /r %%~dpi %%a in (*.*) doという書き方が出来ればいいのですが、これも駄目です。for制御変数の展開も、forの構文解析後に行われます。
ここで使えるのは、普通の環境変数展開と、位置パラメーターだけです。

上に書いたように複雑な括弧を使わない方針で行くと、

for /r %UNZIP_FILE_PATH% %%i in (*.txt) do call :TXT %%i
exit /b

:TXT
    echo %1>>log.txt

    findstr "Zone_10" "%1" >NUL 2>&1 && call :COPY %1
    exit /b

:COPY
        echo １０系です>>log.txt
        echo %~dp1>>log.txt

        for /r %~dp1 %%a in (*.*) do (
            echo "%%a">>log.txt
            copy "%%a" D:\Data
        )
        exit /b

位置パラメーター%~dp1の展開は、forの構文解析と同時なので大丈夫です。

Comments

[uraringo]

丁寧なご回答ありがとうございました。

最初は
for /r %%~dpi %%a in (*.*) do
も試してみたのですが、ダメだったのでわざわざ変数にしてしまいましたが
そもそも解析される時に値が分かってないのダメだったのですね。

１．解析
２．遅延時に変数代入してくれるはず
３．実行

と勝手に思い込んでいました。

サブルーチン化し無事実行することができました。
ありがとうございました！

[otn]

構文解析順序については、昔調べて書いたものがあります。XP時代なのですが、Windows10での検証はしていません。
https://otnx.jp/CMD/%C1%B4%C8%CC/%B9%BD%CA%B8%B2%F2%C0%CF/

[uraringo]

コメントありがとうございます。
ぜひ参考にさせていただきたいと思います。