C#コードを埋め込んで、コンパイルと実行ができるようなバッチファイルの作り方

Question

前提・実現したいこと

一つのバッチファイルに、C#コードを埋め込んでおいて、
実行したときに「コンパイル→成果物を実行」のようなことができないか、調べています。

手法の名前が分からず、調査が難航しており、
そもそも、実現可能かどうかも分からなかった為、質問することにしました。

JScript.NET という言語向けには、下記のような実装があるので、
これと同じことをC#でも、できないか知りたいです。

@if(0)==(0) echo off&title %~n0&for /f "tokens=*" %%i in ('certutil -hashfile "%~f0" ^| find /v ":"') do (set app_hash=%%i)
set app_path=%~dp0%~n0[%app_hash%].exe
if not exist "%app_path%" (
	del "%~dp0%~n0[*].exe">nul 2>&1&setlocal enabledelayedexpansion&for /f "tokens=*" %%i in ('where /r %windir%\Microsoft.NET jsc.exe ^| sort') do (set compiler_path=%%i)
	"!compiler_path!" /nologo /out:"%app_path%" "%~f0"
)
"%app_path%" %*&exit /b %errorlevel%
@end

//! @file template.bat
//! @version 1.00r1

import System;
import System.Threading;
import System.Reflection;
import System.IO;

// エントリーポイント
Environment.Exit(function(){
	Console.WriteLine("Hello JScript.NET!!");
	Console.ReadKey();
	return 0;
}());

上記のバッチファイルが、どういった仕組みで動作しているのかは、
全貌を理解できていませんが実行すると、下記のような挙動になります。

• @end 以下に書いたソースコードがコンパイルされて実行される
• ソースコードに変更を加えない場合は、コンパイルがスキップされる
• 更新があったときは、古い成果物が削除されてから実行される

発生している問題

分からないなりに格闘して、現状は下記の形になっています。

/*
@echo off&title %~n0
for /f "tokens=*" %%i in ('certutil -hashfile "%~f0" ^| find /v ":"') do (set app_hash=%%i)
set app_path=%~dp0%~n0[%app_hash%].exe
if not exist "%app_path%" (
	del "%~dp0%~n0[*].exe">nul 2>&1
	setlocal enabledelayedexpansion&for /f "tokens=*" %%i in ('where /r %windir%\Microsoft.NET csc.exe ^| sort') do (set compiler_path=%%i)
	"!compiler_path!" /nologo /out:"%app_path%" "%~f0"
)
"%app_path%" %*&exit /b %errorlevel%
*/

//! @file template.bat
//! @version 1.00r1

using System;

class Program
{
	static void Main(string[] args)
	{
		Console.WriteLine("Hello C# !!");
		Console.ReadKey();
	}
}

これを実行した場合は、エラーが出ます。

'/*' は、内部コマンドまたは外部コマンド、
操作可能なプログラムまたはバッチ ファイルとして認識されていません。
Hello C# !!

補足情報（FW/ツールのバージョンなど）

環境は、Windows10 Pro 64bit です。

よろしくお願いします。

まとめ（追記）

最終的なコードです。

@echo off&title %~n0&setlocal enabledelayedexpansion&for /f "tokens=*" %%i in ('certutil -hashfile "%~f0"^|find /v":"') do (set app_hash=%%i)
set app_name=%~dp0%~n0[%app_hash%]&set src_path=!app_name!.cs
if not exist "%app_name%.exe" (del "%~dp0%~n0[*].*">nul 2>&1&type "%~f0"|more +5>"%src_path%"&for /f "tokens=*" %%i in ('where /r %windir%\Microsoft.NET csc.exe^|sort') do (set compiler_path=%%i)
"!compiler_path!" /nologo /out:"%app_name%.exe" "%src_path%")
"%app_name%.exe" %*&exit /b %errorlevel%

//! @file template.bat
//! @version 1.00r1

using System;

class Program
{
	static void Main(string[] args)
	{
		Console.WriteLine("Hello C# !!");
		Console.ReadKey();
	}
}

Comments

[Zuishin]

PowerShell を使う、あるいは csi.exe を使うのではだめなのでしょうか？

[退会済みユーザー]

バッチファイルにこだわっている理由は、特にないので
ほかの手段があれば、それでも大丈夫ですが、新たにツールをインストールするのは、避けたいです。

用途的には、「最小限のビルド環境」として使う想定なので、
コンパイルして成果物(.exe)が得られる形が良いです。

PowerShell や csi.exe については、把握していなかったので、これから調べようと思います。

Answer 1

csi は .NET SDK についてくるのでインストールが必要ですが、PowerShell なら入っていると思います。ただ、csc があるなら csi もあると思います。csi は C# とほぼ同じでスクリプト向けの表記を追加した C# スクリプト(*.csx)を実行するコマンドです。

PowerShell は Add-Type というコマンドで C# のソースをコンパイルできるので、ソースをヒアストリングで与えれば簡単に実装できると思います。

PowerShellスクリプト内でC#コードを書いて使う - YOMON8.NET

ただし、この方法の場合、PowerShell を再起動するとコンパイルやり直しになります。コンパイル後の実行ファイルを保存するには Microsoft.CSharp.CSharpCodeProvider または Roslyn を使います。

以下は CSharpCodeProvider を使う方法です。

PowerShell で他言語を使用する C# 編

Comments

[退会済みユーザー]

回答ありがとうございます。
PowerShell と csi.exe について、軽く確認してみました。

先に、csi.exe についてですが、
csc がある環境でも、Visual Studio をインストールしていないと、csi.exe は使えなさそうだったので、
興味は引かれましたが一旦除外しました。（csc.exe は、Windowsにプリインストールされています。）

PowerShell の方は、リンク先のソースをもとに少し変更を加えて.exe が出力できることを確認しました。
.ps1がセキュリティ周りの仕様で、直接実行できないようになっていることに目をつぶれば、
この方法で、問題が解決しそうです。

ただ今まで、サクラエディタを使っていたので、「Ctrl+B」で直接実行できない点が気になりました。
「PowerShell ISE」という標準のエディタ(IDE?)を使えば、ショートカットで実行できますが...

Answer 2

たぶんcsc.exeがどこかに存在していると思うのでファイルを作成して、
csc.exeでコンパイルするバッチファイルを作成すればよいと思います。

参考：
Visual Studioではなく、Windows付属のcsc.exe だけでC#実行ファイルを作る

@echo off

if exist out.cs (del out.cs)

echo using System;                                     >> out.cs
echo namespace Sample                                  >> out.cs
echo {                                                 >> out.cs
echo     class Program                                 >> out.cs
echo     {                                             >> out.cs
echo         static void Main(string[] args)           >> out.cs
echo         {                                         >> out.cs
echo             Console.WriteLine("Hello, World");    >> out.cs
echo         }                                         >> out.cs
echo     }                                             >> out.cs
echo }                                                 >> out.cs

call C:\Windows\Microsoft.NET\Framework\v2.0.50727\csc.exe /nologo out.cs

call out.exe

@echo off

rem 11行目以降に C# のコードを記述してください

if exist out.cs (del out.cs)

type %~0 | more +11 >> %~dp0%out.cs
call C:\Windows\Microsoft.NET\Framework\v2.0.50727\csc.exe /nologo out.cs
call out.exe

exit /b

using System;

namespace Sample
{
    class Program
    {
        static void Main(string[] args)
        {
            for (int i = 1; i <= 100; i++)
            {
                if (i % 15 == 0)
                {
                    Console.WriteLine("FizzBuzz");
                }
                else if (i % 5 == 0)
                {
                    Console.WriteLine("Buzz");
                }
                else if (i % 3 == 0)
                {
                    Console.WriteLine("Fizz");
                }
                else
                {
                    Console.WriteLine(i);
                }
            }
        }
    }
}

Comments

[退会済みユーザー]

回答ありがとうございます。
csc.exe でコンパイルする方法は、ひとまず理解できました。

しかし目的としては、
「コンパイルするバッチにソースコードを埋め込みたい」というものなので、解決には至らずです。

[退会済みユーザー]

追記しました。

[退会済みユーザー]

「echo ○○ >> out.cs」で、C#コードを書くところや
バッチ側が認識する文字をエスケープして書かないといけないあたり煩わしい感じがしますが、
追記いただいたバッチファイルで、最低限目的は達成できそうです。

やはり、こういう類いの若干トリッキーな仕組みは、スマートに実装できないものなのでしょうか？

[退会済みユーザー]

追記しました。

[Zuishin]

バッチにしなくても out.cs を残しておいて csc out.cs じゃいけないんでしょうか？

[退会済みユーザー]

＞ user1 さん
今回の目的は、提示いただいた方法で完璧に対応できそうです！
埋め込んだソースコードを出力しているので、
ロジック自体は汎用的で他の言語でも使えそうですし、シンプルで良いと思いました。

＞ Zuishin さん
out.cs を編集して、コンパイルコマンドを打ては良いということでしょうか？
大した手間ではないのですが、この質問の背景的には、
コンパイルするタイプの言語をスクリプト言語的に扱えた方が、楽できそうという怠惰心から来ています。