エクセルマクロにて「セル内の行ごと」の完全一致検索がしたい

Question

前提・実現したいこと

エクセルの業務マクロを作成中です。
「ある文字列で検索して、表のある列のセルに存在した場合隣の列の値を抽出する」
という処理がしたいのですが、検索対象の列はセル内改行で複数の値の箇条書きのような状態です。
それだけなら部分一致検索でよいのですが、検索対象の値には別の値に文字を後ろにくっつけたようなものがあるため、
短いほうの値で検索するとその値まで抽出されてしまい、困っています。
どのような方法なら可能なのか、ご教授ください。

発生している問題・エラーメッセージ

=====|=====|
val1 |abc  |
     |efg  |
=====|=====|
val2 |abcd |
     |efg  |
=====|=====|
val3 |abc  |
     |abcd |
     |efg  |
===========|
↑のような表から"abc"で検索してval1とval3だけ抽出したいが、val2も抽出されてしまう

該当のソースコード

Sub マクロ()
    
    Dim rng As Range
    Dim i As Long
    Dim ary As Variant
    Dim listSheet As Worksheet
    Dim Val
    
    Set listSheet = ThisWorkbook.Worksheets("一覧")
    
    listSheet.Select
        Set rng = Range(Cells(1, 36), Cells(Rows.count, 37).End(xlUp))
        ary = rng
        For i = LBound(ary) To UBound(ary)
             listSheet.Activate
            If ary(i, 2) Like "*abc*" Then
            	val = ary(i, 1)
            	Call valを使うsub(val)
            End If
        Next
    
End Sub

Answer 1

改行で分割して、比較してはいかがでしょうか。

Sub マクロ()

    Dim rng As Range
    Dim i As Long
    Dim j As Long
    Dim ary As Variant
    Dim listSheet As Worksheet
    Dim val
    Dim lines As Variant
    Set listSheet = ThisWorkbook.Worksheets("一覧")

    listSheet.Select
    Set rng = Range(Cells(1, 36), Cells(Rows.Count, 37).End(xlUp))
    ary = rng
    For i = LBound(ary) To UBound(ary)
        listSheet.Activate
        lines = Split(ary(i, 2), vbLf)
        For j = 0 To UBound(lines)
            If lines(j) = "abc" Then
                val = ary(i, 1)
                Call valを使うsub(val)
                Exit For
            End If
        Next
    Next

End Sub

Comments

[ggsu_koma]

回答ありがとうございます。
ベストアンサーは投稿順で選ばせていただきましたが、
こちらも参考にさせていただきます。

Answer 2

下記の４つの場合でOr条件にすればいいでしょう。

完全一致
先頭行に"abc"
途中行に"abc"
最終行に"abc"

セル内改行は Chr(10) = vbLf です。

    Set listSheet = ThisWorkbook.Worksheets("一覧")

    With listSheet
        Set rng = .Range(.Cells(1, 1), .Cells(.Rows.Count, 2).End(xlUp))
    End With
    ary = rng.Value
    For i = LBound(ary) To UBound(ary)
        Dim val2: val2 = ary(i, 2)
        If val2 = "abc" Or _
           val2 Like "abc" & vbLf & "*" Or _
           val2 Like "*" & vbLf & "abc" & vbLf & "*" Or _
           val2 Like "*" & vbLf & "abc" _
        Then
            Val = ary(i, 1)
            Debug.Print Val 'とりあえずイミディエイトに出力
        End If
    Next

Comments

[ggsu_koma]

改行コードを検索条件に含めるのは盲点でした。
ベストアンサーは投稿順で選ばせていただきましたが、
こちらも参考にさせていただきます。
ありがとうございます。

Answer 3

セル内の文字列をSplitで分割して、分割した値とabcを比較すればよいのでは。
動作確認はしてませんが、こんな感じ。

Set rng = Range(Cells(1, 36), Cells(Rows.count, 37).End(xlUp))
ary = rng
For i = LBound(ary) To UBound(ary)
 	listSheet.Activate
	items = Split(ary(i, 2), vbCrLf)
	For Each item in items
		If item = "abc" Then
			val = ary(i, 1)
			Call valを使うsub(val)
			Exit For
		End If
	Next
Next

余談ですが業務で使用するマクロならアクティブ前提の作りはやめたほうがよいですよ。

Comments

[hatena19]

セル内改行は vbLf なので、Split(ary(i, 2), vbLf) ですね。
エクセルはちょっと特殊です。

[ttyp03]

vbLfでしたか。
やはり動作確認は必要ですね。
指摘ありがとうございます。

[ggsu_koma]

ありがとうございました。改行コードを直したら期待した動作になりました。
シートのセットについては仮入れです。ご忠告ありがとうございます。
大変助かりました