Excelの数式計算設定を自動計算に固定したい。

Question

前提・実現したいこと

前提：Excelの仕様？で数式計算設定が「手動」になっているブックを開いた後、他のブックを開くと計算設定が「手動」になって開かれてしまう。
やりたいこと：上記現象の解消をしたいです。

試したこと

PERSONAL.XLSBにauto_open()を記述して、ブックが開かれるたびに数式計算設定を「自動」に設定してみましたがエラーが発生してしまいます。
エラーの解消方法か、他の方法があれば教えてください。
よろしくお願いします。

ソースコードは下記のとおりです。

Sub auto_open()
Application.Calculation = xlCalculationAutomatic

End Sub

補足情報（FW/ツールのバージョンなど）

Excel2013で試しています。

発生している問題・エラーメッセージ

実行時エラー1004
Caluculationメソッドは失敗しました。_applicationオブジェクト

Answer 1

Personal.xlsbのThisWorkbookに以下を定義してください。
新規にブックを作成したとき、既存のファイルを開いたときに適用されます。

Public WithEvents xlApp As Application

Private Sub Workbook_Open()
    Set xlApp = Application
End Sub

Private Sub xlApp_NewWorkbook(ByVal Wb As Workbook)
    xlApp.Calculation = xlCalculationAutomatic
End Sub

Private Sub xlApp_WorkbookOpen(ByVal Wb As Workbook)
    xlApp.Calculation = xlCalculationAutomatic
End Sub

---

修正版
ファイルオープン後2秒後に設定変更をさせます。
ファイルサイズによってはエラーになるかもしれないので、念のためエラーはスルーさせています。
その場合は設定変更できません。
秒数の調整で突破できるかもしれないので適宜調整をお願いします。

ThisWorkbookを以下に変更。

Public WithEvents xlApp As Application

Private Sub Workbook_Open()
    Set xlApp = Application
End Sub

Private Sub xlApp_NewWorkbook(ByVal Wb As Workbook)
    Application.OnTime Now + TimeSerial(0, 0, 2), "CalcAuto"
End Sub

Private Sub xlApp_WorkbookOpen(ByVal Wb As Workbook)
    Application.OnTime Now + TimeSerial(0, 0, 2), "CalcAuto"
End Sub

標準モジュールに以下を記述。

Public Sub CalcAuto()
    On Error Resume Next
    Application.Calculation = xlCalculationAutomatic
End Sub

Comments

[tamy123]

試してみましたが、
Private Sub xlApp_WorkbookOpen(ByVal Wb As Workbook)
xlApp.Calculation = xlCalculationAutomatic
End Sub
で、やはり同じエラーが発生してしまします・・・。

[tamy123]

Workbook_Open()に下記1文を加えるとエラーは発生しなくなりましたが、計算設定が自動に切り替わりませんでした
Dim xlapp As Object

[ttyp03]

いや、それは意味ないですね。
どこかの記事にありましたが、ブックのサイズが大きくて読み込みに時間がかかるときはエラーになってしまうようです。
対策版をこのあとコメントに追記しますのでそちらで試してみてください。