[ExcelVBA]ADODB.Openした後にErr.Raiseした際、Close処理は行われるか

Question

ExcelVBAでAccessに接続するため、以下のようなクラスを作ります。

Const strFilePath = "C:hoge.accdb"

Dim adoCn As Object
Dim adoRs As Object

Private Sub Class_Initialize()
    Set adoCn = CreateObject("ADODB.Connection"): adoCn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFilePath & ";"
    Set adoRs = CreateObject("ADODB.Recordset")
End Sub

Public Function strTarget(Syain_ID As String, System_Name As String)

    Dim strSQL As String
    strSQL = "SELECT Target FROM テーブル1 WHERE Syain_ID = '" & Syain_ID & "' AND System_Name = '" & System_Name & "'"
    
    adoRs.Open strSQL, adoCn
    
    If Not adoRs.EOF Then
        strTarget = adoRs!Target
    Else
        Err.Raise 1234, , "社員番号：" & Syain_ID & vbCrLf & "システム名：" & System_Name & vbCrLf & "以上を満たすレコードが見つかりません" '←これが起こった場合
    End If

End Function

Private Sub Class_Terminate()
    adoRs.Close: Set adoRs = Nothing
    adoCn.Close: Set adoCn = Nothing
End Sub

その後、標準モジュールで以下のコードを書きます。

Sub main()
    With New Class1
        MsgBox .strTarget("1234567", "System")
    End With
End Sub

AccessにSQLを投げ、0件の場合その時点でErr.Raiseをしたいのですが、この場合Class_Terminateに書かれたClose処理は行われるでしょうか。
また、もしClose処理が行われる前にマクロが終了した際の悪影響についてもご教授ください。

Answer 1

回答の前に確認ですが
strPassword = adoRs!Target
は
strTarget = adoRs!Target
の書き間違いですよね？

---

Classの場合、参照が終わると自動的に解放されます。その時にTerminateイベントが呼び出されます。途中でErr.Raiseでエラーを発生させても同じです。（エラー画面で終了させたり律せとしたらだめですが）

質問のコードでは、'With New Class1'でクラスを生成してますので、End With で参照が終了するのでそこでTerminateが呼び出されてClose処理も実行されます。もし、On Error GoTo ・・・でエラーハンドラに跳んでプロシージャを抜けた場合はその時点でClassが解放されてTerminateが実行されます。
下記のようにデバッグコードを埋め込んで動作を確認してみてはどうでしょうか。

Private Sub Class_Terminate()
    adoRs.Close: Set adoRs = Nothing
    adoCn.Close: Set adoCn = Nothing
    Debug.Print "Close処理完了"
End Sub

---

以下、質問の回答ではないですが、結果が0件というのはエラーではないのでErr.Raiseで処理するというのは違和感があります。
strTarget の返り値を Null または "" にするのがいいように思います。
例えば、Accessの標準のDLookup関数なんかも該当データがない場合Nullを返します。

Comments

[woria]

回答ありがとうございます。
今回の処理はMsgboxで"レコードが見つからない"と出し、NullをReturnするようにします。