ファイル名変更のためのバッチファイルの中身をシンプルにしたいです

Question

前提

Windows10で、ファイル名を一括で変更するバッチを書こうと思っています。

実現したいこと

XXXXX　は、日本語で、全て同じ名前です。

XXXXXX(1).html
XXXXXX(2).html
XXXXXX(3).html
・・・・
XXXXXX(100).html

という感じで数字だけが違うファイルがあり、
この数字だけを3桁にした名前に変更したいです。

001.html
002.html
003.html
・・・・
100.html

現状のバッチファイルの中身

ren *(1).html 001.html
ren *(2).html 002.html
ren *(3).html 003.html
ren *(4).html 004.html
・・・・
ren *(100).html 100.html

こんな書き方で対処しています。

質問

現状だと数字が増えたとき面倒だなと思い、もっとシンプルな書き方を探してたのですが
バッチ　変数、コマンドプロンプト　ワイルドカード、などなど検索してみても、
この例にあてはまりそうな実例が見つけられませんでした。
もし可能なら、数行で書いてみたいです。お知恵をおかしいただけないでしょうか。
よろしくお願いします。

Answer 1

繰り返し処理でしょうね。

for /l %%I in (1,1,100) do call :RENAME %%I
exit /b

:RENAME
set /a J=1000+%1
ren *(%1).html %J:~1,3%.html
exit /b

「ファイル名を分解して。。」というのは不可能ではなさそうですが、非常に見通しが悪くなります。

と思ったけど、あんまり見通しが悪くなかったです。

for %%F in (*^(*^).html) do call :RENAME %%F
exit /b

:RENAME
set A=%1
set B=%A:*(=%
set C=%B:).html=%
set /a D=1000+C
ren %1 %D:~1,3%.html
exit /b

Comments

[yuwail]

早速ありがとうございます！！
最初の例のもので運用していきたいと思います！
次の例のものでも試してみましたが、うまく動きませんでした。

コマンドについて全く詳しくなく、何が書いてあるかサッパリではあります・・
これからひとつひとつ調べてみて読み解いていきたいと思います。
ありがとうございました！

[otn]

他は見ただけでわかると思いますが、
%J:~1,3%
は、変数Jの（先頭文字を0文字目として）1文字目から3文字を取り出すという意味です。
つまり 1001 の 001 を取り出す。

for /l %%I in (1,1,100)
の2つめの 1 は増分です。つまり「1 から 1 きざみで 100 まで繰り返す」

[yuwail]

ご返信頂いてたんですね！ありがとうございます！！
昨日今日とコマンドについて色々調べて、何が書いてあるかようやくわかりました。。！

二番目の事例について、うまくいかない理由がわかりました。
ファイル名の中に、スペースがあったのです。なので、
一行目の
:RENAME %%F
を
:RENAME "%%F"
にしたら行けました。

本当にありがとうございました！