<processing初心者>drawSakuraで作った桜の形を自動で拡大縮小したいです。

Question

前提・実現したいこと

drawSakuraで桜の形を作って拡大してから縮小するアニメーションを作りたいと思っています

発生している問題・エラーメッセージ

初心者なりに構文を作ってみたのですが、桜の形が拡大したままで縮小しません。
わたし的には、該当ソースの

if (ox <= 600) { // 右端に達した?
ox = ox - 1 ;
}

の部分で桜が縮小すると思ったのですが...
ちなみに桜の曲線はこちらのサイトから拝借させていただきました。
https://qiita.com/reona396/items/5fa4babc8243c4ed4914

該当のソースコード

int ox = 0;
int oy = 0;

void setup(){
  size(500,500);
}

void drawSakura(int ox, int oy, int or) {
  pushMatrix();
  translate(ox + 1, oy + 1);
  beginShape();
  for (int theta = 0; theta < 360; theta++) {
    float A = (sin(radians(theta * 5)) + cos(radians(theta * 10))) / 2.0;
    float B = A * 0.5 + 1.0;
    float R = or * B;
    float x = R * sin(radians(theta + 90));
    float y = R * cos(radians(theta + 90));

    vertex(x, y);
  }
  endShape(CLOSE);
  popMatrix();
  
  //桜を拡大縮小する
  
  if (ox <= 600) {  // 右端に達した?
    ox  = ox - 1 ;
  }
  
  if (ox >= 100) {
    ox  = ox + 1;
  } //左端に達した??

試したこと

この他にもDirectionを使う方法を試しましたが、そもそも桜がx軸とy軸基準で作られている訳ではなさそうなので無理そうです。。。

補足情報（Processing3/JavaScript）

ここにより詳細な情報を記載してください。

Answer 1

drawSakuraの中の意味は全く分かっていません。
元記事の、

drawSakura(width/2, height/2, 130); // 横の位置、縦の位置、大きさ調整用変数

Processing で描ける図形まとめ - Qiita#花びらが分かれていないタイプ

から130を変えればよさそうに思いました。
実際に変えている範囲（50-200）は手調整で特に根拠はありません。

int scale = 130; // 大きさに関する値（大きいほど拡大される）
boolean isExpand = true; // boolean型の変数isExpandを定義&初期化（trueで拡大）

void setup() {
    size(500, 500);
}

void draw() {
    background(255);

    if (200 < scale) { // 縮小モードへ
        isExpand = false;
    } else if (scale < 50) { // 拡大モードへ
        isExpand = true;
    }

    if (isExpand) { // 拡大
        scale++;
    } else { // 縮小
        scale--;
    }

    noFill();
    strokeWeight(2);
    stroke(200, 0, 0);
    drawSakura(width / 2, height / 2, scale); // 横の位置、縦の位置、大きさ調整用変数
}

void drawSakura(int ox, int oy, int or) {
    pushMatrix();
    translate(ox + 1, oy + 1);
    beginShape();
    for (int theta = 0; theta < 360; theta++) {
        float A = (sin(radians(theta * 5)) + cos(radians(theta * 10))) / 2.0;
        float B = A * 0.5 + 1.0;
        float R = or * B;
        float x = R * sin(radians(theta + 90));
        float y = R * cos(radians(theta + 90));

        vertex(x, y);
    }
    endShape(CLOSE);
    popMatrix();
}

---

余談

ある数値iを、

if (i < 10) {
    i--;
}
if (0 < i) {
    i++;
}

とした時、iの初期値が

• 0の場合、最初のifで-1になり次のifには一向に入らずどんどんマイナスになります
• 5の場合、最初のifで4になり次のifで5に戻り変化がなくなります
• 10の場合、最初のifには入らず次のifでどんどんプラスになります

なんとなくiは0-10の間を往復しそうな気がしますが、そうはなりません。
閾値を超えた（下回った）時に、モードを切り替えるbooleanを用意するのが常套手段です。

動きがあると楽しいですね。

Answer 2

そもそも別の形と組み合わせていて、元のスケッチから桜の部分だけ抜粋していたのですが、入力して見たところそもそも動きませんでしたTTまた今は別の質問があるのでそちらも見ていただけるとありがたいです。