Execute(ADODB.Connection)にて取得したRecordsetの動的挙動に関する不明事項

Question

確認したいこと

無指定版ではRecordset側の値が動的に連動する実行結果となります。
解消版では、Recordset.Openにてオプションを指定し静的に取得するようにして解消いたしました。
無指定版の場合の動的挙動について下記２点わかりますでしょうか？

1. 無指定版でSet rs = adcn.Executeにて格納している部分で明示的に指定はしていないのですがCursorTypeとLockTypeは何が指定されているのでしょうか？
2. テーブルスキャンは上記の格納とDebug.Print rs!ID & " " & rs!WORDのタイミングで行われているのでしょうか？動的に結果が変わってたのでイメージが難しいです

発生している問題・エラーメッセージ

実行時エラー '-2147217885(80040e23)': 「レコードは削除されています。」

該当のソースコード

• 無指定

Public Sub testAdo()
    Dim adcn  As ADODB.Connection
    Dim rs As ADODB.Recordset
    
    Set adcn = CreateObject("ADODB.Connection")
    adcn.Provider = "Microsoft.ACE.OLEDB.12.0"
    adcn.Open CurrentProject.Path & "\" & "テスト.accdb"
    adcn.Execute ("Insert into TST_TBL VALUES(""ADOZZ"",""ADOAZWRD"")")
    Set rs = adcn.Execute("select * from TST_TBL")
    adcn.Execute ("Delete FROM TST_TBL")
    
    Do Until rs.EOF
        Debug.Print rs!ID & " " & rs!WORD
        rs.MoveNext
    Loop
    
    adcn.Close
    Set rs = Nothing
    Set adcn = Nothing
    
End Sub

• 解消版

Public Sub testAdo()
    Dim adcn  As ADODB.Connection
    Dim rs As ADODB.Recordset
    
    Set adcn = CreateObject("ADODB.Connection")
    adcn.Provider = "Microsoft.ACE.OLEDB.12.0"
    adcn.Open CurrentProject.Path & "\" & "テスト.accdb"
    adcn.Execute ("Insert into TST_TBL VALUES(""ADOZZ"",""ADOAZWRD"")")
    Set rs = CreateObject("ADODB.Recordset")
    rs.Open "select * from TST_TBL", adcn, adOpenStatic, adLockReadOnly
    adcn.Execute ("Delete FROM TST_TBL")
    
    Do Until rs.EOF
        Debug.Print rs!ID & " " & rs!WORD
        rs.MoveNext
    Loop
    
    adcn.Close
    Set rs = Nothing
    Set adcn = Nothing
    
End Sub

補足情報（FW/ツールのバージョンなど）

Office 365 Solo
Accessのバージョンは1908

Answer 1

カーソル タイプを指定しない場合、ADO はデフォルトで前方スクロール カーソルを開きます。
LockType プロパティは、Recordset が閉じているときは読み取り/書き込みが可能であり、開いているときは読み取り専用です。まRecordset オブジェクトで利用できる実際のロック機能を調べるには、Supports メソッドを使うようです。

参考

また単に現在のカーソルタイプやロックタイプを知りたい場合はＶＢＥの標準機能である、debug.printや、ステップ実行でローカルウインドウを表示するなどしてデバックすれば確認できると思います。

Comments

[kaxzuma]

ご回答ありがとうございます、お礼遅れ申し訳ありません。ADOのデフォルトについて理解がなく助かりました。
Supportsメソッドは使ったことがなく実際に確認してみます。