processingで描写した図形にキー入力を反映させたい

Question

前提・実現したいこと

プログラミング初学者です．リサージュ図形の位相や周波数などをキー入力で変化させたいのですがうまくいきません．どなたか教えていたけるとありがたいです．

発生している問題・エラーメッセージ

リサージュ図形は描写されるのですががキー入力を受け付けません

該当のソースコード

int pointCount = 1000;
PVector[] lissajousPoints;
int freqX = 4;
int freqY = 7;
float phi = 15;
float x,y;

int modFreqX = 3;
int modFreqY = 2;

float lineWeight = 0.1;
float lineColor;
int lineAlpha = 50;

int connectionRadius = 100;
int connecionRamp = 6;

void setup() {
  size(800,800);
  smooth();
  lissajousPoints = new PVector[pointCount+1];
  lineColor = color(0,50);
  
  calculateLissajposPoints();
  drawLissajous();
}

void calculateLissajposPoints() {
  for (int i = 0; i <= pointCount; i++) {
    float angle = map(i, 0, pointCount, 0, TAU);
    x = sin(angle * freqX + radians(phi)) * cos(angle * modFreqX);
    y = sin(angle * freqY) * cos(angle * modFreqY);
    x *= width/2 - 30;
    y *= height/2 - 30;
    
    lissajousPoints[i] = new PVector(x,y);
  }
}

void drawLissajous() {
  background(255);
  strokeWeight(lineWeight);
  pushMatrix();
  translate(width/2,height/2);
  
  for (int i1 = 0; i1 < pointCount; i1++) {
    for (int i2 = 0; i2 < i1; i2++) {
      float d = dist(lissajousPoints[i1].x,lissajousPoints[i1].y,lissajousPoints[i2].x,lissajousPoints[i2].y);
      float a = pow(1 / (d / connectionRadius), 6);
      if (d <= connectionRadius) {
        line(lissajousPoints[i1].x,lissajousPoints[i1].y,lissajousPoints[i2].x,lissajousPoints[i2].y);
      }
    }
  }
  popMatrix();
}

void keyPressed() {
  if (key == 's' || key == 'S') { saveFrame("_##.png"); }
  if (key == '1') { freqX--; }
  if (key == '2') { 
    freqX++; 
    freqX = max(freqX,1);
  }
  if (key == '3') { freqY--; }
  if (key == '4') { 
    freqY++;
    freqY = max(freqY,1);
  }
  if (keyCode == LEFT) {phi -= 15; }
  if (keyCode == RIGHT) { phi += 15; }
  
  if (key == '7') { modFreqX--; }
  if (key == '8') { 
    modFreqX++; 
    modFreqX = max(modFreqX, 1);
  }
  if (key == '9') { modFreqY--; }
  if (key == '0') { 
    modFreqY++;
    modFreqY = max(modFreqY, 1);
  }
  println("freqX:" + freqX + ",freqY:" + freqY + ",phi:" + phi + ",modFreqX:" + modFreqX + ",modFreqY:" + modFreqY);
}

Answer 1

Processingのプログラムは、Activeモードでは最初にsetup()を一度実行し、以降draw()を繰り返し実行する、という形をとります。キー入力のハンドラ等は、draw()が終わったところで検査して必要に応じて呼び出されます。

ということで、

このプログラムでは、draw()がないのでsetup()を実行したらあとは何もしません。

void draw(){
  calculateLissajposPoints();
  drawLissajous();
}

とでも追加すればとりあえず何かしら反応するようになります。
ただし、前述のようにキーの読み出しはdraw()の合間に行われるため、draw()の処理が長すぎると反応は悪くなります。

Comments

[shin-3]

回答ありがとうございます．おかげで解決できました．