windows8 配列を扱ったバッチファイルが正しく動作しません

Question

以下のような配列を使うバッチファイルを作ったのですが期待通りの動作をしません。
直し方が分かる人がいましたら教えてください。

動作環境：windows8.1　Enterprise
仕様アプリ：コマンドプロンプト

--batファイルの中身-----------------------
set ftpIPAddress[0]=xx.aa.bb.cc
set ftpFileName[0]=ftp11.txt

set ftpIPAddress[1]=xx.aa.bb.dd
set ftpFileName[1]=ftp12.txt

echo off

echo.
for /l %%n in (0,1,1) do (

call echo open %%ftpIPAddress[%%n]%% > %%ftpFileName[%%n]%%
call echo user >> %%ftpFileName[%%n]%%
call echo pass >> %%ftpFileName[%%n]%%
call echo put ftpcheck.txt /data/ftpcheck/ftpcheck20191121_%%n.txt >> %%ftpFileName[%%n]%%

)

---

期待する動作
fpt11.txt
ftp12.txt
が作成される。

現在の動作
%ftpFileName[0]%
%ftpFileName[1]%
が作成される。

ファイルの中身の記述は意図したとおりになっています。

Answer 1

バッチファイルで使う変数はあくあでも環境変数なので配列というのはありません。
[]で書いてもそれ自体が変数名として扱われます。
とは言え見た目的には配列っぽく扱えるようですね。
以下のような感じになるかと思います。

setlocal enabledelayedexpansion

set ftpIPAddress[0]=xx.aa.bb.cc
set ftpFileName[0]=ftp11.txt

set ftpIPAddress[1]=xx.aa.bb.dd
set ftpFileName[1]=ftp12.txt

echo off

echo.
for /l %%i in (0,1,1) do (
set /a n=%%i
call set ip=%%ftpIPAddress[!n!]%%
call set fn=%%ftpFileName[!n!]%%
echo open !ip! > !fn!
echo user >> !fn!
echo pass >> !fn!
echo put ftpcheck.txt /data/ftpcheck/ftpcheck20191121_!n!.txt >> !fn!
)

Answer 2

BATファイルでは配列ってのは使えません。
そこらへんから考え直しましょう

Comments

[tamina]

あなたのコメントを読んで、別の手段で無理やり対応してしまいました。
手段のミスリードが発生したと感じましたので、低評価とさせていただきます。

[otn]

「配列が使えない」というのは確かなので、低評価ということもないかと。

[y_waiwai]

それで配列か使えると思うのなら、まあ、そんでいいんじゃないの、とは思いますが。

Answer 3

リダイレクト先ファイル名は、call実行前に決まりますので、駄目です。
enabledelayedexpansionを使わない前提では、
案1：

for /l %%n in (0,1,1) do (
  cmd /c "echo open %%ftpIPAddress[%%n]%% > %%ftpFileName[%%n]%%"
  cmd /c "echo user >> %%ftpFileName[%%n]%%"
  cmd /c "echo pass >> %%ftpFileName[%%n]%%"
  cmd /c "echo put ftpcheck.txt /data/ftpcheck/ftpcheck20191121_%%n.txt >> %%ftpFileName[%%n]%%"
)

案2：

for /l %%n in (0,1,1) do call :sub %%n
exit /b

:sub
call set FN=%%ftpFileName[%1]%%
call echo open %%ftpIPAddress[%1]%% > %FN%
call echo user >> %FN%
call echo pass >> %FN%
call echo put ftpcheck.txt /data/ftpcheck/ftpcheck20191121_%1.txt >> %FN%
exit /b