Excel・VBA　結合セルに対するコードのエラー回避

Question

### ????Excel・VBA　結合セルに対するコードのエラー回避

VBA超初心者????です。
Excel2010です。

あるセルに対し、入力例を薄いグレーの文字で表示させておき、カーソルを置くと表示が消える。
入力をした場合黒文字で入力内容が入り、内容を消すと再度グレーの文字の入力例が表示されるようにしています。

これを１シートの中に複数セル、入力例をそれぞれ変えて設置したいのですが、単一セルに対してはうまくいったのですが、結合されたセルに対してはエラーメッセージが出てしまい、うまく再現できません。

「.MargeArea」や「.MargeCells」をうまく使用して書けばよいのかな？と思ってかなり色々と調べて試行錯誤してみたのですが、何故初心者のため理解が浅く・・・正しい書き方がわかりません。
助けていただけますでしょうか。


### 発生している問題・エラーメッセージ

```
実行時エラー'13'
型が一致しません。
```

### 該当のソースコード

```ここに言語名を入力
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Const cell_D4 As String = "[入力例]10/9"
  With Range("D4:F4")
    If Not Intersect(Target, Range("D4:F4")) Is Nothing Then
      If Target = cell_D4 Then
        Target = ""
        .Font.ColorIndex = 0
    End If

    Else
    If .Value = "" Then
      .Value = cell_D4
      .Font.ColorIndex = 16
      End If
    End If
  End With
 End Sub



```

### 試したこと

.MargeAreaで単一セル指定　や、　.MargeCells　で書いてみたり・・・

Accepted Answer

「.MargeArea」や「.MargeCells」は関係ないですね。

```vba
    If .Value = "" Then
```
セル範囲をまとめて判断できません。
1セルずつ判断しないと。

あと、複数セルを選択したときとか、複数セルを選択して削除したときとか、いろいろな状況を考慮する必要があります。

とりあえずサンプルコードを作成してみましたので、参考にしてください。


```vba
Option Explicit

Const cell_D4 As String = "[入力例]10/9"

Private Sub Worksheet_Activate()
    Call cell_D4_Hint
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    Call cell_D4_Hint
        
    Dim r As Range
    Set r = Intersect(Target, Range("D4:F4"))
    If Not r Is Nothing Then
        With ActiveCell
            If .Value = cell_D4 Then
                .Value = ""
                .Font.ColorIndex = 0
            End If
        End With
    End If
End Sub

Public Sub cell_D4_Hint()
    Dim c As Range
    For Each c In Range("D4:F4")
        If c.Value = "" Then
            c.Value = cell_D4
            c.Font.ColorIndex = 16
        End If
    Next
End Sub
```

---
> これを１シートの中に複数セル、入力例をそれぞれ変えて設置したいのですが、

これを考慮してコードを修正してみました。

シートモジュール
```vba
Option Explicit

Private Sub Worksheet_Activate()
    Call Set_Placeholder
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Call Set_Placeholder
End Sub

Private Sub Set_Placeholder(ParamArray aRng_Placeholder() As Variant)
    Call Rng_Placeholder(Range("D4:F4"), "[入力例]10/9")
    Call Rng_Placeholder(Range("A4"), "[入力例]山田 太郎")
    Call Rng_Placeholder(Range("B4"), "[入力例]ヤマダ タロウ")
End Sub

Private Sub Rng_Placeholder(Rng As Range, Placeholder As String)
    Application.EnableEvents = False
    Dim c As Range
    For Each c In Rng
        If c.Value = "" Then
            c.Value = Placeholder
            c.Font.ColorIndex = 16
        End If
    Next
    If Not Intersect(ActiveCell, Rng) Is Nothing Then
        With ActiveCell
            If .Value = Placeholder Then
                .Value = ""
                .Font.ColorIndex = 0
            End If
        End With
    End If
    Application.EnableEvents = True
End Sub
```

Answer

Else側の処理がWithで指定しているRangeを参照してしまっています。
Targetを参照するようにするべきかと。
またValueでは結合セルに対応できないので、きちんとMergeCellsで結合セルか否か判定してからMergeAreaで値を取得しましょう。
もしくはTextで値参照すると結合セルでも表示されている値を取得できるので、こちらの方がいいかもしれません。
以下、Else内の修正版。
```VBA
            If Target.Text = "" Then
                Target.Value = cell_D4
                Target.Font.ColorIndex = 16
            End If
```
余談ですが、Worksheet_SelectionChangeよりWorksheet_Changeの方がよくないですか？

????Excel・VBA 結合セルに対するコードのエラー回避

発生している問題・エラーメッセージ

該当のソースコード

試したこと

関連した質問

????Excel・VBA　結合セルに対するコードのエラー回避